lib/Mouse.pm

   1 package Mouse;
   2 use 5.006_002;
   3
   4 use Mouse::Exporter; # enables strict and warnings
   5
   6 our $VERSION = '0.37_04';
   7
   8 use Carp qw(confess);
   9 use Scalar::Util qw(blessed);
  10
  11 use Mouse::Util qw(load_class is_class_loaded get_code_package not_supported);
  12
  13 use Mouse::Meta::Module;
  14 use Mouse::Meta::Class;
  15 use Mouse::Meta::Role;
  16 use Mouse::Meta::Attribute;
  17 use Mouse::Object;
  18 use Mouse::Util::TypeConstraints ();
  19
  20 Mouse::Exporter->setup_import_methods(
  21     as_is => [qw(
  22         extends with
  23         has
  24         before after around
  25         override super
  26         augment  inner
  27     ),
  28         \&Scalar::Util::blessed,
  29         \&Carp::confess,
  30    ],
  31 );
  32
  33 # XXX: for backward compatibility
  34 our @EXPORT = qw(
  35     extends with
  36     has
  37     before after around
  38     override super
  39     augment  inner
  40     blessed confess
  41 );
  42
  43 sub extends { Mouse::Meta::Class->initialize(scalar caller)->superclasses(@_) }
  44
  45 sub has {
  46     my $meta = Mouse::Meta::Class->initialize(scalar caller);
  47     my $name = shift;
  48
  49     $meta->throw_error(q{Usage: has 'name' => ( key => value, ... )})\r
  50         if @_ % 2; # odd number of arguments
  51
  52     $meta->add_attribute($_ => @_) for ref($name) ? @{$name} : $name;
  53 }
  54
  55 sub before {
  56     my $meta = Mouse::Meta::Class->initialize(scalar caller);
  57
  58     my $code = pop;
  59
  60     for (@_) {
  61         $meta->add_before_method_modifier($_ => $code);
  62     }
  63 }
  64
  65 sub after {
  66     my $meta = Mouse::Meta::Class->initialize(scalar caller);
  67
  68     my $code = pop;
  69
  70     for (@_) {
  71         $meta->add_after_method_modifier($_ => $code);
  72     }
  73 }
  74
  75 sub around {
  76     my $meta = Mouse::Meta::Class->initialize(scalar caller);
  77
  78     my $code = pop;
  79
  80     for (@_) {
  81         $meta->add_around_method_modifier($_ => $code);
  82     }
  83 }
  84
  85 sub with {
  86     Mouse::Util::apply_all_roles(scalar(caller), @_);
  87 }
  88
  89 our $SUPER_PACKAGE;
  90 our $SUPER_BODY;
  91 our @SUPER_ARGS;
  92
  93 sub super {
  94     # This check avoids a recursion loop - see
  95     # t/100_bugs/020_super_recursion.t
  96     return if  defined $SUPER_PACKAGE && $SUPER_PACKAGE ne caller();
  97     return if !defined $SUPER_BODY;
  98     $SUPER_BODY->(@SUPER_ARGS);
  99 }
 100
 101 sub override {
 102     # my($name, $method) = @_;
 103     Mouse::Meta::Class->initialize(scalar caller)->add_override_method_modifier(@_);
 104 }
 105
 106 our %INNER_BODY;
 107 our %INNER_ARGS;
 108
 109 sub inner {
 110     my $pkg = caller();
 111     if ( my $body = $INNER_BODY{$pkg} ) {
 112         my $args = $INNER_ARGS{$pkg};
 113         local $INNER_ARGS{$pkg};
 114         local $INNER_BODY{$pkg};
 115         return $body->(@{$args});
 116     }
 117     else {
 118         return;
 119     }
 120 }
 121
 122 sub augment {
 123     #my($name, $method) = @_;
 124     Mouse::Meta::Class->initialize(scalar caller)->add_augment_method_modifier(@_);
 125 }
 126
 127 sub init_meta {
 128     shift;
 129     my %args = @_;
 130
 131     my $class = $args{for_class}
 132                     or confess("Cannot call init_meta without specifying a for_class");
 133     my $base_class = $args{base_class} || 'Mouse::Object';
 134     my $metaclass  = $args{metaclass}  || 'Mouse::Meta::Class';
 135
 136     # make a subtype for each Mouse class
 137     Mouse::Util::TypeConstraints::class_type($class)
 138         unless Mouse::Util::TypeConstraints::find_type_constraint($class);
 139
 140     my $meta = $metaclass->initialize($class);
 141
 142     $meta->add_method(meta => sub{
 143         return $metaclass->initialize(ref($_[0]) || $_[0]);
 144     });
 145
 146     $meta->superclasses($base_class)
 147         unless $meta->superclasses;
 148
 149     return $meta;
 150 }
 151
 152
 153 1;
 154
 155 __END__
 156
 157 =head1 NAME
 158
 159 Mouse - Moose minus the antlers
 160
 161 =head1 SYNOPSIS
 162
 163     package Point;
 164     use Mouse; # automatically turns on strict and warnings
 165
 166     has 'x' => (is => 'rw', isa => 'Int');
 167     has 'y' => (is => 'rw', isa => 'Int');
 168
 169     sub clear {
 170         my $self = shift;
 171         $self->x(0);
 172         $self->y(0);
 173     }
 174
 175     package Point3D;
 176     use Mouse;
 177
 178     extends 'Point';
 179
 180     has 'z' => (is => 'rw', isa => 'Int');
 181
 182     after 'clear' => sub {
 183         my $self = shift;
 184         $self->z(0);
 185     };
 186
 187 =head1 DESCRIPTION
 188
 189 L<Moose> is wonderful. B<Use Moose instead of Mouse.>
 190
 191 Unfortunately, Moose has a compile-time penalty. Though significant progress
 192 has been made over the years, the compile time penalty is a non-starter for
 193 some very specific applications. If you are writing a command-line application
 194 or CGI script where startup time is essential, you may not be able to use
 195 Moose. We recommend that you instead use L<HTTP::Engine> and FastCGI for the
 196 latter, if possible.
 197
 198 Mouse aims to alleviate this by providing a subset of Moose's functionality,
 199 faster.
 200
 201 We're also going as light on dependencies as possible.
 202 L<Class::Method::Modifiers::Fast> or L<Class::Method::Modifiers> is required
 203 if you want support for L</before>, L</after>, and L</around>.
 204
 205 =head2 MOOSE COMPATIBILITY
 206
 207 Compatibility with Moose has been the utmost concern. Fewer than 1% of the
 208 tests fail when run against Moose instead of Mouse. Mouse code coverage is also
 209 over 96%. Even the error messages are taken from Moose. The Mouse code just
 210 runs the test suite 4x faster.
 211
 212 The idea is that, if you need the extra power, you should be able to run
 213 C<s/Mouse/Moose/g> on your codebase and have nothing break. To that end,
 214 we have written L<Any::Moose> which will act as Mouse unless Moose is loaded,
 215 in which case it will act as Moose. Since Mouse is a little sloppier than
 216 Moose, if you run into weird errors, it would be worth running:
 217
 218     ANY_MOOSE=Moose perl your-script.pl
 219
 220 to see if the bug is caused by Mouse. Moose's diagnostics and validation are
 221 also much better.
 222
 223 =head2 MouseX
 224
 225 Please don't copy MooseX code to MouseX. If you need extensions, you really
 226 should upgrade to Moose. We don't need two parallel sets of extensions!
 227
 228 If you really must write a Mouse extension, please contact the Moose mailing
 229 list or #moose on IRC beforehand.
 230
 231 =head1 KEYWORDS
 232
 233 =head2 C<< $object->meta -> Mouse::Meta::Class >>
 234
 235 Returns this class' metaclass instance.
 236
 237 =head2 C<< extends superclasses >>
 238
 239 Sets this class' superclasses.
 240
 241 =head2 C<< before (method|methods) => CodeRef >>
 242
 243 Installs a "before" method modifier. See L<Moose/before> or
 244 L<Class::Method::Modifiers/before>.
 245
 246 Use of this feature requires L<Class::Method::Modifiers>!
 247
 248 =head2 C<< after (method|methods) => CodeRef >>
 249
 250 Installs an "after" method modifier. See L<Moose/after> or
 251 L<Class::Method::Modifiers/after>.
 252
 253 Use of this feature requires L<Class::Method::Modifiers>!
 254
 255 =head2 C<< around (method|methods) => CodeRef >>
 256
 257 Installs an "around" method modifier. See L<Moose/around> or
 258 L<Class::Method::Modifiers/around>.
 259
 260 Use of this feature requires L<Class::Method::Modifiers>!
 261
 262 =head2 C<< has (name|names) => parameters >>
 263
 264 Adds an attribute (or if passed an arrayref of names, multiple attributes) to
 265 this class. Options:
 266
 267 =over 4
 268
 269 =item C<< is => ro|rw|bare >>
 270
 271 If specified, inlines a read-only/read-write accessor with the same name as
 272 the attribute.
 273
 274 =item C<< isa => TypeConstraint >>
 275
 276 Provides type checking in the constructor and accessor. The following types are
 277 supported. Any unknown type is taken to be a class check
 278 (e.g. C<< isa => 'DateTime' >> would accept only L<DateTime> objects).
 279
 280     Any Item Bool Undef Defined Value Num Int Str ClassName
 281     Ref ScalarRef ArrayRef HashRef CodeRef RegexpRef GlobRef
 282     FileHandle Object
 283
 284 For more documentation on type constraints, see L<Mouse::Util::TypeConstraints>.
 285
 286
 287 =item C<< required => Bool >>
 288
 289 Whether this attribute is required to have a value. If the attribute is lazy or
 290 has a builder, then providing a value for the attribute in the constructor is
 291 optional.
 292
 293 =item C<< init_arg => Str | Undef >>
 294
 295 Allows you to use a different key name in the constructor.  If undef, the
 296 attribute can't be passed to the constructor.
 297
 298 =item C<< default => Value | CodeRef >>
 299
 300 Sets the default value of the attribute. If the default is a coderef, it will
 301 be invoked to get the default value. Due to quirks of Perl, any bare reference
 302 is forbidden, you must wrap the reference in a coderef. Otherwise, all
 303 instances will share the same reference.
 304
 305 =item C<< lazy => Bool >>
 306
 307 If specified, the default is calculated on demand instead of in the
 308 constructor.
 309
 310 =item C<< predicate => Str >>
 311
 312 Lets you specify a method name for installing a predicate method, which checks
 313 that the attribute has a value. It will not invoke a lazy default or builder
 314 method.
 315
 316 =item C<< clearer => Str >>
 317
 318 Lets you specify a method name for installing a clearer method, which clears
 319 the attribute's value from the instance. On the next read, lazy or builder will
 320 be invoked.
 321
 322 =item C<< handles => HashRef|ArrayRef >>
 323
 324 Lets you specify methods to delegate to the attribute. ArrayRef forwards the
 325 given method names to method calls on the attribute. HashRef maps local method
 326 names to remote method names called on the attribute. Other forms of
 327 L</handles>, such as regular expression and coderef, are not yet supported.
 328
 329 =item C<< weak_ref => Bool >>
 330
 331 Lets you automatically weaken any reference stored in the attribute.
 332
 333 Use of this feature requires L<Scalar::Util>!
 334
 335 =item C<< trigger => CodeRef >>
 336
 337 Any time the attribute's value is set (either through the accessor or the constructor), the trigger is called on it. The trigger receives as arguments the instance, the new value, and the attribute instance.
 338
 339 =item C<< builder => Str >>
 340
 341 Defines a method name to be called to provide the default value of the
 342 attribute. C<< builder => 'build_foo' >> is mostly equivalent to
 343 C<< default => sub { $_[0]->build_foo } >>.
 344
 345 =item C<< auto_deref => Bool >>
 346
 347 Allows you to automatically dereference ArrayRef and HashRef attributes in list
 348 context. In scalar context, the reference is returned (NOT the list length or
 349 bucket status). You must specify an appropriate type constraint to use
 350 auto_deref.
 351
 352 =item C<< lazy_build => Bool >>
 353
 354 Automatically define the following options:
 355
 356     has $attr => (
 357         # ...
 358         lazy      => 1
 359         builder   => "_build_$attr",
 360         clearer   => "clear_$attr",
 361         predicate => "has_$attr",
 362     );
 363
 364 =back
 365
 366 =head2 C<< confess(message) -> BOOM >>
 367
 368 L<Carp/confess> for your convenience.
 369
 370 =head2 C<< blessed(value) -> ClassName | undef >>
 371
 372 L<Scalar::Util/blessed> for your convenience.
 373
 374 =head1 MISC
 375
 376 =head2 import
 377
 378 Importing Mouse will default your class' superclass list to L<Mouse::Object>.
 379 You may use L</extends> to replace the superclass list.
 380
 381 =head2 unimport
 382
 383 Please unimport Mouse (C<no Mouse>) so that if someone calls one of the
 384 keywords (such as L</extends>) it will break loudly instead breaking subtly.
 385
 386 =head1 SOURCE CODE ACCESS
 387
 388 We have a public git repository:
 389
 390  git clone git://jules.scsys.co.uk/gitmo/Mouse.git
 391
 392 =head1 DEPENDENCIES
 393
 394 Perl 5.6.2 or later.
 395
 396 =head1 SEE ALSO
 397
 398 L<Moose>
 399
 400 L<Class::MOP>
 401
 402 =head1 AUTHORS
 403
 404 Shawn M Moore, E<lt>sartak at gmail.comE<gt>
 405
 406 Yuval Kogman, E<lt>nothingmuch at woobling.orgE<gt>
 407
 408 tokuhirom
 409
 410 Yappo
 411
 412 wu-lee
 413
 414 Goro Fuji (gfx) E<lt>gfuji at cpan.orgE<gt>
 415
 416 with plenty of code borrowed from L<Class::MOP> and L<Moose>
 417
 418 =head1 BUGS
 419
 420 All complex software has bugs lurking in it, and this module is no exception.
 421 Please report any bugs to C<bug-mouse at rt.cpan.org>, or through the web
 422 interface at L<http://rt.cpan.org/Public/Dist/Display.html?Name=Mouse>
 423
 424 =head1 COPYRIGHT AND LICENSE
 425
 426 Copyright 2008-2009 Infinity Interactive, Inc.
 427
 428 http://www.iinteractive.com/
 429
 430 This program is free software; you can redistribute it and/or modify it
 431 under the same terms as Perl itself.
 432
 433 =cut
 434