lib/Mouse.pm

   1 package Mouse;
   2 use strict;
   3 use warnings;
   4 use 5.006;
   5 use base 'Exporter';
   6
   7 our $VERSION = '0.15';
   8
   9 BEGIN {
  10     if ($ENV{MOUSE_DEBUG}) {
  11         *DEBUG = sub (){ 1 };
  12     } else {
  13         *DEBUG = sub (){ 0 };
  14     }
  15 }
  16
  17 use Carp 'confess';
  18 use Scalar::Util 'blessed';
  19 use Mouse::Util;
  20
  21 use Mouse::Meta::Attribute;
  22 use Mouse::Meta::Class;
  23 use Mouse::Object;
  24 use Mouse::Util::TypeConstraints;
  25
  26 our @EXPORT = qw(extends has before after around blessed confess with);
  27
  28 sub extends { Mouse::Meta::Class->initialize(caller)->superclasses(@_) }
  29
  30 sub has {
  31     my $meta = Mouse::Meta::Class->initialize(caller);
  32
  33     my $names = shift;
  34     $names = [$names] if !ref($names);
  35
  36     for my $name (@$names) {
  37         if ($name =~ s/^\+//) {
  38             Mouse::Meta::Attribute->clone_parent($meta, $name, @_);
  39         }
  40         else {
  41             Mouse::Meta::Attribute->create($meta, $name, @_);
  42         }
  43     }
  44 }
  45
  46 sub before {
  47     my $meta = Mouse::Meta::Class->initialize(caller);
  48
  49     my $code = pop;
  50
  51     for (@_) {
  52         $meta->add_before_method_modifier($_ => $code);
  53     }
  54 }
  55
  56 sub after {
  57     my $meta = Mouse::Meta::Class->initialize(caller);
  58
  59     my $code = pop;
  60
  61     for (@_) {
  62         $meta->add_after_method_modifier($_ => $code);
  63     }
  64 }
  65
  66 sub around {
  67     my $meta = Mouse::Meta::Class->initialize(caller);
  68
  69     my $code = pop;
  70
  71     for (@_) {
  72         $meta->add_around_method_modifier($_ => $code);
  73     }
  74 }
  75
  76 sub with {
  77     Mouse::Util::apply_all_roles((caller)[0], @_);
  78 }
  79
  80 sub import {
  81     my $class = shift;
  82
  83     strict->import;
  84     warnings->import;
  85
  86     my $caller = caller;
  87
  88     # we should never export to main
  89     if ($caller eq 'main') {
  90         warn qq{$class does not export its sugar to the 'main' package.\n};
  91         return;
  92     }
  93
  94     my $meta = Mouse::Meta::Class->initialize($caller);
  95     $meta->superclasses('Mouse::Object')
  96         unless $meta->superclasses;
  97
  98     no strict 'refs';
  99     no warnings 'redefine';
 100     *{$caller.'::meta'} = sub { $meta };
 101
 102     if (@_) {
 103         __PACKAGE__->export_to_level( 1, $class, @_);
 104     } else {
 105         # shortcut for the common case of no type character
 106         no strict 'refs';
 107         for my $keyword (@EXPORT) {
 108             *{ $caller . '::' . $keyword } = *{__PACKAGE__ . '::' . $keyword};
 109         }
 110     }
 111 }
 112
 113 sub unimport {
 114     my $caller = caller;
 115
 116     no strict 'refs';
 117     for my $keyword (@EXPORT) {
 118         delete ${ $caller . '::' }{$keyword};
 119     }
 120 }
 121
 122 sub load_class {
 123     my $class = shift;
 124
 125     if (ref($class) || !defined($class) || !length($class)) {
 126         my $display = defined($class) ? $class : 'undef';
 127         confess "Invalid class name ($display)";
 128     }
 129
 130     return 1 if $class eq 'Mouse::Object';
 131     return 1 if is_class_loaded($class);
 132
 133     (my $file = "$class.pm") =~ s{::}{/}g;
 134
 135     eval { CORE::require($file) };
 136     confess "Could not load class ($class) because : $@" if $@;
 137
 138     return 1;
 139 }
 140
 141 sub is_class_loaded {
 142     my $class = shift;
 143
 144     return 0 if ref($class) || !defined($class) || !length($class);
 145
 146     # walk the symbol table tree to avoid autovififying
 147     # \*{${main::}{"Foo::"}} == \*main::Foo::
 148
 149     my $pack = \*::;
 150     foreach my $part (split('::', $class)) {
 151         return 0 unless exists ${$$pack}{"${part}::"};
 152         $pack = \*{${$$pack}{"${part}::"}};
 153     }
 154
 155     # check for $VERSION or @ISA
 156     return 1 if exists ${$$pack}{VERSION}
 157              && defined *{${$$pack}{VERSION}}{SCALAR};
 158     return 1 if exists ${$$pack}{ISA}
 159              && defined *{${$$pack}{ISA}}{ARRAY};
 160
 161     # check for any method
 162     foreach ( keys %{$$pack} ) {
 163         next if substr($_, -2, 2) eq '::';
 164         return 1 if defined *{${$$pack}{$_}}{CODE};
 165     }
 166
 167     # fail
 168     return 0;
 169 }
 170
 171 1;
 172
 173 __END__
 174
 175 =head1 NAME
 176
 177 Mouse - Moose minus the antlers
 178
 179 =head1 SYNOPSIS
 180
 181     package Point;
 182     use Mouse; # automatically turns on strict and warnings
 183
 184     has 'x' => (is => 'rw', isa => 'Int');
 185     has 'y' => (is => 'rw', isa => 'Int');
 186
 187     sub clear {
 188         my $self = shift;
 189         $self->x(0);
 190         $self->y(0);
 191     }
 192
 193     package Point3D;
 194     use Mouse;
 195
 196     extends 'Point';
 197
 198     has 'z' => (is => 'rw', isa => 'Int');
 199
 200     after 'clear' => sub {
 201         my $self = shift;
 202         $self->z(0);
 203     };
 204
 205 =head1 DESCRIPTION
 206
 207 L<Moose> is wonderful.
 208
 209 Unfortunately, it's a little slow. Though significant progress has been made
 210 over the years, the compile time penalty is a non-starter for some
 211 applications.
 212
 213 Mouse aims to alleviate this by providing a subset of Moose's
 214 functionality, faster. In particular, L<Moose/has> is missing only a few
 215 expert-level features.
 216
 217 We're also going as light on dependencies as possible. Most functions we use
 218 from L<Scalar::Util> are copied into this dist. L<Scalar::Util> is required if
 219 you'd like weak references; there's simply no way to do it from pure Perl.
 220 L<Class::Method::Modifiers> is required if you want support for L</before>,
 221 L</after>, and L</around>.
 222
 223 =head2 MOOSE COMPAT
 224
 225 Compatibility with Moose has been the utmost concern. Fewer than 1% of the
 226 tests fail when run against Moose instead of Mouse. Mouse code coverage is also
 227 over 96%. Even the error messages are taken from Moose. The Mouse code just
 228 runs the test suite 4x faster.
 229
 230 The idea is that, if you need the extra power, you should be able to run
 231 C<s/Mouse/Moose/g> on your codebase and have nothing break. To that end,
 232 nothingmuch has written L<Squirrel> (part of this distribution) which will act
 233 as Mouse unless Moose is loaded, in which case it will act as Moose.
 234
 235 Mouse also has the blessings of Moose's author, stevan.
 236
 237 =head1 KEYWORDS
 238
 239 =head2 meta -> Mouse::Meta::Class
 240
 241 Returns this class' metaclass instance.
 242
 243 =head2 extends superclasses
 244
 245 Sets this class' superclasses.
 246
 247 =head2 before (method|methods) => Code
 248
 249 Installs a "before" method modifier. See L<Moose/before> or
 250 L<Class::Method::Modifiers/before>.
 251
 252 Use of this feature requires L<Class::Method::Modifiers>!
 253
 254 =head2 after (method|methods) => Code
 255
 256 Installs an "after" method modifier. See L<Moose/after> or
 257 L<Class::Method::Modifiers/after>.
 258
 259 Use of this feature requires L<Class::Method::Modifiers>!
 260
 261 =head2 around (method|methods) => Code
 262
 263 Installs an "around" method modifier. See L<Moose/around> or
 264 L<Class::Method::Modifiers/around>.
 265
 266 Use of this feature requires L<Class::Method::Modifiers>!
 267
 268 =head2 has (name|names) => parameters
 269
 270 Adds an attribute (or if passed an arrayref of names, multiple attributes) to
 271 this class. Options:
 272
 273 =over 4
 274
 275 =item is => ro|rw
 276
 277 If specified, inlines a read-only/read-write accessor with the same name as
 278 the attribute.
 279
 280 =item isa => TypeConstraint
 281
 282 Provides basic type checking in the constructor and accessor. Basic types such
 283 as C<Int>, C<ArrayRef>, C<Defined> are supported. Any unknown type is taken to
 284 be a class check (e.g. isa => 'DateTime' would accept only L<DateTime>
 285 objects).
 286
 287 =item required => 0|1
 288
 289 Whether this attribute is required to have a value. If the attribute is lazy or
 290 has a builder, then providing a value for the attribute in the constructor is
 291 optional.
 292
 293 =item init_arg => Str | Undef
 294
 295 Allows you to use a different key name in the constructor.  If undef, the
 296 attribue can't be passed to the constructor.
 297
 298 =item default => Value | CodeRef
 299
 300 Sets the default value of the attribute. If the default is a coderef, it will
 301 be invoked to get the default value. Due to quirks of Perl, any bare reference
 302 is forbidden, you must wrap the reference in a coderef. Otherwise, all
 303 instances will share the same reference.
 304
 305 =item lazy => 0|1
 306
 307 If specified, the default is calculated on demand instead of in the
 308 constructor.
 309
 310 =item predicate => Str
 311
 312 Lets you specify a method name for installing a predicate method, which checks
 313 that the attribute has a value. It will not invoke a lazy default or builder
 314 method.
 315
 316 =item clearer => Str
 317
 318 Lets you specify a method name for installing a clearer method, which clears
 319 the attribute's value from the instance. On the next read, lazy or builder will
 320 be invoked.
 321
 322 =item handles => HashRef|ArrayRef
 323
 324 Lets you specify methods to delegate to the attribute. ArrayRef forwards the
 325 given method names to method calls on the attribute. HashRef maps local method
 326 names to remote method names called on the attribute. Other forms of
 327 L</handles>, such as regular expression and coderef, are not yet supported.
 328
 329 =item weak_ref => 0|1
 330
 331 Lets you automatically weaken any reference stored in the attribute.
 332
 333 Use of this feature requires L<Scalar::Util>!
 334
 335 =item trigger => CodeRef
 336
 337 Any time the attribute's value is set (either through the accessor or the constructor), the trigger is called on it. The trigger receives as arguments the instance, the new value, and the attribute instance.
 338
 339 Mouse 0.05 supported more complex triggers, but this behavior is now removed.
 340
 341 =item builder => Str
 342
 343 Defines a method name to be called to provide the default value of the
 344 attribute. C<< builder => 'build_foo' >> is mostly equivalent to
 345 C<< default => sub { $_[0]->build_foo } >>.
 346
 347 =item auto_deref => 0|1
 348
 349 Allows you to automatically dereference ArrayRef and HashRef attributes in list
 350 context. In scalar context, the reference is returned (NOT the list length or
 351 bucket status). You must specify an appropriate type constraint to use
 352 auto_deref.
 353
 354 =item lazy_build => 0|1
 355
 356 Automatically define lazy => 1 as well as builder => "_build_$attr", clearer =>
 357 "clear_$attr', predicate => 'has_$attr' unless they are already defined.
 358
 359 =back
 360
 361 =head2 confess error -> BOOM
 362
 363 L<Carp/confess> for your convenience.
 364
 365 =head2 blessed value -> ClassName | undef
 366
 367 L<Scalar::Util/blessed> for your convenience.
 368
 369 =head1 MISC
 370
 371 =head2 import
 372
 373 Importing Mouse will default your class' superclass list to L<Mouse::Object>.
 374 You may use L</extends> to replace the superclass list.
 375
 376 =head2 unimport
 377
 378 Please unimport Mouse (C<no Mouse>) so that if someone calls one of the
 379 keywords (such as L</extends>) it will break loudly instead breaking subtly.
 380
 381 =head1 FUNCTIONS
 382
 383 =head2 load_class Class::Name
 384
 385 This will load a given C<Class::Name> (or die if it's not loadable).
 386 This function can be used in place of tricks like
 387 C<eval "use $module"> or using C<require>.
 388
 389 =head2 is_class_loaded Class::Name -> Bool
 390
 391 Returns whether this class is actually loaded or not. It uses a heuristic which
 392 involves checking for the existence of C<$VERSION>, C<@ISA>, and any
 393 locally-defined method.
 394
 395 =head1 AUTHORS
 396
 397 Shawn M Moore, C<< <sartak at gmail.com> >>
 398
 399 Yuval Kogman, C<< <nothingmuch at woobling.org> >>
 400
 401 tokuhirom
 402
 403 Yappo
 404
 405 with plenty of code borrowed from L<Class::MOP> and L<Moose>
 406
 407 =head1 BUGS
 408
 409 No known bugs.
 410
 411 Please report any bugs through RT: email
 412 C<bug-mouse at rt.cpan.org>, or browse
 413 L<http://rt.cpan.org/NoAuth/ReportBug.html?Queue=Mouse>.
 414
 415 =head1 COPYRIGHT AND LICENSE
 416
 417 Copyright 2008 Shawn M Moore.
 418
 419 This program is free software; you can redistribute it and/or modify it
 420 under the same terms as Perl itself.
 421
 422 =cut
 423