lib/Mouse.pm

   1 #!/usr/bin/env perl
   2 package Mouse;
   3 use strict;
   4 use warnings;
   5 use base 'Exporter';
   6
   7 our $VERSION = '0.08';
   8 use 5.006;
   9
  10 use Carp 'confess';
  11 use Mouse::Util 'blessed';
  12
  13 use Mouse::Meta::Attribute;
  14 use Mouse::Meta::Class;
  15 use Mouse::Object;
  16 use Mouse::TypeRegistry;
  17
  18 our @EXPORT = qw(extends has before after around blessed confess with);
  19
  20 sub extends { Mouse::Meta::Class->initialize(caller)->superclasses(@_) }
  21
  22 sub has {
  23     my $meta = Mouse::Meta::Class->initialize(caller);
  24
  25     my $names = shift;
  26     $names = [$names] if !ref($names);
  27
  28     for my $name (@$names) {
  29         if ($name =~ s/^\+//) {
  30             Mouse::Meta::Attribute->clone_parent($meta, $name, @_);
  31         }
  32         else {
  33             Mouse::Meta::Attribute->create($meta, $name, @_);
  34         }
  35     }
  36 }
  37
  38 sub before {
  39     my $meta = Mouse::Meta::Class->initialize(caller);
  40
  41     my $code = pop;
  42
  43     for (@_) {
  44         $meta->add_before_method_modifier($_ => $code);
  45     }
  46 }
  47
  48 sub after {
  49     my $meta = Mouse::Meta::Class->initialize(caller);
  50
  51     my $code = pop;
  52
  53     for (@_) {
  54         $meta->add_after_method_modifier($_ => $code);
  55     }
  56 }
  57
  58 sub around {
  59     my $meta = Mouse::Meta::Class->initialize(caller);
  60
  61     my $code = pop;
  62
  63     for (@_) {
  64         $meta->add_around_method_modifier($_ => $code);
  65     }
  66 }
  67
  68 sub with {
  69     my $meta = Mouse::Meta::Class->initialize(caller);
  70
  71     my $role  = shift;
  72
  73     confess "Mouse::Role only supports 'with' on individual roles at a time" if @_;
  74
  75     Mouse::load_class($role);
  76     $role->meta->apply($meta);
  77 }
  78
  79 sub import {
  80     strict->import;
  81     warnings->import;
  82
  83     my $caller = caller;
  84
  85     my $meta = Mouse::Meta::Class->initialize($caller);
  86     $meta->superclasses('Mouse::Object')
  87         unless $meta->superclasses;
  88
  89     no strict 'refs';
  90     no warnings 'redefine';
  91     *{$caller.'::meta'} = sub { $meta };
  92
  93     Mouse->export_to_level(1, @_);
  94 }
  95
  96 sub unimport {
  97     my $caller = caller;
  98
  99     no strict 'refs';
 100     for my $keyword (@EXPORT) {
 101         delete ${ $caller . '::' }{$keyword};
 102     }
 103 }
 104
 105 sub load_class {
 106     my $class = shift;
 107
 108     if (ref($class) || !defined($class) || !length($class)) {
 109         my $display = defined($class) ? $class : 'undef';
 110         confess "Invalid class name ($display)";
 111     }
 112
 113     return 1 if is_class_loaded($class);
 114
 115     (my $file = "$class.pm") =~ s{::}{/}g;
 116
 117     eval { CORE::require($file) };
 118     confess "Could not load class ($class) because : $@" if $@;
 119
 120     return 1;
 121 }
 122
 123 sub is_class_loaded {
 124     my $class = shift;
 125
 126     return 0 if ref($class) || !defined($class) || !length($class);
 127
 128     # walk the symbol table tree to avoid autovififying
 129     # \*{${main::}{"Foo::"}} == \*main::Foo::
 130
 131     my $pack = \*::;
 132     foreach my $part (split('::', $class)) {
 133         return 0 unless exists ${$$pack}{"${part}::"};
 134         $pack = \*{${$$pack}{"${part}::"}};
 135     }
 136
 137     # check for $VERSION or @ISA
 138     return 1 if exists ${$$pack}{VERSION}
 139              && defined *{${$$pack}{VERSION}}{SCALAR};
 140     return 1 if exists ${$$pack}{ISA}
 141              && defined *{${$$pack}{ISA}}{ARRAY};
 142
 143     # check for any method
 144     foreach ( keys %{$$pack} ) {
 145         next if substr($_, -2, 2) eq '::';
 146         return 1 if defined *{${$$pack}{$_}}{CODE};
 147     }
 148
 149     # fail
 150     return 0;
 151 }
 152
 153 1;
 154
 155 __END__
 156
 157 =head1 NAME
 158
 159 Mouse - Moose minus the antlers
 160
 161 =head1 SYNOPSIS
 162
 163     package Point;
 164     use Mouse; # automatically turns on strict and warnings
 165
 166     has 'x' => (is => 'rw', isa => 'Int');
 167     has 'y' => (is => 'rw', isa => 'Int');
 168
 169     sub clear {
 170         my $self = shift;
 171         $self->x(0);
 172         $self->y(0);
 173     }
 174
 175     package Point3D;
 176     use Mouse;
 177
 178     extends 'Point';
 179
 180     has 'z' => (is => 'rw', isa => 'Int');
 181
 182     after 'clear' => sub {
 183         my $self = shift;
 184         $self->z(0);
 185     };
 186
 187 =head1 DESCRIPTION
 188
 189 L<Moose> is wonderful.
 190
 191 Unfortunately, it's a little slow. Though significant progress has been made
 192 over the years, the compile time penalty is a non-starter for some
 193 applications.
 194
 195 Mouse aims to alleviate this by providing a subset of Moose's
 196 functionality, faster. In particular, L<Moose/has> is missing only a few
 197 expert-level features.
 198
 199 We're also going as light on dependencies as possible. Most functions we use
 200 from L<Scalar::Util> are copied into this dist. L<Scalar::Util> is required if
 201 you'd like weak references; there's simply no way to do it from pure Perl.
 202 L<Class::Method::Modifiers> is required if you want support for L</before>,
 203 L</after>, and L</around>.
 204
 205 =head2 MOOSE COMPAT
 206
 207 Compatibility with Moose has been the utmost concern. Fewer than 1% of the
 208 tests fail when run against Moose instead of Mouse. Mouse code coverage is also
 209 over 96%. Even the error messages are taken from Moose. The Mouse code just
 210 runs the test suite 4x faster.
 211
 212 The idea is that, if you need the extra power, you should be able to run
 213 C<s/Mouse/Moose/g> on your codebase and have nothing break. To that end,
 214 nothingmuch has written L<Squirrel> (part of this distribution) which will act
 215 as Mouse unless Moose is loaded, in which case it will act as Moose.
 216
 217 Mouse also has the blessings of Moose's author, stevan.
 218
 219 =head2 MISSING FEATURES
 220
 221 =head3 Roles
 222
 223 We're working on fixing this one! stevan has suggested an implementation
 224 strategy. Mouse currently ignores methods, so that needs to be fixed next.
 225 Roles that consist entirely of attributes may be usable in this very version.
 226
 227 =head3 Complex types
 228
 229 User-defined type constraints and parameterized types may be implemented. Type
 230 coercions probably not (patches welcome).
 231
 232 =head3 Bootstrapped meta world
 233
 234 Very handy for extensions to the MOP. Not pressing, but would be nice to have.
 235
 236 =head3 Modification of attribute metaclass
 237
 238 When you declare an attribute with L</has>, you get the inlined accessors
 239 installed immediately. Modifying the attribute metaclass, even if possible,
 240 does nothing.
 241
 242 =head3 Lots more..
 243
 244 MouseX?
 245
 246 =head1 KEYWORDS
 247
 248 =head2 meta -> Mouse::Meta::Class
 249
 250 Returns this class' metaclass instance.
 251
 252 =head2 extends superclasses
 253
 254 Sets this class' superclasses.
 255
 256 =head2 before (method|methods) => Code
 257
 258 Installs a "before" method modifier. See L<Moose/before> or
 259 L<Class::Method::Modifiers/before>.
 260
 261 =head2 after (method|methods) => Code
 262
 263 Installs an "after" method modifier. See L<Moose/after> or
 264 L<Class::Method::Modifiers/after>.
 265
 266 =head2 around (method|methods) => Code
 267
 268 Installs an "around" method modifier. See L<Moose/around> or
 269 L<Class::Method::Modifiers/around>.
 270
 271 =head2 has (name|names) => parameters
 272
 273 Adds an attribute (or if passed an arrayref of names, multiple attributes) to
 274 this class. Options:
 275
 276 =over 4
 277
 278 =item is => ro|rw
 279
 280 If specified, inlines a read-only/read-write accessor with the same name as
 281 the attribute.
 282
 283 =item isa => TypeConstraint
 284
 285 Provides basic type checking in the constructor and accessor. Basic types such
 286 as C<Int>, C<ArrayRef>, C<Defined> are supported. Any unknown type is taken to
 287 be a class check (e.g. isa => 'DateTime' would accept only L<DateTime>
 288 objects).
 289
 290 =item required => 0|1
 291
 292 Whether this attribute is required to have a value. If the attribute is lazy or
 293 has a builder, then providing a value for the attribute in the constructor is
 294 optional.
 295
 296 =item init_arg => Str
 297
 298 Allows you to use a different key name in the constructor.
 299
 300 =item default => Value | CodeRef
 301
 302 Sets the default value of the attribute. If the default is a coderef, it will
 303 be invoked to get the default value. Due to quirks of Perl, any bare reference
 304 is forbidden, you must wrap the reference in a coderef. Otherwise, all
 305 instances will share the same reference.
 306
 307 =item lazy => 0|1
 308
 309 If specified, the default is calculated on demand instead of in the
 310 constructor.
 311
 312 =item predicate => Str
 313
 314 Lets you specify a method name for installing a predicate method, which checks
 315 that the attribute has a value. It will not invoke a lazy default or builder
 316 method.
 317
 318 =item clearer => Str
 319
 320 Lets you specify a method name for installing a clearer method, which clears
 321 the attribute's value from the instance. On the next read, lazy or builder will
 322 be invoked.
 323
 324 =item handles => HashRef|ArrayRef
 325
 326 Lets you specify methods to delegate to the attribute. ArrayRef forwards the
 327 given method names to method calls on the attribute. HashRef maps local method
 328 names to remote method names called on the attribute. Other forms of
 329 L</handles>, such as regular expression and coderef, are not yet supported.
 330
 331 =item weak_ref => 0|1
 332
 333 Lets you automatically weaken any reference stored in the attribute.
 334
 335 =item trigger => CodeRef
 336
 337 Any time the attribute's value is set (either through the accessor or the constructor), the trigger is called on it. The trigger receives as arguments the instance, the new value, and the attribute instance.
 338
 339 Mouse 0.05 supported more complex triggers, but this behavior is now deprecated.
 340
 341 =item builder => Str
 342
 343 Defines a method name to be called to provide the default value of the
 344 attribute. C<< builder => 'build_foo' >> is mostly equivalent to
 345 C<< default => sub { $_[0]->build_foo } >>.
 346
 347 =item auto_deref => 0|1
 348
 349 Allows you to automatically dereference ArrayRef and HashRef attributes in list
 350 context. In scalar context, the reference is returned (NOT the list length or
 351 bucket status). You must specify an appropriate type constraint to use
 352 auto_deref.
 353
 354 =back
 355
 356 =head2 confess error -> BOOM
 357
 358 L<Carp/confess> for your convenience.
 359
 360 =head2 blessed value -> ClassName | undef
 361
 362 L<Scalar::Util/blessed> for your convenience.
 363
 364 =head1 MISC
 365
 366 =head2 import
 367
 368 Importing Mouse will default your class' superclass list to L<Mouse::Object>.
 369 You may use L</extends> to replace the superclass list.
 370
 371 =head2 unimport
 372
 373 Please unimport Mouse (C<no Mouse>) so that if someone calls one of the
 374 keywords (such as L</extends>) it will break loudly instead breaking subtly.
 375
 376 =head1 FUNCTIONS
 377
 378 =head2 load_class Class::Name
 379
 380 This will load a given C<Class::Name> (or die if it's not loadable).
 381 This function can be used in place of tricks like
 382 C<eval "use $module"> or using C<require>.
 383
 384 =head2 is_class_loaded Class::Name -> Bool
 385
 386 Returns whether this class is actually loaded or not. It uses a heuristic which
 387 involves checking for the existence of C<$VERSION>, C<@ISA>, and any
 388 locally-defined method.
 389
 390 =head1 AUTHOR
 391
 392 Shawn M Moore, C<< <sartak at gmail.com> >>
 393
 394 with plenty of code borrowed from L<Class::MOP> and L<Moose>
 395
 396 =head1 BUGS
 397
 398 No known bugs.
 399
 400 Please report any bugs through RT: email
 401 C<bug-mouse at rt.cpan.org>, or browse
 402 L<http://rt.cpan.org/NoAuth/ReportBug.html?Queue=Mouse>.
 403
 404 =head1 COPYRIGHT AND LICENSE
 405
 406 Copyright 2008 Shawn M Moore.
 407
 408 This program is free software; you can redistribute it and/or modify it
 409 under the same terms as Perl itself.
 410
 411 =cut
 412