lib/Mouse.pm

   1 package Mouse;
   2 use strict;
   3 use warnings;
   4 use 5.006;
   5 use base 'Exporter';
   6
   7 our $VERSION = '0.24';
   8
   9 use Carp 'confess';
  10 use Scalar::Util 'blessed';
  11 use Mouse::Util;
  12
  13 use Mouse::Meta::Attribute;
  14 use Mouse::Meta::Class;
  15 use Mouse::Object;
  16 use Mouse::Util::TypeConstraints;
  17
  18 our @EXPORT = qw(extends has before after around override super blessed confess with);
  19
  20 sub extends { Mouse::Meta::Class->initialize(caller)->superclasses(@_) }
  21
  22 sub has {
  23     my $meta = Mouse::Meta::Class->initialize(caller);
  24     $meta->add_attribute(@_);
  25 }
  26
  27 sub before {
  28     my $meta = Mouse::Meta::Class->initialize(caller);
  29
  30     my $code = pop;
  31
  32     for (@_) {
  33         $meta->add_before_method_modifier($_ => $code);
  34     }
  35 }
  36
  37 sub after {
  38     my $meta = Mouse::Meta::Class->initialize(caller);
  39
  40     my $code = pop;
  41
  42     for (@_) {
  43         $meta->add_after_method_modifier($_ => $code);
  44     }
  45 }
  46
  47 sub around {
  48     my $meta = Mouse::Meta::Class->initialize(caller);
  49
  50     my $code = pop;
  51
  52     for (@_) {
  53         $meta->add_around_method_modifier($_ => $code);
  54     }
  55 }
  56
  57 sub with {
  58     Mouse::Util::apply_all_roles((caller)[0], @_);
  59 }
  60
  61 our $SUPER_PACKAGE;
  62 our $SUPER_BODY;
  63 our @SUPER_ARGS;
  64
  65 sub super {
  66     # This check avoids a recursion loop - see
  67     # t/100_bugs/020_super_recursion.t
  68     return if defined $SUPER_PACKAGE && $SUPER_PACKAGE ne caller();
  69     return unless $SUPER_BODY; $SUPER_BODY->(@SUPER_ARGS);
  70 }
  71
  72 sub override {
  73     my $meta = Mouse::Meta::Class->initialize(caller);
  74     my $pkg = $meta->name;
  75
  76     my $name = shift;
  77     my $code = shift;
  78
  79     my $body = $pkg->can($name)
  80         or confess "You cannot override '$name' because it has no super method";
  81
  82     $meta->add_method($name => sub {
  83         local $SUPER_PACKAGE = $pkg;
  84         local @SUPER_ARGS = @_;
  85         local $SUPER_BODY = $body;
  86
  87         $code->(@_);
  88     });
  89 }
  90
  91 sub import {
  92     my $class = shift;
  93
  94     strict->import;
  95     warnings->import;
  96
  97     my $opts = do {
  98         if (ref($_[0]) && ref($_[0]) eq 'HASH') {
  99             shift @_;
 100         } else {
 101             +{ };
 102         }
 103     };
 104     my $level = delete $opts->{into_level};
 105        $level = 0 unless defined $level;
 106     my $caller = caller($level);
 107
 108     # we should never export to main
 109     if ($caller eq 'main') {
 110         warn qq{$class does not export its sugar to the 'main' package.\n};
 111         return;
 112     }
 113
 114     my $meta = Mouse::Meta::Class->initialize($caller);
 115     $meta->superclasses('Mouse::Object')
 116         unless $meta->superclasses;
 117
 118     # make a subtype for each Mouse class
 119     class_type($caller) unless find_type_constraint($caller);
 120
 121     no strict 'refs';
 122     no warnings 'redefine';
 123     *{$caller.'::meta'} = sub { $meta };
 124
 125     if (@_) {
 126         __PACKAGE__->export_to_level( $level+1, $class, @_);
 127     } else {
 128         # shortcut for the common case of no type character
 129         no strict 'refs';
 130         for my $keyword (@EXPORT) {
 131             *{ $caller . '::' . $keyword } = *{__PACKAGE__ . '::' . $keyword};
 132         }
 133     }
 134 }
 135
 136 sub unimport {
 137     my $caller = caller;
 138
 139     no strict 'refs';
 140     for my $keyword (@EXPORT) {
 141         delete ${ $caller . '::' }{$keyword};
 142     }
 143 }
 144
 145 sub load_class {
 146     my $class = shift;
 147
 148     if (ref($class) || !defined($class) || !length($class)) {
 149         my $display = defined($class) ? $class : 'undef';
 150         confess "Invalid class name ($display)";
 151     }
 152
 153     return 1 if $class eq 'Mouse::Object';
 154     return 1 if is_class_loaded($class);
 155
 156     (my $file = "$class.pm") =~ s{::}{/}g;
 157
 158     eval { CORE::require($file) };
 159     confess "Could not load class ($class) because : $@" if $@;
 160
 161     return 1;
 162 }
 163
 164 sub is_class_loaded {
 165     my $class = shift;
 166
 167     return 0 if ref($class) || !defined($class) || !length($class);
 168
 169     # walk the symbol table tree to avoid autovififying
 170     # \*{${main::}{"Foo::"}} == \*main::Foo::
 171
 172     my $pack = \*::;
 173     foreach my $part (split('::', $class)) {
 174         return 0 unless exists ${$$pack}{"${part}::"};
 175         $pack = \*{${$$pack}{"${part}::"}};
 176     }
 177
 178     # check for $VERSION or @ISA
 179     return 1 if exists ${$$pack}{VERSION}
 180              && defined *{${$$pack}{VERSION}}{SCALAR};
 181     return 1 if exists ${$$pack}{ISA}
 182              && defined *{${$$pack}{ISA}}{ARRAY};
 183
 184     # check for any method
 185     foreach ( keys %{$$pack} ) {
 186         next if substr($_, -2, 2) eq '::';
 187         return 1 if defined *{${$$pack}{$_}}{CODE};
 188     }
 189
 190     # fail
 191     return 0;
 192 }
 193
 194 sub class_of {
 195     return unless defined $_[0];
 196     my $class = blessed($_[0]) || $_[0];
 197     return Mouse::Meta::Class::get_metaclass_by_name($class);
 198 }
 199
 200 1;
 201
 202 __END__
 203
 204 =head1 NAME
 205
 206 Mouse - Moose minus the antlers
 207
 208 =head1 SYNOPSIS
 209
 210     package Point;
 211     use Mouse; # automatically turns on strict and warnings
 212
 213     has 'x' => (is => 'rw', isa => 'Int');
 214     has 'y' => (is => 'rw', isa => 'Int');
 215
 216     sub clear {
 217         my $self = shift;
 218         $self->x(0);
 219         $self->y(0);
 220     }
 221
 222     package Point3D;
 223     use Mouse;
 224
 225     extends 'Point';
 226
 227     has 'z' => (is => 'rw', isa => 'Int');
 228
 229     after 'clear' => sub {
 230         my $self = shift;
 231         $self->z(0);
 232     };
 233
 234 =head1 DESCRIPTION
 235
 236 L<Moose> is wonderful. B<Use Moose instead of Mouse.>
 237
 238 Unfortunately, Moose has a compile-time penalty. Though significant progress has
 239 been made over the years, the compile time penalty is a non-starter for some
 240 applications.
 241
 242 Mouse aims to alleviate this by providing a subset of Moose's functionality,
 243 faster.
 244
 245 We're also going as light on dependencies as possible.
 246 L<Class::Method::Modifiers> or L<Data::Util> is required if you want support
 247 for L</before>, L</after>, and L</around>.
 248
 249 =head2 MOOSE COMPAT
 250
 251 Compatibility with Moose has been the utmost concern. Fewer than 1% of the
 252 tests fail when run against Moose instead of Mouse. Mouse code coverage is also
 253 over 96%. Even the error messages are taken from Moose. The Mouse code just
 254 runs the test suite 4x faster.
 255
 256 The idea is that, if you need the extra power, you should be able to run
 257 C<s/Mouse/Moose/g> on your codebase and have nothing break. To that end,
 258 we have written L<Any::Moose> which will act as Mouse unless Moose is loaded,
 259 in which case it will act as Moose.
 260
 261 =head2 MouseX
 262
 263 Please don't copy MooseX code to MouseX. If you need extensions, you really
 264 should upgrade to Moose. We don't need two parallel sets of extensions!
 265
 266 If you really must write a Mouse extension, please contact the Moose mailing
 267 list or #moose on IRC beforehand.
 268
 269 =head1 KEYWORDS
 270
 271 =head2 meta -> Mouse::Meta::Class
 272
 273 Returns this class' metaclass instance.
 274
 275 =head2 extends superclasses
 276
 277 Sets this class' superclasses.
 278
 279 =head2 before (method|methods) => Code
 280
 281 Installs a "before" method modifier. See L<Moose/before> or
 282 L<Class::Method::Modifiers/before>.
 283
 284 Use of this feature requires L<Class::Method::Modifiers>!
 285
 286 =head2 after (method|methods) => Code
 287
 288 Installs an "after" method modifier. See L<Moose/after> or
 289 L<Class::Method::Modifiers/after>.
 290
 291 Use of this feature requires L<Class::Method::Modifiers>!
 292
 293 =head2 around (method|methods) => Code
 294
 295 Installs an "around" method modifier. See L<Moose/around> or
 296 L<Class::Method::Modifiers/around>.
 297
 298 Use of this feature requires L<Class::Method::Modifiers>!
 299
 300 =head2 has (name|names) => parameters
 301
 302 Adds an attribute (or if passed an arrayref of names, multiple attributes) to
 303 this class. Options:
 304
 305 =over 4
 306
 307 =item is => ro|rw
 308
 309 If specified, inlines a read-only/read-write accessor with the same name as
 310 the attribute.
 311
 312 =item isa => TypeConstraint
 313
 314 Provides type checking in the constructor and accessor. The following types are
 315 supported. Any unknown type is taken to be a class check (e.g. isa =>
 316 'DateTime' would accept only L<DateTime> objects).
 317
 318     Any Item Bool Undef Defined Value Num Int Str ClassName
 319     Ref ScalarRef ArrayRef HashRef CodeRef RegexpRef GlobRef
 320     FileHandle Object
 321
 322 For more documentation on type constraints, see L<Mouse::Util::TypeConstraints>.
 323
 324
 325 =item required => 0|1
 326
 327 Whether this attribute is required to have a value. If the attribute is lazy or
 328 has a builder, then providing a value for the attribute in the constructor is
 329 optional.
 330
 331 =item init_arg => Str | Undef
 332
 333 Allows you to use a different key name in the constructor.  If undef, the
 334 attribue can't be passed to the constructor.
 335
 336 =item default => Value | CodeRef
 337
 338 Sets the default value of the attribute. If the default is a coderef, it will
 339 be invoked to get the default value. Due to quirks of Perl, any bare reference
 340 is forbidden, you must wrap the reference in a coderef. Otherwise, all
 341 instances will share the same reference.
 342
 343 =item lazy => 0|1
 344
 345 If specified, the default is calculated on demand instead of in the
 346 constructor.
 347
 348 =item predicate => Str
 349
 350 Lets you specify a method name for installing a predicate method, which checks
 351 that the attribute has a value. It will not invoke a lazy default or builder
 352 method.
 353
 354 =item clearer => Str
 355
 356 Lets you specify a method name for installing a clearer method, which clears
 357 the attribute's value from the instance. On the next read, lazy or builder will
 358 be invoked.
 359
 360 =item handles => HashRef|ArrayRef
 361
 362 Lets you specify methods to delegate to the attribute. ArrayRef forwards the
 363 given method names to method calls on the attribute. HashRef maps local method
 364 names to remote method names called on the attribute. Other forms of
 365 L</handles>, such as regular expression and coderef, are not yet supported.
 366
 367 =item weak_ref => 0|1
 368
 369 Lets you automatically weaken any reference stored in the attribute.
 370
 371 Use of this feature requires L<Scalar::Util>!
 372
 373 =item trigger => CodeRef
 374
 375 Any time the attribute's value is set (either through the accessor or the constructor), the trigger is called on it. The trigger receives as arguments the instance, the new value, and the attribute instance.
 376
 377 Mouse 0.05 supported more complex triggers, but this behavior is now removed.
 378
 379 =item builder => Str
 380
 381 Defines a method name to be called to provide the default value of the
 382 attribute. C<< builder => 'build_foo' >> is mostly equivalent to
 383 C<< default => sub { $_[0]->build_foo } >>.
 384
 385 =item auto_deref => 0|1
 386
 387 Allows you to automatically dereference ArrayRef and HashRef attributes in list
 388 context. In scalar context, the reference is returned (NOT the list length or
 389 bucket status). You must specify an appropriate type constraint to use
 390 auto_deref.
 391
 392 =item lazy_build => 0|1
 393
 394 Automatically define lazy => 1 as well as builder => "_build_$attr", clearer =>
 395 "clear_$attr', predicate => 'has_$attr' unless they are already defined.
 396
 397 =back
 398
 399 =head2 confess error -> BOOM
 400
 401 L<Carp/confess> for your convenience.
 402
 403 =head2 blessed value -> ClassName | undef
 404
 405 L<Scalar::Util/blessed> for your convenience.
 406
 407 =head1 MISC
 408
 409 =head2 import
 410
 411 Importing Mouse will default your class' superclass list to L<Mouse::Object>.
 412 You may use L</extends> to replace the superclass list.
 413
 414 =head2 unimport
 415
 416 Please unimport Mouse (C<no Mouse>) so that if someone calls one of the
 417 keywords (such as L</extends>) it will break loudly instead breaking subtly.
 418
 419 =head1 FUNCTIONS
 420
 421 =head2 load_class Class::Name
 422
 423 This will load a given C<Class::Name> (or die if it's not loadable).
 424 This function can be used in place of tricks like
 425 C<eval "use $module"> or using C<require>.
 426
 427 =head2 is_class_loaded Class::Name -> Bool
 428
 429 Returns whether this class is actually loaded or not. It uses a heuristic which
 430 involves checking for the existence of C<$VERSION>, C<@ISA>, and any
 431 locally-defined method.
 432
 433 =head1 SOURCE CODE ACCESS
 434
 435 We have a public git repo:
 436
 437  git clone git://jules.scsys.co.uk/gitmo/Mouse.git
 438
 439 =head1 AUTHORS
 440
 441 Shawn M Moore, C<< <sartak at gmail.com> >>
 442
 443 Yuval Kogman, C<< <nothingmuch at woobling.org> >>
 444
 445 tokuhirom
 446
 447 Yappo
 448
 449 wu-lee
 450
 451 with plenty of code borrowed from L<Class::MOP> and L<Moose>
 452
 453 =head1 BUGS
 454
 455 There is a known issue with Mouse on 5.6.2 regarding the @ISA tests. Until
 456 this is resolve the minimum version of Perl for Mouse is set to 5.8.0. Patches
 457 to resolve these tests are more than welcome.
 458
 459 Please report any bugs through RT: email
 460 C<bug-mouse at rt.cpan.org>, or browse
 461 L<http://rt.cpan.org/NoAuth/ReportBug.html?Queue=Mouse>.
 462
 463 =head1 COPYRIGHT AND LICENSE
 464
 465 Copyright 2008 Shawn M Moore.
 466
 467 This program is free software; you can redistribute it and/or modify it
 468 under the same terms as Perl itself.
 469
 470 =cut
 471