lib/Mouse.pm

   1 package Mouse;
   2 use strict;
   3 use warnings;
   4 use 5.006;
   5 use base 'Exporter';
   6
   7 our $VERSION = '0.15';
   8
   9 BEGIN {
  10     if ($ENV{MOUSE_DEBUG}) {
  11         *DEBUG = sub (){ 1 };
  12     } else {
  13         *DEBUG = sub (){ 0 };
  14     }
  15 }
  16
  17 use Carp 'confess';
  18 use Scalar::Util 'blessed';
  19 use Mouse::Util;
  20
  21 use Mouse::Meta::Attribute;
  22 use Mouse::Meta::Class;
  23 use Mouse::Object;
  24 use Mouse::TypeRegistry;
  25
  26 our @EXPORT = qw(extends has before after around blessed confess with);
  27
  28 sub extends { Mouse::Meta::Class->initialize(caller)->superclasses(@_) }
  29
  30 sub has {
  31     my $meta = Mouse::Meta::Class->initialize(caller);
  32
  33     my $names = shift;
  34     $names = [$names] if !ref($names);
  35
  36     for my $name (@$names) {
  37         if ($name =~ s/^\+//) {
  38             Mouse::Meta::Attribute->clone_parent($meta, $name, @_);
  39         }
  40         else {
  41             Mouse::Meta::Attribute->create($meta, $name, @_);
  42         }
  43     }
  44 }
  45
  46 sub before {
  47     my $meta = Mouse::Meta::Class->initialize(caller);
  48
  49     my $code = pop;
  50
  51     for (@_) {
  52         $meta->add_before_method_modifier($_ => $code);
  53     }
  54 }
  55
  56 sub after {
  57     my $meta = Mouse::Meta::Class->initialize(caller);
  58
  59     my $code = pop;
  60
  61     for (@_) {
  62         $meta->add_after_method_modifier($_ => $code);
  63     }
  64 }
  65
  66 sub around {
  67     my $meta = Mouse::Meta::Class->initialize(caller);
  68
  69     my $code = pop;
  70
  71     for (@_) {
  72         $meta->add_around_method_modifier($_ => $code);
  73     }
  74 }
  75
  76 sub with {
  77     Mouse::Util::apply_all_roles((caller)[0], @_);
  78 }
  79
  80 sub import {
  81     my $class = shift;
  82
  83     strict->import;
  84     warnings->import;
  85
  86     my $caller = caller;
  87
  88     my $meta = Mouse::Meta::Class->initialize($caller);
  89     $meta->superclasses('Mouse::Object')
  90         unless $meta->superclasses;
  91
  92     no strict 'refs';
  93     no warnings 'redefine';
  94     *{$caller.'::meta'} = sub { $meta };
  95
  96     if (@_) {
  97         __PACKAGE__->export_to_level( 1, $class, @_);
  98     } else {
  99         # shortcut for the common case of no type character
 100         no strict 'refs';
 101         for my $keyword (@EXPORT) {
 102             *{ $caller . '::' . $keyword } = *{__PACKAGE__ . '::' . $keyword};
 103         }
 104     }
 105 }
 106
 107 sub unimport {
 108     my $caller = caller;
 109
 110     no strict 'refs';
 111     for my $keyword (@EXPORT) {
 112         delete ${ $caller . '::' }{$keyword};
 113     }
 114 }
 115
 116 sub load_class {
 117     my $class = shift;
 118
 119     if (ref($class) || !defined($class) || !length($class)) {
 120         my $display = defined($class) ? $class : 'undef';
 121         confess "Invalid class name ($display)";
 122     }
 123
 124     return 1 if $class eq 'Mouse::Object';
 125     return 1 if is_class_loaded($class);
 126
 127     (my $file = "$class.pm") =~ s{::}{/}g;
 128
 129     eval { CORE::require($file) };
 130     confess "Could not load class ($class) because : $@" if $@;
 131
 132     return 1;
 133 }
 134
 135 sub is_class_loaded {
 136     my $class = shift;
 137
 138     return 0 if ref($class) || !defined($class) || !length($class);
 139
 140     # walk the symbol table tree to avoid autovififying
 141     # \*{${main::}{"Foo::"}} == \*main::Foo::
 142
 143     my $pack = \*::;
 144     foreach my $part (split('::', $class)) {
 145         return 0 unless exists ${$$pack}{"${part}::"};
 146         $pack = \*{${$$pack}{"${part}::"}};
 147     }
 148
 149     # check for $VERSION or @ISA
 150     return 1 if exists ${$$pack}{VERSION}
 151              && defined *{${$$pack}{VERSION}}{SCALAR};
 152     return 1 if exists ${$$pack}{ISA}
 153              && defined *{${$$pack}{ISA}}{ARRAY};
 154
 155     # check for any method
 156     foreach ( keys %{$$pack} ) {
 157         next if substr($_, -2, 2) eq '::';
 158         return 1 if defined *{${$$pack}{$_}}{CODE};
 159     }
 160
 161     # fail
 162     return 0;
 163 }
 164
 165 1;
 166
 167 __END__
 168
 169 =head1 NAME
 170
 171 Mouse - Moose minus the antlers
 172
 173 =head1 SYNOPSIS
 174
 175     package Point;
 176     use Mouse; # automatically turns on strict and warnings
 177
 178     has 'x' => (is => 'rw', isa => 'Int');
 179     has 'y' => (is => 'rw', isa => 'Int');
 180
 181     sub clear {
 182         my $self = shift;
 183         $self->x(0);
 184         $self->y(0);
 185     }
 186
 187     package Point3D;
 188     use Mouse;
 189
 190     extends 'Point';
 191
 192     has 'z' => (is => 'rw', isa => 'Int');
 193
 194     after 'clear' => sub {
 195         my $self = shift;
 196         $self->z(0);
 197     };
 198
 199 =head1 DESCRIPTION
 200
 201 L<Moose> is wonderful.
 202
 203 Unfortunately, it's a little slow. Though significant progress has been made
 204 over the years, the compile time penalty is a non-starter for some
 205 applications.
 206
 207 Mouse aims to alleviate this by providing a subset of Moose's
 208 functionality, faster. In particular, L<Moose/has> is missing only a few
 209 expert-level features.
 210
 211 We're also going as light on dependencies as possible. Most functions we use
 212 from L<Scalar::Util> are copied into this dist. L<Scalar::Util> is required if
 213 you'd like weak references; there's simply no way to do it from pure Perl.
 214 L<Class::Method::Modifiers> is required if you want support for L</before>,
 215 L</after>, and L</around>.
 216
 217 =head2 MOOSE COMPAT
 218
 219 Compatibility with Moose has been the utmost concern. Fewer than 1% of the
 220 tests fail when run against Moose instead of Mouse. Mouse code coverage is also
 221 over 96%. Even the error messages are taken from Moose. The Mouse code just
 222 runs the test suite 4x faster.
 223
 224 The idea is that, if you need the extra power, you should be able to run
 225 C<s/Mouse/Moose/g> on your codebase and have nothing break. To that end,
 226 nothingmuch has written L<Squirrel> (part of this distribution) which will act
 227 as Mouse unless Moose is loaded, in which case it will act as Moose.
 228
 229 Mouse also has the blessings of Moose's author, stevan.
 230
 231 =head2 MISSING FEATURES
 232
 233 =head3 Roles
 234
 235 We're working on fixing this one! stevan has suggested an implementation
 236 strategy. Mouse currently ignores methods, so that needs to be fixed next.
 237 Roles that consist entirely of attributes may be usable in this very version.
 238
 239 =head3 Complex types
 240
 241 User-defined type constraints and parameterized types may be implemented. Type
 242 coercions probably not (patches welcome).
 243
 244 =head3 Bootstrapped meta world
 245
 246 Very handy for extensions to the MOP. Not pressing, but would be nice to have.
 247
 248 =head3 Modification of attribute metaclass
 249
 250 When you declare an attribute with L</has>, you get the inlined accessors
 251 installed immediately. Modifying the attribute metaclass, even if possible,
 252 does nothing.
 253
 254 =head3 Lots more..
 255
 256 MouseX?
 257
 258 =head1 KEYWORDS
 259
 260 =head2 meta -> Mouse::Meta::Class
 261
 262 Returns this class' metaclass instance.
 263
 264 =head2 extends superclasses
 265
 266 Sets this class' superclasses.
 267
 268 =head2 before (method|methods) => Code
 269
 270 Installs a "before" method modifier. See L<Moose/before> or
 271 L<Class::Method::Modifiers/before>.
 272
 273 Use of this feature requires L<Class::Method::Modifiers>!
 274
 275 =head2 after (method|methods) => Code
 276
 277 Installs an "after" method modifier. See L<Moose/after> or
 278 L<Class::Method::Modifiers/after>.
 279
 280 Use of this feature requires L<Class::Method::Modifiers>!
 281
 282 =head2 around (method|methods) => Code
 283
 284 Installs an "around" method modifier. See L<Moose/around> or
 285 L<Class::Method::Modifiers/around>.
 286
 287 Use of this feature requires L<Class::Method::Modifiers>!
 288
 289 =head2 has (name|names) => parameters
 290
 291 Adds an attribute (or if passed an arrayref of names, multiple attributes) to
 292 this class. Options:
 293
 294 =over 4
 295
 296 =item is => ro|rw
 297
 298 If specified, inlines a read-only/read-write accessor with the same name as
 299 the attribute.
 300
 301 =item isa => TypeConstraint
 302
 303 Provides basic type checking in the constructor and accessor. Basic types such
 304 as C<Int>, C<ArrayRef>, C<Defined> are supported. Any unknown type is taken to
 305 be a class check (e.g. isa => 'DateTime' would accept only L<DateTime>
 306 objects).
 307
 308 =item required => 0|1
 309
 310 Whether this attribute is required to have a value. If the attribute is lazy or
 311 has a builder, then providing a value for the attribute in the constructor is
 312 optional.
 313
 314 =item init_arg => Str | Undef
 315
 316 Allows you to use a different key name in the constructor.  If undef, the
 317 attribue can't be passed to the constructor.
 318
 319 =item default => Value | CodeRef
 320
 321 Sets the default value of the attribute. If the default is a coderef, it will
 322 be invoked to get the default value. Due to quirks of Perl, any bare reference
 323 is forbidden, you must wrap the reference in a coderef. Otherwise, all
 324 instances will share the same reference.
 325
 326 =item lazy => 0|1
 327
 328 If specified, the default is calculated on demand instead of in the
 329 constructor.
 330
 331 =item predicate => Str
 332
 333 Lets you specify a method name for installing a predicate method, which checks
 334 that the attribute has a value. It will not invoke a lazy default or builder
 335 method.
 336
 337 =item clearer => Str
 338
 339 Lets you specify a method name for installing a clearer method, which clears
 340 the attribute's value from the instance. On the next read, lazy or builder will
 341 be invoked.
 342
 343 =item handles => HashRef|ArrayRef
 344
 345 Lets you specify methods to delegate to the attribute. ArrayRef forwards the
 346 given method names to method calls on the attribute. HashRef maps local method
 347 names to remote method names called on the attribute. Other forms of
 348 L</handles>, such as regular expression and coderef, are not yet supported.
 349
 350 =item weak_ref => 0|1
 351
 352 Lets you automatically weaken any reference stored in the attribute.
 353
 354 Use of this feature requires L<Scalar::Util>!
 355
 356 =item trigger => CodeRef
 357
 358 Any time the attribute's value is set (either through the accessor or the constructor), the trigger is called on it. The trigger receives as arguments the instance, the new value, and the attribute instance.
 359
 360 Mouse 0.05 supported more complex triggers, but this behavior is now removed.
 361
 362 =item builder => Str
 363
 364 Defines a method name to be called to provide the default value of the
 365 attribute. C<< builder => 'build_foo' >> is mostly equivalent to
 366 C<< default => sub { $_[0]->build_foo } >>.
 367
 368 =item auto_deref => 0|1
 369
 370 Allows you to automatically dereference ArrayRef and HashRef attributes in list
 371 context. In scalar context, the reference is returned (NOT the list length or
 372 bucket status). You must specify an appropriate type constraint to use
 373 auto_deref.
 374
 375 =item lazy_build => 0|1
 376
 377 Automatically define lazy => 1 as well as builder => "_build_$attr", clearer =>
 378 "clear_$attr', predicate => 'has_$attr' unless they are already defined.
 379
 380 =back
 381
 382 =head2 confess error -> BOOM
 383
 384 L<Carp/confess> for your convenience.
 385
 386 =head2 blessed value -> ClassName | undef
 387
 388 L<Scalar::Util/blessed> for your convenience.
 389
 390 =head1 MISC
 391
 392 =head2 import
 393
 394 Importing Mouse will default your class' superclass list to L<Mouse::Object>.
 395 You may use L</extends> to replace the superclass list.
 396
 397 =head2 unimport
 398
 399 Please unimport Mouse (C<no Mouse>) so that if someone calls one of the
 400 keywords (such as L</extends>) it will break loudly instead breaking subtly.
 401
 402 =head1 FUNCTIONS
 403
 404 =head2 load_class Class::Name
 405
 406 This will load a given C<Class::Name> (or die if it's not loadable).
 407 This function can be used in place of tricks like
 408 C<eval "use $module"> or using C<require>.
 409
 410 =head2 is_class_loaded Class::Name -> Bool
 411
 412 Returns whether this class is actually loaded or not. It uses a heuristic which
 413 involves checking for the existence of C<$VERSION>, C<@ISA>, and any
 414 locally-defined method.
 415
 416 =head1 AUTHORS
 417
 418 Shawn M Moore, C<< <sartak at gmail.com> >>
 419
 420 Yuval Kogman, C<< <nothingmuch at woobling.org> >>
 421
 422 tokuhirom
 423
 424 Yappo
 425
 426 with plenty of code borrowed from L<Class::MOP> and L<Moose>
 427
 428 =head1 BUGS
 429
 430 No known bugs.
 431
 432 Please report any bugs through RT: email
 433 C<bug-mouse at rt.cpan.org>, or browse
 434 L<http://rt.cpan.org/NoAuth/ReportBug.html?Queue=Mouse>.
 435
 436 =head1 COPYRIGHT AND LICENSE
 437
 438 Copyright 2008 Shawn M Moore.
 439
 440 This program is free software; you can redistribute it and/or modify it
 441 under the same terms as Perl itself.
 442
 443 =cut
 444