lib/Mouse.pm

   1 package Mouse;
   2 use strict;
   3 use warnings;
   4 use 5.006;
   5 use base 'Exporter';
   6
   7 our $VERSION = '0.33';
   8
   9 sub moose_version(){ 0.90 } # which Mouse is a subset of
  10
  11 use Carp 'confess';
  12 use Scalar::Util 'blessed';
  13
  14 use Mouse::Util qw(load_class is_class_loaded not_supported);
  15
  16 use Mouse::Meta::Module;
  17 use Mouse::Meta::Class;
  18 use Mouse::Meta::Role;
  19 use Mouse::Meta::Attribute;
  20 use Mouse::Object;
  21 use Mouse::Util::TypeConstraints ();
  22
  23 our @EXPORT = qw(
  24     extends with
  25     has
  26     before after around
  27     override super
  28     augment  inner
  29
  30     blessed confess
  31 );
  32
  33 our %is_removable = map{ $_ => undef } @EXPORT;
  34 delete $is_removable{blessed};
  35 delete $is_removable{confess};
  36
  37 sub extends { Mouse::Meta::Class->initialize(scalar caller)->superclasses(@_) }
  38
  39 sub has {
  40     my $meta = Mouse::Meta::Class->initialize(scalar caller);
  41     $meta->add_attribute(@_);
  42 }
  43
  44 sub before {
  45     my $meta = Mouse::Meta::Class->initialize(scalar caller);
  46
  47     my $code = pop;
  48
  49     for (@_) {
  50         $meta->add_before_method_modifier($_ => $code);
  51     }
  52 }
  53
  54 sub after {
  55     my $meta = Mouse::Meta::Class->initialize(scalar caller);
  56
  57     my $code = pop;
  58
  59     for (@_) {
  60         $meta->add_after_method_modifier($_ => $code);
  61     }
  62 }
  63
  64 sub around {
  65     my $meta = Mouse::Meta::Class->initialize(scalar caller);
  66
  67     my $code = pop;
  68
  69     for (@_) {
  70         $meta->add_around_method_modifier($_ => $code);
  71     }
  72 }
  73
  74 sub with {
  75     Mouse::Util::apply_all_roles(scalar(caller), @_);
  76 }
  77
  78 our $SUPER_PACKAGE;
  79 our $SUPER_BODY;
  80 our @SUPER_ARGS;
  81
  82 sub super {
  83     # This check avoids a recursion loop - see
  84     # t/100_bugs/020_super_recursion.t
  85     return if defined $SUPER_PACKAGE && $SUPER_PACKAGE ne caller();
  86     return unless $SUPER_BODY; $SUPER_BODY->(@SUPER_ARGS);
  87 }
  88
  89 sub override {
  90     my $meta = Mouse::Meta::Class->initialize(caller);
  91     my $pkg = $meta->name;
  92
  93     my $name = shift;
  94     my $code = shift;
  95
  96     my $body = $pkg->can($name)
  97         or confess "You cannot override '$name' because it has no super method";
  98
  99     $meta->add_method($name => sub {
 100         local $SUPER_PACKAGE = $pkg;
 101         local @SUPER_ARGS = @_;
 102         local $SUPER_BODY = $body;
 103
 104         $code->(@_);
 105     });
 106 }
 107
 108 sub inner  { not_supported }
 109 sub augment{ not_supported }
 110
 111 sub init_meta {
 112     shift;
 113     my %args = @_;
 114
 115     my $class = $args{for_class}
 116                     or confess("Cannot call init_meta without specifying a for_class");
 117     my $base_class = $args{base_class} || 'Mouse::Object';
 118     my $metaclass  = $args{metaclass}  || 'Mouse::Meta::Class';
 119
 120     confess("The Metaclass $metaclass must be a subclass of Mouse::Meta::Class.")
 121             unless $metaclass->isa('Mouse::Meta::Class');
 122
 123     # make a subtype for each Mouse class
 124     Mouse::Util::TypeConstraints::class_type($class)
 125         unless Mouse::Util::TypeConstraints::find_type_constraint($class);
 126
 127     my $meta = $metaclass->initialize($class);
 128
 129     $meta->add_method(meta => sub{
 130         return $metaclass->initialize(ref($_[0]) || $_[0]);
 131     });
 132
 133     $meta->superclasses($base_class)
 134         unless $meta->superclasses;
 135
 136     return $meta;
 137 }
 138
 139 sub import {
 140     my $class = shift;
 141
 142     strict->import;
 143     warnings->import;
 144
 145     my $opts = do {
 146         if (ref($_[0]) && ref($_[0]) eq 'HASH') {
 147             shift @_;
 148         } else {
 149             +{ };
 150         }
 151     };
 152     my $level = delete $opts->{into_level};
 153        $level = 0 unless defined $level;
 154     my $caller = caller($level);
 155
 156     # we should never export to main
 157     if ($caller eq 'main') {
 158         warn qq{$class does not export its sugar to the 'main' package.\n};
 159         return;
 160     }
 161
 162     $class->init_meta(
 163         for_class  => $caller,
 164     );
 165
 166     if (@_) {
 167         __PACKAGE__->export_to_level( $level+1, $class, @_);
 168     } else {
 169         # shortcut for the common case of no type character
 170         no strict 'refs';
 171         for my $keyword (@EXPORT) {
 172             *{ $caller . '::' . $keyword } = *{__PACKAGE__ . '::' . $keyword};
 173         }
 174     }
 175 }
 176
 177 sub unimport {
 178     my $caller = caller;
 179
 180     my $stash = do{
 181         no strict 'refs';
 182         \%{$caller . '::'}
 183     };
 184
 185     for my $keyword (@EXPORT) {
 186         my $code;
 187         if(exists $is_removable{$keyword}
 188             && ($code = $caller->can($keyword))
 189             && (Mouse::Util::get_code_info($code))[0] eq __PACKAGE__){
 190
 191             delete $stash->{$keyword};
 192         }
 193     }
 194 }
 195
 196 1;
 197
 198 __END__
 199
 200 =head1 NAME
 201
 202 Mouse - Moose minus the antlers
 203
 204 =head1 SYNOPSIS
 205
 206     package Point;
 207     use Mouse; # automatically turns on strict and warnings
 208
 209     has 'x' => (is => 'rw', isa => 'Int');
 210     has 'y' => (is => 'rw', isa => 'Int');
 211
 212     sub clear {
 213         my $self = shift;
 214         $self->x(0);
 215         $self->y(0);
 216     }
 217
 218     package Point3D;
 219     use Mouse;
 220
 221     extends 'Point';
 222
 223     has 'z' => (is => 'rw', isa => 'Int');
 224
 225     after 'clear' => sub {
 226         my $self = shift;
 227         $self->z(0);
 228     };
 229
 230 =head1 DESCRIPTION
 231
 232 L<Moose> is wonderful. B<Use Moose instead of Mouse.>
 233
 234 Unfortunately, Moose has a compile-time penalty. Though significant progress
 235 has been made over the years, the compile time penalty is a non-starter for
 236 some very specific applications. If you are writing a command-line application
 237 or CGI script where startup time is essential, you may not be able to use
 238 Moose. We recommend that you instead use L<HTTP::Engine> and FastCGI for the
 239 latter, if possible.
 240
 241 Mouse aims to alleviate this by providing a subset of Moose's functionality,
 242 faster.
 243
 244 We're also going as light on dependencies as possible.
 245 L<Class::Method::Modifiers::Fast> or L<Class::Method::Modifiers> is required
 246 if you want support for L</before>, L</after>, and L</around>.
 247
 248 =head2 MOOSE COMPAT
 249
 250 Compatibility with Moose has been the utmost concern. Fewer than 1% of the
 251 tests fail when run against Moose instead of Mouse. Mouse code coverage is also
 252 over 96%. Even the error messages are taken from Moose. The Mouse code just
 253 runs the test suite 4x faster.
 254
 255 The idea is that, if you need the extra power, you should be able to run
 256 C<s/Mouse/Moose/g> on your codebase and have nothing break. To that end,
 257 we have written L<Any::Moose> which will act as Mouse unless Moose is loaded,
 258 in which case it will act as Moose. Since Mouse is a little sloppier than
 259 Moose, if you run into weird errors, it would be worth running:
 260
 261     ANY_MOOSE=Moose perl your-script.pl
 262
 263 to see if the bug is caused by Mouse. Moose's diagnostics and validation are
 264 also much better.
 265
 266 =head2 MouseX
 267
 268 Please don't copy MooseX code to MouseX. If you need extensions, you really
 269 should upgrade to Moose. We don't need two parallel sets of extensions!
 270
 271 If you really must write a Mouse extension, please contact the Moose mailing
 272 list or #moose on IRC beforehand.
 273
 274 =head2 Maintenance
 275
 276 The original author of this module has mostly stepped down from maintaining
 277 Mouse. See L<http://www.nntp.perl.org/group/perl.moose/2009/04/msg653.html>.
 278 If you would like to help maintain this module, please get in touch with us.
 279
 280 =head1 KEYWORDS
 281
 282 =head2 meta -> Mouse::Meta::Class
 283
 284 Returns this class' metaclass instance.
 285
 286 =head2 extends superclasses
 287
 288 Sets this class' superclasses.
 289
 290 =head2 before (method|methods) => Code
 291
 292 Installs a "before" method modifier. See L<Moose/before> or
 293 L<Class::Method::Modifiers/before>.
 294
 295 Use of this feature requires L<Class::Method::Modifiers>!
 296
 297 =head2 after (method|methods) => Code
 298
 299 Installs an "after" method modifier. See L<Moose/after> or
 300 L<Class::Method::Modifiers/after>.
 301
 302 Use of this feature requires L<Class::Method::Modifiers>!
 303
 304 =head2 around (method|methods) => Code
 305
 306 Installs an "around" method modifier. See L<Moose/around> or
 307 L<Class::Method::Modifiers/around>.
 308
 309 Use of this feature requires L<Class::Method::Modifiers>!
 310
 311 =head2 has (name|names) => parameters
 312
 313 Adds an attribute (or if passed an arrayref of names, multiple attributes) to
 314 this class. Options:
 315
 316 =over 4
 317
 318 =item is => ro|rw
 319
 320 If specified, inlines a read-only/read-write accessor with the same name as
 321 the attribute.
 322
 323 =item isa => TypeConstraint
 324
 325 Provides type checking in the constructor and accessor. The following types are
 326 supported. Any unknown type is taken to be a class check (e.g. isa =>
 327 'DateTime' would accept only L<DateTime> objects).
 328
 329     Any Item Bool Undef Defined Value Num Int Str ClassName
 330     Ref ScalarRef ArrayRef HashRef CodeRef RegexpRef GlobRef
 331     FileHandle Object
 332
 333 For more documentation on type constraints, see L<Mouse::Util::TypeConstraints>.
 334
 335
 336 =item required => 0|1
 337
 338 Whether this attribute is required to have a value. If the attribute is lazy or
 339 has a builder, then providing a value for the attribute in the constructor is
 340 optional.
 341
 342 =item init_arg => Str | Undef
 343
 344 Allows you to use a different key name in the constructor.  If undef, the
 345 attribue can't be passed to the constructor.
 346
 347 =item default => Value | CodeRef
 348
 349 Sets the default value of the attribute. If the default is a coderef, it will
 350 be invoked to get the default value. Due to quirks of Perl, any bare reference
 351 is forbidden, you must wrap the reference in a coderef. Otherwise, all
 352 instances will share the same reference.
 353
 354 =item lazy => 0|1
 355
 356 If specified, the default is calculated on demand instead of in the
 357 constructor.
 358
 359 =item predicate => Str
 360
 361 Lets you specify a method name for installing a predicate method, which checks
 362 that the attribute has a value. It will not invoke a lazy default or builder
 363 method.
 364
 365 =item clearer => Str
 366
 367 Lets you specify a method name for installing a clearer method, which clears
 368 the attribute's value from the instance. On the next read, lazy or builder will
 369 be invoked.
 370
 371 =item handles => HashRef|ArrayRef
 372
 373 Lets you specify methods to delegate to the attribute. ArrayRef forwards the
 374 given method names to method calls on the attribute. HashRef maps local method
 375 names to remote method names called on the attribute. Other forms of
 376 L</handles>, such as regular expression and coderef, are not yet supported.
 377
 378 =item weak_ref => 0|1
 379
 380 Lets you automatically weaken any reference stored in the attribute.
 381
 382 Use of this feature requires L<Scalar::Util>!
 383
 384 =item trigger => CodeRef
 385
 386 Any time the attribute's value is set (either through the accessor or the constructor), the trigger is called on it. The trigger receives as arguments the instance, the new value, and the attribute instance.
 387
 388 Mouse 0.05 supported more complex triggers, but this behavior is now removed.
 389
 390 =item builder => Str
 391
 392 Defines a method name to be called to provide the default value of the
 393 attribute. C<< builder => 'build_foo' >> is mostly equivalent to
 394 C<< default => sub { $_[0]->build_foo } >>.
 395
 396 =item auto_deref => 0|1
 397
 398 Allows you to automatically dereference ArrayRef and HashRef attributes in list
 399 context. In scalar context, the reference is returned (NOT the list length or
 400 bucket status). You must specify an appropriate type constraint to use
 401 auto_deref.
 402
 403 =item lazy_build => 0|1
 404
 405 Automatically define lazy => 1 as well as builder => "_build_$attr", clearer =>
 406 "clear_$attr', predicate => 'has_$attr' unless they are already defined.
 407
 408 =back
 409
 410 =head2 confess error -> BOOM
 411
 412 L<Carp/confess> for your convenience.
 413
 414 =head2 blessed value -> ClassName | undef
 415
 416 L<Scalar::Util/blessed> for your convenience.
 417
 418 =head1 MISC
 419
 420 =head2 import
 421
 422 Importing Mouse will default your class' superclass list to L<Mouse::Object>.
 423 You may use L</extends> to replace the superclass list.
 424
 425 =head2 unimport
 426
 427 Please unimport Mouse (C<no Mouse>) so that if someone calls one of the
 428 keywords (such as L</extends>) it will break loudly instead breaking subtly.
 429
 430 =head1 FUNCTIONS
 431
 432 =head2 load_class Class::Name
 433
 434 This will load a given C<Class::Name> (or die if it's not loadable).
 435 This function can be used in place of tricks like
 436 C<eval "use $module"> or using C<require>.
 437
 438 =head2 is_class_loaded Class::Name -> Bool
 439
 440 Returns whether this class is actually loaded or not. It uses a heuristic which
 441 involves checking for the existence of C<$VERSION>, C<@ISA>, and any
 442 locally-defined method.
 443
 444 =head1 SOURCE CODE ACCESS
 445
 446 We have a public git repo:
 447
 448  git clone git://jules.scsys.co.uk/gitmo/Mouse.git
 449
 450 =head1 AUTHORS
 451
 452 Shawn M Moore, C<< <sartak at gmail.com> >>
 453
 454 Yuval Kogman, C<< <nothingmuch at woobling.org> >>
 455
 456 tokuhirom
 457
 458 Yappo
 459
 460 wu-lee
 461
 462 Goro Fuji (gfx) C<< <gfuji at cpan.org> >>
 463
 464 with plenty of code borrowed from L<Class::MOP> and L<Moose>
 465
 466 =head1 BUGS
 467
 468 There is a known issue with Mouse on 5.6.2 regarding the @ISA tests. Until
 469 this is resolve the minimum version of Perl for Mouse is set to 5.8.0. Patches
 470 to resolve these tests are more than welcome.
 471
 472 Please report any bugs through RT: email
 473 C<bug-mouse at rt.cpan.org>, or browse
 474 L<http://rt.cpan.org/NoAuth/ReportBug.html?Queue=Mouse>.
 475
 476 =head1 COPYRIGHT AND LICENSE
 477
 478 Copyright 2008-2009 Infinity Interactive, Inc.
 479
 480 http://www.iinteractive.com/
 481
 482 This program is free software; you can redistribute it and/or modify it
 483 under the same terms as Perl itself.
 484
 485 =cut
 486