lib/Mouse/Exporter.pm

   1 package Mouse::Exporter;
   2 use strict;
   3 use warnings;
   4
   5 use Carp qw(confess);
   6
   7 my %SPEC;
   8
   9 use constant _strict_bits => strict::bits(qw(subs refs vars));
  10
  11 # it must be "require", because Mouse::Util depends on Mouse::Exporter,
  12 # which depends on Mouse::Util::import()
  13 require Mouse::Util;
  14
  15 sub import{
  16     $^H              |= _strict_bits;         # strict->import;
  17     ${^WARNING_BITS}  = $warnings::Bits{all}; # warnings->import;
  18     return;
  19 }
  20
  21
  22 sub setup_import_methods{
  23     my($class, %args) = @_;
  24
  25     my $exporting_package = $args{exporting_package} ||= caller();
  26
  27     my($import, $unimport) = $class->build_import_methods(%args);
  28
  29     no strict 'refs';
  30
  31     *{$exporting_package . '::import'}    = $import;
  32     *{$exporting_package . '::unimport'}  = $unimport;
  33
  34     # for backward compatibility
  35     *{$exporting_package . '::export_to_level'} = sub{
  36         my($package, $level, undef, @args) = @_; # the third argument is redundant
  37         $package->import({ into_level => $level + 1 }, @args);
  38     };
  39     *{$exporting_package . '::export'} = sub{
  40         my($package, $into, @args) = @_;
  41         $package->import({ into => $into }, @args);
  42     };
  43     return;
  44 }
  45
  46 sub build_import_methods{
  47     my($class, %args) = @_;
  48
  49     my $exporting_package = $args{exporting_package} ||= caller();
  50
  51     $SPEC{$exporting_package} = \%args;
  52
  53     # canonicalize args
  54     my @export_from;
  55     if($args{also}){
  56         my %seen;
  57         my @stack = ($exporting_package);
  58
  59         while(my $current = shift @stack){
  60             push @export_from, $current;
  61
  62             my $also = $SPEC{$current}{also} or next;
  63             push @stack, grep{ !$seen{$_}++ } ref($also) ? @{ $also } : $also;
  64         }
  65     }
  66     else{
  67         @export_from = ($exporting_package);
  68     }
  69
  70     {
  71         my %exports;
  72         my @removables;
  73         my @all;
  74
  75         my @init_meta_methods;
  76
  77         foreach my $package(@export_from){
  78             my $spec = $SPEC{$package} or next;
  79
  80             if(my $as_is = $spec->{as_is}){
  81                 foreach my $thingy (@{$as_is}){
  82                     my($code_package, $code_name, $code);
  83
  84                     if(ref($thingy)){
  85                         $code = $thingy;
  86                         ($code_package, $code_name) = Mouse::Util::get_code_info($code);
  87                     }
  88                     else{
  89                         no strict 'refs';
  90                         $code_package = $package;
  91                         $code_name    = $thingy;
  92                         $code         = \&{ $code_package . '::' . $code_name };
  93                    }
  94
  95                     push @all, $code_name;
  96                     $exports{$code_name} = $code;
  97                     if($code_package eq $package){
  98                         push @removables, $code_name;
  99                     }
 100                 }
 101             }
 102
 103             if(my $init_meta = $package->can('init_meta')){
 104                 if(!grep{ $_ == $init_meta } @init_meta_methods){
 105                     push @init_meta_methods, $init_meta;
 106                 }
 107             }
 108         }
 109         $args{EXPORTS}    = \%exports;
 110         $args{REMOVABLES} = \@removables;
 111
 112         $args{groups}{all}     ||= \@all;
 113
 114         if(my $default_list = $args{groups}{default}){
 115             my %default;
 116             foreach my $keyword(@{$default_list}){
 117                 $default{$keyword} = $exports{$keyword}
 118                     || confess(qq{The $exporting_package package does not export "$keyword"});
 119             }
 120             $args{DEFAULT} = \%default;
 121         }
 122         else{
 123             $args{groups}{default} ||= \@all;
 124             $args{DEFAULT}           = $args{EXPORTS};
 125         }
 126
 127         if(@init_meta_methods){
 128             $args{INIT_META} = \@init_meta_methods;
 129         }
 130     }
 131
 132     return (\&do_import, \&do_unimport);
 133 }
 134
 135
 136 # the entity of general import()
 137 sub do_import {
 138     my($package, @args) = @_;
 139
 140     my $spec = $SPEC{$package}
 141         || confess("The package $package package does not use Mouse::Exporter");
 142
 143     my $into = _get_caller_package(ref($args[0]) ? shift @args : undef);
 144
 145     my @exports;
 146
 147     foreach my $arg(@args){
 148         if($arg =~ s/^-//){
 149             Mouse::Util::not_supported("-$arg");
 150         }
 151         elsif($arg =~ s/^://){
 152             my $group = $spec->{groups}{$arg}
 153                 || confess(qq{The $package package does not export the group "$arg"});
 154             push @exports, @{$group};
 155         }
 156         else{
 157             push @exports, $arg;
 158         }
 159     }
 160
 161     $^H              |= _strict_bits;         # strict->import;
 162     ${^WARNING_BITS}  = $warnings::Bits{all}; # warnings->import;
 163
 164     if($spec->{INIT_META}){
 165         foreach my $init_meta(@{$spec->{INIT_META}}){
 166             $into->$init_meta(for_class => $into);
 167         }
 168
 169         # _apply_meta_traits($into); # TODO
 170     }
 171
 172     if(@exports){
 173         foreach my $keyword(@exports){
 174             no strict 'refs';
 175             *{$into.'::'.$keyword} = $spec->{EXPORTS}{$keyword}
 176                 || confess(qq{The $package package does not export "$keyword"});
 177         }
 178     }
 179     else{
 180         my $default = $spec->{DEFAULT};
 181         while(my($keyword, $code) = each %{$default}){
 182             no strict 'refs';
 183             *{$into.'::'.$keyword} = $code;
 184         }
 185     }
 186     return;
 187 }
 188
 189 # the entity of general unimport()
 190 sub do_unimport {
 191     my($package, $arg) = @_;
 192
 193     my $spec = $SPEC{$package}
 194         || confess("The package $package does not use Mouse::Exporter");
 195
 196     my $from = _get_caller_package($arg);
 197
 198     my $stash = do{
 199         no strict 'refs';
 200         \%{$from . '::'}
 201     };
 202
 203     for my $keyword (@{ $spec->{REMOVABLES} }) {
 204         my $gv = \$stash->{$keyword};
 205         if(ref($gv) eq 'GLOB' && *{$gv}{CODE} == $spec->{EXPORTS}{$keyword}){ # make sure it is from us
 206             delete $stash->{$keyword};
 207         }
 208     }
 209     return;
 210 }
 211
 212 # 1 extra level because it's called by import so there's a layer\r
 213 # of indirection\r
 214 sub _LEVEL(){ 1 }
 215
 216 sub _get_caller_package {
 217     my($arg) = @_;
 218
 219     if(ref $arg){
 220         return defined($arg->{into})       ? $arg->{into}
 221              : defined($arg->{into_level}) ? scalar caller(_LEVEL + $arg->{into_level})
 222              :                               scalar caller(_LEVEL);
 223     }
 224     else{
 225         return scalar caller(_LEVEL);
 226     }
 227 }
 228
 229 #sub _spec{ %SPEC }
 230
 231 1;
 232
 233 __END__
 234
 235 =head1 NAME
 236
 237 Mouse::Exporter - make an import() and unimport() just like Mouse.pm
 238
 239 =head1 VERSION
 240
 241 This document describes Mouse version 0.40
 242
 243 =head1 SYNOPSIS
 244
 245     package MyApp::Mouse;\r
 246 \r
 247     use Mouse ();\r
 248     use Mouse::Exporter;\r
 249 \r
 250     Mouse::Exporter->setup_import_methods(\r
 251       as_is     => [ 'has_rw', 'other_sugar', \&Some::Random::thing ],\r
 252       also      => 'Mouse',\r
 253     );\r
 254 \r
 255     sub has_rw {
 256         my $meta = caller->meta;\r
 257         my ( $name, %options ) = @_;\r
 258         $meta->add_attribute(\r
 259           $name,\r
 260           is => 'rw',\r
 261           %options,\r
 262         );\r
 263     }\r
 264 \r
 265     # then later ...\r
 266     package MyApp::User;\r
 267
 268     use MyApp::Mouse;\r
 269 \r
 270     has 'name';\r
 271     has_rw 'size';\r
 272     thing;\r
 273 \r
 274     no MyApp::Mouse;
 275
 276 =head1 DESCRIPTION
 277
 278 This module encapsulates the exporting of sugar functions in a\r
 279 C<Mouse.pm>-like manner. It does this by building custom C<import>,\r
 280 C<unimport> methods for your module, based on a spec you provide.\r
 281
 282 Note that C<Mouse::Exporter> does not provide the C<with_meta> option,
 283 but you can easily get the metaclass by C<< caller->meta >> as L</SYNOPSIS> shows.
 284
 285 =head1 METHODS
 286
 287 =head2 C<< setup_import_methods( ARGS ) >>
 288
 289 =head2 C<< build_import_methods( ARGS ) -> (\&import, \&unimport) >>
 290
 291 =head1 SEE ALSO
 292
 293 L<Moose::Exporter>
 294
 295 =cut
 296