lib/Mouse.pm

   1 package Mouse;
   2 use strict;
   3 use warnings;
   4 use 5.006;
   5 use base 'Exporter';
   6
   7 our $VERSION = '0.15';
   8
   9 BEGIN {
  10     if ($ENV{MOUSE_DEBUG}) {
  11         *DEBUG = sub (){ 1 };
  12     } else {
  13         *DEBUG = sub (){ 0 };
  14     }
  15 }
  16
  17 use Carp 'confess';
  18 use Scalar::Util 'blessed';
  19 use Mouse::Util;
  20
  21 use Mouse::Meta::Attribute;
  22 use Mouse::Meta::Class;
  23 use Mouse::Object;
  24 use Mouse::Util::TypeConstraints;
  25
  26 our @EXPORT = qw(extends has before after around blessed confess with);
  27
  28 sub extends { Mouse::Meta::Class->initialize(caller)->superclasses(@_) }
  29
  30 sub has {
  31     my $meta = Mouse::Meta::Class->initialize(caller);
  32
  33     my $names = shift;
  34     $names = [$names] if !ref($names);
  35
  36     for my $name (@$names) {
  37         if ($name =~ s/^\+//) {
  38             Mouse::Meta::Attribute->clone_parent($meta, $name, @_);
  39         }
  40         else {
  41             Mouse::Meta::Attribute->create($meta, $name, @_);
  42         }
  43     }
  44 }
  45
  46 sub before {
  47     my $meta = Mouse::Meta::Class->initialize(caller);
  48
  49     my $code = pop;
  50
  51     for (@_) {
  52         $meta->add_before_method_modifier($_ => $code);
  53     }
  54 }
  55
  56 sub after {
  57     my $meta = Mouse::Meta::Class->initialize(caller);
  58
  59     my $code = pop;
  60
  61     for (@_) {
  62         $meta->add_after_method_modifier($_ => $code);
  63     }
  64 }
  65
  66 sub around {
  67     my $meta = Mouse::Meta::Class->initialize(caller);
  68
  69     my $code = pop;
  70
  71     for (@_) {
  72         $meta->add_around_method_modifier($_ => $code);
  73     }
  74 }
  75
  76 sub with {
  77     Mouse::Util::apply_all_roles((caller)[0], @_);
  78 }
  79
  80 sub import {
  81     my $class = shift;
  82
  83     strict->import;
  84     warnings->import;
  85
  86     my $caller = caller;
  87
  88     # we should never export to main
  89     if ($caller eq 'main') {
  90         warn qq{$class does not export its sugar to the 'main' package.\n};
  91         return;
  92     }
  93
  94     my $meta = Mouse::Meta::Class->initialize($caller);
  95     $meta->superclasses('Mouse::Object')
  96         unless $meta->superclasses;
  97
  98     no strict 'refs';
  99     no warnings 'redefine';
 100     *{$caller.'::meta'} = sub { $meta };
 101
 102     if (@_) {
 103         __PACKAGE__->export_to_level( 1, $class, @_);
 104     } else {
 105         # shortcut for the common case of no type character
 106         no strict 'refs';
 107         for my $keyword (@EXPORT) {
 108             *{ $caller . '::' . $keyword } = *{__PACKAGE__ . '::' . $keyword};
 109         }
 110     }
 111 }
 112
 113 sub unimport {
 114     my $caller = caller;
 115
 116     no strict 'refs';
 117     for my $keyword (@EXPORT) {
 118         delete ${ $caller . '::' }{$keyword};
 119     }
 120 }
 121
 122 sub load_class {
 123     my $class = shift;
 124
 125     if (ref($class) || !defined($class) || !length($class)) {
 126         my $display = defined($class) ? $class : 'undef';
 127         confess "Invalid class name ($display)";
 128     }
 129
 130     return 1 if $class eq 'Mouse::Object';
 131     return 1 if is_class_loaded($class);
 132
 133     (my $file = "$class.pm") =~ s{::}{/}g;
 134
 135     eval { CORE::require($file) };
 136     confess "Could not load class ($class) because : $@" if $@;
 137
 138     return 1;
 139 }
 140
 141 sub is_class_loaded {
 142     my $class = shift;
 143
 144     return 0 if ref($class) || !defined($class) || !length($class);
 145
 146     # walk the symbol table tree to avoid autovififying
 147     # \*{${main::}{"Foo::"}} == \*main::Foo::
 148
 149     my $pack = \*::;
 150     foreach my $part (split('::', $class)) {
 151         return 0 unless exists ${$$pack}{"${part}::"};
 152         $pack = \*{${$$pack}{"${part}::"}};
 153     }
 154
 155     # check for $VERSION or @ISA
 156     return 1 if exists ${$$pack}{VERSION}
 157              && defined *{${$$pack}{VERSION}}{SCALAR};
 158     return 1 if exists ${$$pack}{ISA}
 159              && defined *{${$$pack}{ISA}}{ARRAY};
 160
 161     # check for any method
 162     foreach ( keys %{$$pack} ) {
 163         next if substr($_, -2, 2) eq '::';
 164         return 1 if defined *{${$$pack}{$_}}{CODE};
 165     }
 166
 167     # fail
 168     return 0;
 169 }
 170
 171 1;
 172
 173 __END__
 174
 175 =head1 NAME
 176
 177 Mouse - Moose minus the antlers
 178
 179 =head1 SYNOPSIS
 180
 181     package Point;
 182     use Mouse; # automatically turns on strict and warnings
 183
 184     has 'x' => (is => 'rw', isa => 'Int');
 185     has 'y' => (is => 'rw', isa => 'Int');
 186
 187     sub clear {
 188         my $self = shift;
 189         $self->x(0);
 190         $self->y(0);
 191     }
 192
 193     package Point3D;
 194     use Mouse;
 195
 196     extends 'Point';
 197
 198     has 'z' => (is => 'rw', isa => 'Int');
 199
 200     after 'clear' => sub {
 201         my $self = shift;
 202         $self->z(0);
 203     };
 204
 205 =head1 DESCRIPTION
 206
 207 L<Moose> is wonderful.
 208
 209 Unfortunately, it's a little slow. Though significant progress has been made
 210 over the years, the compile time penalty is a non-starter for some
 211 applications.
 212
 213 Mouse aims to alleviate this by providing a subset of Moose's
 214 functionality, faster. In particular, L<Moose/has> is missing only a few
 215 expert-level features.
 216
 217 We're also going as light on dependencies as possible. Most functions we use
 218 from L<Scalar::Util> are copied into this dist. L<Scalar::Util> is required if
 219 you'd like weak references; there's simply no way to do it from pure Perl.
 220 L<Class::Method::Modifiers> is required if you want support for L</before>,
 221 L</after>, and L</around>.
 222
 223 =head2 MOOSE COMPAT
 224
 225 Compatibility with Moose has been the utmost concern. Fewer than 1% of the
 226 tests fail when run against Moose instead of Mouse. Mouse code coverage is also
 227 over 96%. Even the error messages are taken from Moose. The Mouse code just
 228 runs the test suite 4x faster.
 229
 230 The idea is that, if you need the extra power, you should be able to run
 231 C<s/Mouse/Moose/g> on your codebase and have nothing break. To that end,
 232 nothingmuch has written L<Squirrel> (part of this distribution) which will act
 233 as Mouse unless Moose is loaded, in which case it will act as Moose.
 234
 235 Mouse also has the blessings of Moose's author, stevan.
 236
 237 =head2 MouseX
 238
 239 Please don't copy MooseX code to MouseX. If you need extensions, you really
 240 should upgrade to Moose. We don't need two parallel sets of extensions!
 241
 242 If you really must write a Mouse extension, please contact the Moose mailing
 243 list or #moose on IRC beforehand.
 244
 245 =head1 KEYWORDS
 246
 247 =head2 meta -> Mouse::Meta::Class
 248
 249 Returns this class' metaclass instance.
 250
 251 =head2 extends superclasses
 252
 253 Sets this class' superclasses.
 254
 255 =head2 before (method|methods) => Code
 256
 257 Installs a "before" method modifier. See L<Moose/before> or
 258 L<Class::Method::Modifiers/before>.
 259
 260 Use of this feature requires L<Class::Method::Modifiers>!
 261
 262 =head2 after (method|methods) => Code
 263
 264 Installs an "after" method modifier. See L<Moose/after> or
 265 L<Class::Method::Modifiers/after>.
 266
 267 Use of this feature requires L<Class::Method::Modifiers>!
 268
 269 =head2 around (method|methods) => Code
 270
 271 Installs an "around" method modifier. See L<Moose/around> or
 272 L<Class::Method::Modifiers/around>.
 273
 274 Use of this feature requires L<Class::Method::Modifiers>!
 275
 276 =head2 has (name|names) => parameters
 277
 278 Adds an attribute (or if passed an arrayref of names, multiple attributes) to
 279 this class. Options:
 280
 281 =over 4
 282
 283 =item is => ro|rw
 284
 285 If specified, inlines a read-only/read-write accessor with the same name as
 286 the attribute.
 287
 288 =item isa => TypeConstraint
 289
 290 Provides basic type checking in the constructor and accessor. Basic types such
 291 as C<Int>, C<ArrayRef>, C<Defined> are supported. Any unknown type is taken to
 292 be a class check (e.g. isa => 'DateTime' would accept only L<DateTime>
 293 objects).
 294
 295 =item required => 0|1
 296
 297 Whether this attribute is required to have a value. If the attribute is lazy or
 298 has a builder, then providing a value for the attribute in the constructor is
 299 optional.
 300
 301 =item init_arg => Str | Undef
 302
 303 Allows you to use a different key name in the constructor.  If undef, the
 304 attribue can't be passed to the constructor.
 305
 306 =item default => Value | CodeRef
 307
 308 Sets the default value of the attribute. If the default is a coderef, it will
 309 be invoked to get the default value. Due to quirks of Perl, any bare reference
 310 is forbidden, you must wrap the reference in a coderef. Otherwise, all
 311 instances will share the same reference.
 312
 313 =item lazy => 0|1
 314
 315 If specified, the default is calculated on demand instead of in the
 316 constructor.
 317
 318 =item predicate => Str
 319
 320 Lets you specify a method name for installing a predicate method, which checks
 321 that the attribute has a value. It will not invoke a lazy default or builder
 322 method.
 323
 324 =item clearer => Str
 325
 326 Lets you specify a method name for installing a clearer method, which clears
 327 the attribute's value from the instance. On the next read, lazy or builder will
 328 be invoked.
 329
 330 =item handles => HashRef|ArrayRef
 331
 332 Lets you specify methods to delegate to the attribute. ArrayRef forwards the
 333 given method names to method calls on the attribute. HashRef maps local method
 334 names to remote method names called on the attribute. Other forms of
 335 L</handles>, such as regular expression and coderef, are not yet supported.
 336
 337 =item weak_ref => 0|1
 338
 339 Lets you automatically weaken any reference stored in the attribute.
 340
 341 Use of this feature requires L<Scalar::Util>!
 342
 343 =item trigger => CodeRef
 344
 345 Any time the attribute's value is set (either through the accessor or the constructor), the trigger is called on it. The trigger receives as arguments the instance, the new value, and the attribute instance.
 346
 347 Mouse 0.05 supported more complex triggers, but this behavior is now removed.
 348
 349 =item builder => Str
 350
 351 Defines a method name to be called to provide the default value of the
 352 attribute. C<< builder => 'build_foo' >> is mostly equivalent to
 353 C<< default => sub { $_[0]->build_foo } >>.
 354
 355 =item auto_deref => 0|1
 356
 357 Allows you to automatically dereference ArrayRef and HashRef attributes in list
 358 context. In scalar context, the reference is returned (NOT the list length or
 359 bucket status). You must specify an appropriate type constraint to use
 360 auto_deref.
 361
 362 =item lazy_build => 0|1
 363
 364 Automatically define lazy => 1 as well as builder => "_build_$attr", clearer =>
 365 "clear_$attr', predicate => 'has_$attr' unless they are already defined.
 366
 367 =back
 368
 369 =head2 confess error -> BOOM
 370
 371 L<Carp/confess> for your convenience.
 372
 373 =head2 blessed value -> ClassName | undef
 374
 375 L<Scalar::Util/blessed> for your convenience.
 376
 377 =head1 MISC
 378
 379 =head2 import
 380
 381 Importing Mouse will default your class' superclass list to L<Mouse::Object>.
 382 You may use L</extends> to replace the superclass list.
 383
 384 =head2 unimport
 385
 386 Please unimport Mouse (C<no Mouse>) so that if someone calls one of the
 387 keywords (such as L</extends>) it will break loudly instead breaking subtly.
 388
 389 =head1 FUNCTIONS
 390
 391 =head2 load_class Class::Name
 392
 393 This will load a given C<Class::Name> (or die if it's not loadable).
 394 This function can be used in place of tricks like
 395 C<eval "use $module"> or using C<require>.
 396
 397 =head2 is_class_loaded Class::Name -> Bool
 398
 399 Returns whether this class is actually loaded or not. It uses a heuristic which
 400 involves checking for the existence of C<$VERSION>, C<@ISA>, and any
 401 locally-defined method.
 402
 403 =head1 AUTHORS
 404
 405 Shawn M Moore, C<< <sartak at gmail.com> >>
 406
 407 Yuval Kogman, C<< <nothingmuch at woobling.org> >>
 408
 409 tokuhirom
 410
 411 Yappo
 412
 413 with plenty of code borrowed from L<Class::MOP> and L<Moose>
 414
 415 =head1 BUGS
 416
 417 No known bugs.
 418
 419 Please report any bugs through RT: email
 420 C<bug-mouse at rt.cpan.org>, or browse
 421 L<http://rt.cpan.org/NoAuth/ReportBug.html?Queue=Mouse>.
 422
 423 =head1 COPYRIGHT AND LICENSE
 424
 425 Copyright 2008 Shawn M Moore.
 426
 427 This program is free software; you can redistribute it and/or modify it
 428 under the same terms as Perl itself.
 429
 430 =cut
 431