lib/Mouse.pm

   1 #!/usr/bin/env perl
   2 package Mouse;
   3 use strict;
   4 use warnings;
   5 use base 'Exporter';
   6
   7 our $VERSION = '0.08';
   8 use 5.006;
   9
  10 use Carp 'confess';
  11 use Mouse::Util 'blessed';
  12
  13 use Mouse::Meta::Attribute;
  14 use Mouse::Meta::Class;
  15 use Mouse::Object;
  16 use Mouse::TypeRegistry;
  17
  18 our @EXPORT = qw(extends has before after around blessed confess with);
  19
  20 sub extends { Mouse::Meta::Class->initialize(caller)->superclasses(@_) }
  21
  22 sub has {
  23     my $meta = Mouse::Meta::Class->initialize(caller);
  24
  25     my $names = shift;
  26     $names = [$names] if !ref($names);
  27
  28     for my $name (@$names) {
  29         if ($name =~ s/^\+//) {
  30             Mouse::Meta::Attribute->clone_parent($meta, $name, @_);
  31         }
  32         else {
  33             Mouse::Meta::Attribute->create($meta, $name, @_);
  34         }
  35     }
  36 }
  37
  38 sub before {
  39     my $meta = Mouse::Meta::Class->initialize(caller);
  40
  41     my $code = pop;
  42
  43     for (@_) {
  44         $meta->add_before_method_modifier($_ => $code);
  45     }
  46 }
  47
  48 sub after {
  49     my $meta = Mouse::Meta::Class->initialize(caller);
  50
  51     my $code = pop;
  52
  53     for (@_) {
  54         $meta->add_after_method_modifier($_ => $code);
  55     }
  56 }
  57
  58 sub around {
  59     my $meta = Mouse::Meta::Class->initialize(caller);
  60
  61     my $code = pop;
  62
  63     for (@_) {
  64         $meta->add_around_method_modifier($_ => $code);
  65     }
  66 }
  67
  68 sub with {
  69     my $meta = Mouse::Meta::Class->initialize(caller);
  70
  71     my $role  = shift;
  72
  73     confess "Mouse::Role only supports 'with' on individual roles at a time" if @_;
  74
  75     Mouse::load_class($role);
  76     $role->meta->apply($meta);
  77 }
  78
  79 sub import {
  80     strict->import;
  81     warnings->import;
  82
  83     my $caller = caller;
  84
  85     my $meta = Mouse::Meta::Class->initialize($caller);
  86     $meta->superclasses('Mouse::Object')
  87         unless $meta->superclasses;
  88
  89     no strict 'refs';
  90     no warnings 'redefine';
  91     *{$caller.'::meta'} = sub { $meta };
  92
  93     Mouse->export_to_level(1, @_);
  94 }
  95
  96 sub unimport {
  97     my $caller = caller;
  98
  99     no strict 'refs';
 100     for my $keyword (@EXPORT) {
 101         delete ${ $caller . '::' }{$keyword};
 102     }
 103 }
 104
 105 sub load_class {
 106     my $class = shift;
 107
 108     if (ref($class) || !defined($class) || !length($class)) {
 109         my $display = defined($class) ? $class : 'undef';
 110         confess "Invalid class name ($display)";
 111     }
 112
 113     return 1 if is_class_loaded($class);
 114
 115     (my $file = "$class.pm") =~ s{::}{/}g;
 116
 117     eval { CORE::require($file) };
 118     confess "Could not load class ($class) because : $@" if $@;
 119
 120     return 1;
 121 }
 122
 123 sub is_class_loaded {
 124     my $class = shift;
 125
 126     return 0 if ref($class) || !defined($class) || !length($class);
 127
 128     # walk the symbol table tree to avoid autovififying
 129     # \*{${main::}{"Foo::"}} == \*main::Foo::
 130
 131     my $pack = \*::;
 132     foreach my $part (split('::', $class)) {
 133         return 0 unless exists ${$$pack}{"${part}::"};
 134         $pack = \*{${$$pack}{"${part}::"}};
 135     }
 136
 137     # check for $VERSION or @ISA
 138     return 1 if exists ${$$pack}{VERSION}
 139              && defined *{${$$pack}{VERSION}}{SCALAR};
 140     return 1 if exists ${$$pack}{ISA}
 141              && defined *{${$$pack}{ISA}}{ARRAY};
 142
 143     # check for any method
 144     foreach ( keys %{$$pack} ) {
 145         next if substr($_, -2, 2) eq '::';
 146         return 1 if defined *{${$$pack}{$_}}{CODE};
 147     }
 148
 149     # fail
 150     return 0;
 151 }
 152
 153 1;
 154
 155 __END__
 156
 157 =head1 NAME
 158
 159 Mouse - Moose minus the antlers
 160
 161 =head1 SYNOPSIS
 162
 163     package Point;
 164     use Mouse; # automatically turns on strict and warnings
 165
 166     has 'x' => (is => 'rw', isa => 'Int');
 167     has 'y' => (is => 'rw', isa => 'Int');
 168
 169     sub clear {
 170         my $self = shift;
 171         $self->x(0);
 172         $self->y(0);
 173     }
 174
 175     package Point3D;
 176     use Mouse;
 177
 178     extends 'Point';
 179
 180     has 'z' => (is => 'rw', isa => 'Int');
 181
 182     after 'clear' => sub {
 183         my $self = shift;
 184         $self->z(0);
 185     };
 186
 187 =head1 DESCRIPTION
 188
 189 L<Moose> is wonderful.
 190
 191 Unfortunately, it's a little slow. Though significant progress has been made
 192 over the years, the compile time penalty is a non-starter for some
 193 applications.
 194
 195 Mouse aims to alleviate this by providing a subset of Moose's
 196 functionality, faster. In particular, L<Moose/has> is missing only a few
 197 expert-level features.
 198
 199 =head2 MOOSE COMPAT
 200
 201 Compatibility with Moose has been the utmost concern. Fewer than 1% of the
 202 tests fail when run against Moose instead of Mouse. Mouse code coverage is also
 203 over 96%. Even the error messages are taken from Moose. The Mouse code just
 204 runs the test suite 4x faster.
 205
 206 The idea is that, if you need the extra power, you should be able to run
 207 C<s/Mouse/Moose/g> on your codebase and have nothing break. To that end,
 208 nothingmuch has written L<Squirrel> (part of this distribution) which will act
 209 as Mouse unless Moose is loaded, in which case it will act as Moose.
 210
 211 Mouse also has the blessings of Moose's author, stevan.
 212
 213 =head2 MISSING FEATURES
 214
 215 =head3 Roles
 216
 217 We're working on fixing this one! stevan has suggested an implementation
 218 strategy. Mouse currently ignores methods, so that needs to be fixed next.
 219 Roles that consist entirely of attributes may be usable in this very version.
 220
 221 =head3 Complex types
 222
 223 User-defined type constraints and parameterized types may be implemented. Type
 224 coercions probably not (patches welcome).
 225
 226 =head3 Bootstrapped meta world
 227
 228 Very handy for extensions to the MOP. Not pressing, but would be nice to have.
 229
 230 =head3 Modification of attribute metaclass
 231
 232 When you declare an attribute with L</has>, you get the inlined accessors
 233 installed immediately. Modifying the attribute metaclass, even if possible,
 234 does nothing.
 235
 236 =head3 Lots more..
 237
 238 MouseX?
 239
 240 =head1 KEYWORDS
 241
 242 =head2 meta -> Mouse::Meta::Class
 243
 244 Returns this class' metaclass instance.
 245
 246 =head2 extends superclasses
 247
 248 Sets this class' superclasses.
 249
 250 =head2 before (method|methods) => Code
 251
 252 Installs a "before" method modifier. See L<Moose/before> or
 253 L<Class::Method::Modifiers/before>.
 254
 255 =head2 after (method|methods) => Code
 256
 257 Installs an "after" method modifier. See L<Moose/after> or
 258 L<Class::Method::Modifiers/after>.
 259
 260 =head2 around (method|methods) => Code
 261
 262 Installs an "around" method modifier. See L<Moose/around> or
 263 L<Class::Method::Modifiers/around>.
 264
 265 =head2 has (name|names) => parameters
 266
 267 Adds an attribute (or if passed an arrayref of names, multiple attributes) to
 268 this class. Options:
 269
 270 =over 4
 271
 272 =item is => ro|rw
 273
 274 If specified, inlines a read-only/read-write accessor with the same name as
 275 the attribute.
 276
 277 =item isa => TypeConstraint
 278
 279 Provides basic type checking in the constructor and accessor. Basic types such
 280 as C<Int>, C<ArrayRef>, C<Defined> are supported. Any unknown type is taken to
 281 be a class check (e.g. isa => 'DateTime' would accept only L<DateTime>
 282 objects).
 283
 284 =item required => 0|1
 285
 286 Whether this attribute is required to have a value. If the attribute is lazy or
 287 has a builder, then providing a value for the attribute in the constructor is
 288 optional.
 289
 290 =item init_arg => Str
 291
 292 Allows you to use a different key name in the constructor.
 293
 294 =item default => Value | CodeRef
 295
 296 Sets the default value of the attribute. If the default is a coderef, it will
 297 be invoked to get the default value. Due to quirks of Perl, any bare reference
 298 is forbidden, you must wrap the reference in a coderef. Otherwise, all
 299 instances will share the same reference.
 300
 301 =item lazy => 0|1
 302
 303 If specified, the default is calculated on demand instead of in the
 304 constructor.
 305
 306 =item predicate => Str
 307
 308 Lets you specify a method name for installing a predicate method, which checks
 309 that the attribute has a value. It will not invoke a lazy default or builder
 310 method.
 311
 312 =item clearer => Str
 313
 314 Lets you specify a method name for installing a clearer method, which clears
 315 the attribute's value from the instance. On the next read, lazy or builder will
 316 be invoked.
 317
 318 =item handles => HashRef|ArrayRef
 319
 320 Lets you specify methods to delegate to the attribute. ArrayRef forwards the
 321 given method names to method calls on the attribute. HashRef maps local method
 322 names to remote method names called on the attribute. Other forms of
 323 L</handles>, such as regular expression and coderef, are not yet supported.
 324
 325 =item weak_ref => 0|1
 326
 327 Lets you automatically weaken any reference stored in the attribute.
 328
 329 =item trigger => CodeRef
 330
 331 Any time the attribute's value is set (either through the accessor or the constructor), the trigger is called on it. The trigger receives as arguments the instance, the new value, and the attribute instance.
 332
 333 Mouse 0.05 supported more complex triggers, but this behavior is now deprecated.
 334
 335 =item builder => Str
 336
 337 Defines a method name to be called to provide the default value of the
 338 attribute. C<< builder => 'build_foo' >> is mostly equivalent to
 339 C<< default => sub { $_[0]->build_foo } >>.
 340
 341 =item auto_deref => 0|1
 342
 343 Allows you to automatically dereference ArrayRef and HashRef attributes in list
 344 context. In scalar context, the reference is returned (NOT the list length or
 345 bucket status). You must specify an appropriate type constraint to use
 346 auto_deref.
 347
 348 =back
 349
 350 =head2 confess error -> BOOM
 351
 352 L<Carp/confess> for your convenience.
 353
 354 =head2 blessed value -> ClassName | undef
 355
 356 L<Scalar::Util/blessed> for your convenience.
 357
 358 =head1 MISC
 359
 360 =head2 import
 361
 362 Importing Mouse will default your class' superclass list to L<Mouse::Object>.
 363 You may use L</extends> to replace the superclass list.
 364
 365 =head2 unimport
 366
 367 Please unimport Mouse (C<no Mouse>) so that if someone calls one of the
 368 keywords (such as L</extends>) it will break loudly instead breaking subtly.
 369
 370 =head1 FUNCTIONS
 371
 372 =head2 load_class Class::Name
 373
 374 This will load a given C<Class::Name> (or die if it's not loadable).
 375 This function can be used in place of tricks like
 376 C<eval "use $module"> or using C<require>.
 377
 378 =head2 is_class_loaded Class::Name -> Bool
 379
 380 Returns whether this class is actually loaded or not. It uses a heuristic which
 381 involves checking for the existence of C<$VERSION>, C<@ISA>, and any
 382 locally-defined method.
 383
 384 =head1 AUTHOR
 385
 386 Shawn M Moore, C<< <sartak at gmail.com> >>
 387
 388 with plenty of code borrowed from L<Class::MOP> and L<Moose>
 389
 390 =head1 BUGS
 391
 392 No known bugs.
 393
 394 Please report any bugs through RT: email
 395 C<bug-mouse at rt.cpan.org>, or browse
 396 L<http://rt.cpan.org/NoAuth/ReportBug.html?Queue=Mouse>.
 397
 398 =head1 COPYRIGHT AND LICENSE
 399
 400 Copyright 2008 Shawn M Moore.
 401
 402 This program is free software; you can redistribute it and/or modify it
 403 under the same terms as Perl itself.
 404
 405 =cut
 406