lib/Mouse/Attribute.pm

   1 #!/usr/bin/env perl
   2 package Mouse::Attribute;
   3 use strict;
   4 use warnings;
   5
   6 use Carp 'confess';
   7 use Scalar::Util 'blessed';
   8
   9 sub new {
  10     my $class = shift;
  11     my %args  = @_;
  12
  13     $args{init_arg} = $args{name}
  14         unless exists $args{init_arg};
  15     $args{is} ||= '';
  16
  17     bless \%args, $class;
  18 }
  19
  20 sub name            { $_[0]->{name}            }
  21 sub class           { $_[0]->{class}           }
  22 sub _is_metadata    { $_[0]->{is}              }
  23 sub is_required     { $_[0]->{required}        }
  24 sub default         { $_[0]->{default}         }
  25 sub is_lazy         { $_[0]->{lazy}            }
  26 sub predicate       { $_[0]->{predicate}       }
  27 sub clearer         { $_[0]->{clearer}         }
  28 sub handles         { $_[0]->{handles}         }
  29 sub weak_ref        { $_[0]->{weak_ref}        }
  30 sub init_arg        { $_[0]->{init_arg}        }
  31 sub type_constraint { $_[0]->{type_constraint} }
  32 sub trigger         { $_[0]->{trigger}         }
  33 sub builder         { $_[0]->{builder}         }
  34
  35 sub has_default         { exists $_[0]->{default}         }
  36 sub has_predicate       { exists $_[0]->{predicate}       }
  37 sub has_clearer         { exists $_[0]->{clearer}         }
  38 sub has_handles         { exists $_[0]->{handles}         }
  39 sub has_type_constraint { exists $_[0]->{type_constraint} }
  40 sub has_trigger         { exists $_[0]->{trigger}         }
  41 sub has_builder         { exists $_[0]->{builder}         }
  42
  43 sub generate_accessor {
  44     my $attribute = shift;
  45
  46     my $name       = $attribute->name;
  47     my $key        = $attribute->init_arg;
  48     my $default    = $attribute->default;
  49     my $trigger    = $attribute->trigger;
  50     my $type       = $attribute->type_constraint;
  51     my $constraint = $attribute->find_type_constraint;
  52     my $builder    = $attribute->builder;
  53
  54     my $accessor = 'sub {
  55         my $self = shift;';
  56
  57     if ($attribute->_is_metadata eq 'rw') {
  58         $accessor .= 'if (@_) {
  59             local $_ = $_[0];';
  60
  61         if ($constraint) {
  62             $accessor .= 'do {
  63                 my $display = defined($_) ? $_ : "undef";
  64                 Carp::confess("Attribute ($name) does not pass the type constraint because: Validation failed for \'$type\' failed with value $display") unless $constraint->();
  65             };'
  66         }
  67
  68         $accessor .= '$self->{$key} = $_;';
  69
  70         if ($attribute->weak_ref) {
  71             $accessor .= 'Scalar::Util::weaken($self->{$key});';
  72         }
  73
  74         if ($trigger) {
  75             $accessor .= '$trigger->($self, $_, $attribute);';
  76         }
  77
  78         $accessor .= '}';
  79     }
  80     else {
  81     }
  82
  83     if ($attribute->is_lazy) {
  84         $accessor .= '$self->{$key} = ';
  85
  86         $accessor .= $attribute->has_builder
  87                    ? '$self->$builder'
  88                      : ref($default) eq 'CODE'
  89                      ? '$default->($self)'
  90                      : '$default';
  91
  92         $accessor .= ' if !exists($self->{$key});';
  93     }
  94
  95     $accessor .= 'return $self->{$key}
  96     }';
  97
  98     return eval $accessor;
  99 }
 100
 101 sub generate_predicate {
 102     my $attribute = shift;
 103     my $key = $attribute->init_arg;
 104
 105     my $predicate = 'sub { exists($_[0]->{$key}) }';
 106
 107     return eval $predicate;
 108 }
 109
 110 sub generate_clearer {
 111     my $attribute = shift;
 112     my $key = $attribute->init_arg;
 113
 114     my $predicate = 'sub { delete($_[0]->{$key}) }';
 115
 116     return eval $predicate;
 117 }
 118
 119 sub generate_handles {
 120     my $attribute = shift;
 121     my $reader = $attribute->name;
 122
 123     my %method_map;
 124
 125     for my $local_method (keys %{ $attribute->handles }) {
 126         my $remote_method = $attribute->handles->{$local_method};
 127
 128         my $method = 'sub {
 129             my $self = shift;
 130             $self->$reader->$remote_method(@_)
 131         }';
 132
 133         $method_map{$local_method} = eval $method;
 134     }
 135
 136     return \%method_map;
 137 }
 138
 139 sub create {
 140     my ($self, $class, $name, %args) = @_;
 141
 142     confess "You must specify a default for lazy attribute '$name'"
 143         if $args{lazy} && !exists($args{default}) && !exists($args{builder});
 144
 145     confess "Trigger is not allowed on read-only attribute '$name'"
 146         if $args{trigger} && $args{is} ne 'rw';
 147
 148     confess "References are not allowed as default values, you must wrap the default of '$name' in a CODE reference (ex: sub { [] } and not [])"
 149         if ref($args{default})
 150         && ref($args{default}) ne 'CODE';
 151
 152     $args{handles} = { $self->_canonicalize_handles($args{handles}) }
 153         if $args{handles};
 154
 155     $args{type_constraint} = delete $args{isa}
 156         if exists $args{isa};
 157
 158     my $attribute = $self->new(%args, name => $name, class => $class);
 159     my $meta = $class->meta;
 160
 161     $meta->add_attribute($attribute);
 162
 163     # install an accessor
 164     if ($attribute->_is_metadata eq 'rw' || $attribute->_is_metadata eq 'ro') {
 165         my $accessor = $attribute->generate_accessor;
 166         no strict 'refs';
 167         *{ $class . '::' . $name } = $accessor;
 168     }
 169
 170     for my $method (qw/predicate clearer/) {
 171         my $predicate = "has_$method";
 172         if ($attribute->$predicate) {
 173             my $generator = "generate_$method";
 174             my $coderef = $attribute->$generator;
 175             no strict 'refs';
 176             *{ $class . '::' . $attribute->$method } = $coderef;
 177         }
 178     }
 179
 180     if ($attribute->has_handles) {
 181         my $method_map = $attribute->generate_handles;
 182         for my $method_name (keys %$method_map) {
 183             no strict 'refs';
 184             *{ $class . '::' . $method_name } = $method_map->{$method_name};
 185         }
 186     }
 187
 188     return $attribute;
 189 }
 190
 191 sub find_type_constraint {
 192     my $self = shift;
 193     my $type = $self->type_constraint;
 194
 195     return unless $type;
 196
 197     my $checker = Mouse::TypeRegistry->optimized_constraints->{$type};
 198     return $checker if $checker;
 199
 200     return sub { blessed($_) && blessed($_) eq $type };
 201 }
 202
 203 sub verify_type_constraint {
 204     my $self = shift;
 205     local $_ = shift;
 206
 207     my $type = $self->type_constraint
 208         or return 1;
 209     my $constraint = $self->find_type_constraint;
 210
 211     return 1 if $constraint->($_);
 212
 213     my $name = $self->name;
 214     local $_ = "undef" unless defined($_);
 215     Carp::confess("Attribute ($name) does not pass the type constraint because: Validation failed for \'$type\' failed with value $_");
 216 }
 217
 218 sub _canonicalize_handles {
 219     my $self    = shift;
 220     my $handles = shift;
 221
 222     if (ref($handles) eq 'HASH') {
 223         return %$handles;
 224     }
 225     elsif (ref($handles) eq 'ARRAY') {
 226         return map { $_ => $_ } @$handles;
 227     }
 228     else {
 229         confess "Unable to canonicalize the 'handles' option with $handles";
 230     }
 231 }
 232
 233 1;
 234
 235 __END__
 236
 237 =head1 NAME
 238
 239 Mouse::Attribute - attribute metaclass
 240
 241 =head1 METHODS
 242
 243 =head2 new %args -> Mouse::Attribute
 244
 245 Instantiates a new Mouse::Attribute. Does nothing else.
 246
 247 =head2 create OwnerClass, AttributeName, %args -> Mouse::Attribute
 248
 249 Creates a new attribute in OwnerClass. Accessors and helper methods are
 250 installed. Some error checking is done.
 251
 252 =head2 name -> AttributeName
 253
 254 =head2 class -> OwnerClass
 255
 256 =head2 is_required -> Bool
 257
 258 =head2 default -> Item
 259
 260 =head2 has_default -> Bool
 261
 262 =head2 is_lazy -> Bool
 263
 264 =head2 predicate -> MethodName | Undef
 265
 266 =head2 has_predicate -> Bool
 267
 268 =head2 clearer -> MethodName | Undef
 269
 270 =head2 has_clearer -> Bool
 271
 272 =head2 handles -> { LocalName => RemoteName }
 273
 274 =head2 has_handles -> Bool
 275
 276 =head2 weak_ref -> Bool
 277
 278 =head2 init_arg -> Str
 279
 280 =head2 type_constraint -> Str
 281
 282 =head2 has_type_constraint -> Bool
 283
 284 =head2 trigger => CODE | Undef
 285
 286 =head2 has_trigger -> Bool
 287
 288 =head2 builder => MethodName | Undef
 289
 290 =head2 has_builder -> Bool
 291
 292 Informational methods.
 293
 294 =head2 generate_accessor -> CODE
 295
 296 Creates a new code reference for the attribute's accessor.
 297
 298 =head2 generate_predicate -> CODE
 299
 300 Creates a new code reference for the attribute's predicate.
 301
 302 =head2 generate_clearer -> CODE
 303
 304 Creates a new code reference for the attribute's clearer.
 305
 306 =head2 generate_handles -> { MethodName => CODE }
 307
 308 Creates a new code reference for each of the attribute's handles methods.
 309
 310 =head2 find_type_constraint -> CODE
 311
 312 Returns a code reference which can be used to check that a given value passes
 313 this attribute's type constraint;
 314
 315 =head2 verify_type_constraint Item -> 1 | ERROR
 316
 317 Checks that the given value passes this attribute's type constraint. Returns 1
 318 on success, otherwise C<confess>es.
 319
 320 =cut
 321