lib/Mouse.pm

   1 package Mouse;
   2 use strict;
   3 use warnings;
   4 use 5.006;
   5 use base 'Exporter';
   6
   7 our $VERSION = '0.32';
   8
   9 sub moose_version(){ 0.90 } # which Mouse is a subset of
  10
  11 use Carp 'confess';
  12 use Scalar::Util 'blessed';
  13
  14 use Mouse::Util qw(load_class is_class_loaded);
  15
  16 use Mouse::Meta::Module;
  17 use Mouse::Meta::Class;
  18 use Mouse::Meta::Role;
  19 use Mouse::Meta::Attribute;
  20 use Mouse::Object;
  21 use Mouse::Util::TypeConstraints ();
  22
  23 our @EXPORT = qw(extends has before after around override super blessed confess with);
  24
  25 our %is_removable = map{ $_ => undef } @EXPORT;
  26 delete $is_removable{blessed};
  27 delete $is_removable{confess};
  28
  29 sub extends { Mouse::Meta::Class->initialize(scalar caller)->superclasses(@_) }
  30
  31 sub has {
  32     my $meta = Mouse::Meta::Class->initialize(scalar caller);
  33     $meta->add_attribute(@_);
  34 }
  35
  36 sub before {
  37     my $meta = Mouse::Meta::Class->initialize(scalar caller);
  38
  39     my $code = pop;
  40
  41     for (@_) {
  42         $meta->add_before_method_modifier($_ => $code);
  43     }
  44 }
  45
  46 sub after {
  47     my $meta = Mouse::Meta::Class->initialize(scalar caller);
  48
  49     my $code = pop;
  50
  51     for (@_) {
  52         $meta->add_after_method_modifier($_ => $code);
  53     }
  54 }
  55
  56 sub around {
  57     my $meta = Mouse::Meta::Class->initialize(scalar caller);
  58
  59     my $code = pop;
  60
  61     for (@_) {
  62         $meta->add_around_method_modifier($_ => $code);
  63     }
  64 }
  65
  66 sub with {
  67     Mouse::Util::apply_all_roles(scalar(caller), @_);
  68 }
  69
  70 our $SUPER_PACKAGE;
  71 our $SUPER_BODY;
  72 our @SUPER_ARGS;
  73
  74 sub super {
  75     # This check avoids a recursion loop - see
  76     # t/100_bugs/020_super_recursion.t
  77     return if defined $SUPER_PACKAGE && $SUPER_PACKAGE ne caller();
  78     return unless $SUPER_BODY; $SUPER_BODY->(@SUPER_ARGS);
  79 }
  80
  81 sub override {
  82     my $meta = Mouse::Meta::Class->initialize(caller);
  83     my $pkg = $meta->name;
  84
  85     my $name = shift;
  86     my $code = shift;
  87
  88     my $body = $pkg->can($name)
  89         or confess "You cannot override '$name' because it has no super method";
  90
  91     $meta->add_method($name => sub {
  92         local $SUPER_PACKAGE = $pkg;
  93         local @SUPER_ARGS = @_;
  94         local $SUPER_BODY = $body;
  95
  96         $code->(@_);
  97     });
  98 }
  99
 100 sub init_meta {
 101     shift;
 102     my %args = @_;
 103
 104     my $class = $args{for_class}
 105                     or confess("Cannot call init_meta without specifying a for_class");
 106     my $base_class = $args{base_class} || 'Mouse::Object';
 107     my $metaclass  = $args{metaclass}  || 'Mouse::Meta::Class';
 108
 109     confess("The Metaclass $metaclass must be a subclass of Mouse::Meta::Class.")
 110             unless $metaclass->isa('Mouse::Meta::Class');
 111
 112     # make a subtype for each Mouse class
 113     Mouse::Util::TypeConstraints::class_type($class)
 114         unless Mouse::Util::TypeConstraints::find_type_constraint($class);
 115
 116     my $meta = $metaclass->initialize($class);
 117
 118     $meta->add_method(meta => sub{
 119         return $metaclass->initialize(ref($_[0]) || $_[0]);
 120     });
 121
 122     $meta->superclasses($base_class)
 123         unless $meta->superclasses;
 124
 125     return $meta;
 126 }
 127
 128 sub import {
 129     my $class = shift;
 130
 131     strict->import;
 132     warnings->import;
 133
 134     my $opts = do {
 135         if (ref($_[0]) && ref($_[0]) eq 'HASH') {
 136             shift @_;
 137         } else {
 138             +{ };
 139         }
 140     };
 141     my $level = delete $opts->{into_level};
 142        $level = 0 unless defined $level;
 143     my $caller = caller($level);
 144
 145     # we should never export to main
 146     if ($caller eq 'main') {
 147         warn qq{$class does not export its sugar to the 'main' package.\n};
 148         return;
 149     }
 150
 151     $class->init_meta(
 152         for_class  => $caller,
 153     );
 154
 155     if (@_) {
 156         __PACKAGE__->export_to_level( $level+1, $class, @_);
 157     } else {
 158         # shortcut for the common case of no type character
 159         no strict 'refs';
 160         for my $keyword (@EXPORT) {
 161             *{ $caller . '::' . $keyword } = *{__PACKAGE__ . '::' . $keyword};
 162         }
 163     }
 164 }
 165
 166 sub unimport {
 167     my $caller = caller;
 168
 169     my $stash = do{
 170         no strict 'refs';
 171         \%{$caller . '::'}
 172     };
 173
 174     for my $keyword (@EXPORT) {
 175         my $code;
 176         if(exists $is_removable{$keyword}
 177             && ($code = $caller->can($keyword))
 178             && (Mouse::Util::get_code_info($code))[0] eq __PACKAGE__){
 179
 180             delete $stash->{$keyword};
 181         }
 182     }
 183 }
 184
 185 1;
 186
 187 __END__
 188
 189 =head1 NAME
 190
 191 Mouse - Moose minus the antlers
 192
 193 =head1 SYNOPSIS
 194
 195     package Point;
 196     use Mouse; # automatically turns on strict and warnings
 197
 198     has 'x' => (is => 'rw', isa => 'Int');
 199     has 'y' => (is => 'rw', isa => 'Int');
 200
 201     sub clear {
 202         my $self = shift;
 203         $self->x(0);
 204         $self->y(0);
 205     }
 206
 207     package Point3D;
 208     use Mouse;
 209
 210     extends 'Point';
 211
 212     has 'z' => (is => 'rw', isa => 'Int');
 213
 214     after 'clear' => sub {
 215         my $self = shift;
 216         $self->z(0);
 217     };
 218
 219 =head1 DESCRIPTION
 220
 221 L<Moose> is wonderful. B<Use Moose instead of Mouse.>
 222
 223 Unfortunately, Moose has a compile-time penalty. Though significant progress
 224 has been made over the years, the compile time penalty is a non-starter for
 225 some very specific applications. If you are writing a command-line application
 226 or CGI script where startup time is essential, you may not be able to use
 227 Moose. We recommend that you instead use L<HTTP::Engine> and FastCGI for the
 228 latter, if possible.
 229
 230 Mouse aims to alleviate this by providing a subset of Moose's functionality,
 231 faster.
 232
 233 We're also going as light on dependencies as possible.
 234 L<Class::Method::Modifiers::Fast> or L<Class::Method::Modifiers> is required
 235 if you want support for L</before>, L</after>, and L</around>.
 236
 237 =head2 MOOSE COMPAT
 238
 239 Compatibility with Moose has been the utmost concern. Fewer than 1% of the
 240 tests fail when run against Moose instead of Mouse. Mouse code coverage is also
 241 over 96%. Even the error messages are taken from Moose. The Mouse code just
 242 runs the test suite 4x faster.
 243
 244 The idea is that, if you need the extra power, you should be able to run
 245 C<s/Mouse/Moose/g> on your codebase and have nothing break. To that end,
 246 we have written L<Any::Moose> which will act as Mouse unless Moose is loaded,
 247 in which case it will act as Moose. Since Mouse is a little sloppier than
 248 Moose, if you run into weird errors, it would be worth running:
 249
 250     ANY_MOOSE=Moose perl your-script.pl
 251
 252 to see if the bug is caused by Mouse. Moose's diagnostics and validation are
 253 also much better.
 254
 255 =head2 MouseX
 256
 257 Please don't copy MooseX code to MouseX. If you need extensions, you really
 258 should upgrade to Moose. We don't need two parallel sets of extensions!
 259
 260 If you really must write a Mouse extension, please contact the Moose mailing
 261 list or #moose on IRC beforehand.
 262
 263 =head2 Maintenance
 264
 265 The original author of this module has mostly stepped down from maintaining
 266 Mouse. See L<http://www.nntp.perl.org/group/perl.moose/2009/04/msg653.html>.
 267 If you would like to help maintain this module, please get in touch with us.
 268
 269 =head1 KEYWORDS
 270
 271 =head2 meta -> Mouse::Meta::Class
 272
 273 Returns this class' metaclass instance.
 274
 275 =head2 extends superclasses
 276
 277 Sets this class' superclasses.
 278
 279 =head2 before (method|methods) => Code
 280
 281 Installs a "before" method modifier. See L<Moose/before> or
 282 L<Class::Method::Modifiers/before>.
 283
 284 Use of this feature requires L<Class::Method::Modifiers>!
 285
 286 =head2 after (method|methods) => Code
 287
 288 Installs an "after" method modifier. See L<Moose/after> or
 289 L<Class::Method::Modifiers/after>.
 290
 291 Use of this feature requires L<Class::Method::Modifiers>!
 292
 293 =head2 around (method|methods) => Code
 294
 295 Installs an "around" method modifier. See L<Moose/around> or
 296 L<Class::Method::Modifiers/around>.
 297
 298 Use of this feature requires L<Class::Method::Modifiers>!
 299
 300 =head2 has (name|names) => parameters
 301
 302 Adds an attribute (or if passed an arrayref of names, multiple attributes) to
 303 this class. Options:
 304
 305 =over 4
 306
 307 =item is => ro|rw
 308
 309 If specified, inlines a read-only/read-write accessor with the same name as
 310 the attribute.
 311
 312 =item isa => TypeConstraint
 313
 314 Provides type checking in the constructor and accessor. The following types are
 315 supported. Any unknown type is taken to be a class check (e.g. isa =>
 316 'DateTime' would accept only L<DateTime> objects).
 317
 318     Any Item Bool Undef Defined Value Num Int Str ClassName
 319     Ref ScalarRef ArrayRef HashRef CodeRef RegexpRef GlobRef
 320     FileHandle Object
 321
 322 For more documentation on type constraints, see L<Mouse::Util::TypeConstraints>.
 323
 324
 325 =item required => 0|1
 326
 327 Whether this attribute is required to have a value. If the attribute is lazy or
 328 has a builder, then providing a value for the attribute in the constructor is
 329 optional.
 330
 331 =item init_arg => Str | Undef
 332
 333 Allows you to use a different key name in the constructor.  If undef, the
 334 attribue can't be passed to the constructor.
 335
 336 =item default => Value | CodeRef
 337
 338 Sets the default value of the attribute. If the default is a coderef, it will
 339 be invoked to get the default value. Due to quirks of Perl, any bare reference
 340 is forbidden, you must wrap the reference in a coderef. Otherwise, all
 341 instances will share the same reference.
 342
 343 =item lazy => 0|1
 344
 345 If specified, the default is calculated on demand instead of in the
 346 constructor.
 347
 348 =item predicate => Str
 349
 350 Lets you specify a method name for installing a predicate method, which checks
 351 that the attribute has a value. It will not invoke a lazy default or builder
 352 method.
 353
 354 =item clearer => Str
 355
 356 Lets you specify a method name for installing a clearer method, which clears
 357 the attribute's value from the instance. On the next read, lazy or builder will
 358 be invoked.
 359
 360 =item handles => HashRef|ArrayRef
 361
 362 Lets you specify methods to delegate to the attribute. ArrayRef forwards the
 363 given method names to method calls on the attribute. HashRef maps local method
 364 names to remote method names called on the attribute. Other forms of
 365 L</handles>, such as regular expression and coderef, are not yet supported.
 366
 367 =item weak_ref => 0|1
 368
 369 Lets you automatically weaken any reference stored in the attribute.
 370
 371 Use of this feature requires L<Scalar::Util>!
 372
 373 =item trigger => CodeRef
 374
 375 Any time the attribute's value is set (either through the accessor or the constructor), the trigger is called on it. The trigger receives as arguments the instance, the new value, and the attribute instance.
 376
 377 Mouse 0.05 supported more complex triggers, but this behavior is now removed.
 378
 379 =item builder => Str
 380
 381 Defines a method name to be called to provide the default value of the
 382 attribute. C<< builder => 'build_foo' >> is mostly equivalent to
 383 C<< default => sub { $_[0]->build_foo } >>.
 384
 385 =item auto_deref => 0|1
 386
 387 Allows you to automatically dereference ArrayRef and HashRef attributes in list
 388 context. In scalar context, the reference is returned (NOT the list length or
 389 bucket status). You must specify an appropriate type constraint to use
 390 auto_deref.
 391
 392 =item lazy_build => 0|1
 393
 394 Automatically define lazy => 1 as well as builder => "_build_$attr", clearer =>
 395 "clear_$attr', predicate => 'has_$attr' unless they are already defined.
 396
 397 =back
 398
 399 =head2 confess error -> BOOM
 400
 401 L<Carp/confess> for your convenience.
 402
 403 =head2 blessed value -> ClassName | undef
 404
 405 L<Scalar::Util/blessed> for your convenience.
 406
 407 =head1 MISC
 408
 409 =head2 import
 410
 411 Importing Mouse will default your class' superclass list to L<Mouse::Object>.
 412 You may use L</extends> to replace the superclass list.
 413
 414 =head2 unimport
 415
 416 Please unimport Mouse (C<no Mouse>) so that if someone calls one of the
 417 keywords (such as L</extends>) it will break loudly instead breaking subtly.
 418
 419 =head1 FUNCTIONS
 420
 421 =head2 load_class Class::Name
 422
 423 This will load a given C<Class::Name> (or die if it's not loadable).
 424 This function can be used in place of tricks like
 425 C<eval "use $module"> or using C<require>.
 426
 427 =head2 is_class_loaded Class::Name -> Bool
 428
 429 Returns whether this class is actually loaded or not. It uses a heuristic which
 430 involves checking for the existence of C<$VERSION>, C<@ISA>, and any
 431 locally-defined method.
 432
 433 =head1 SOURCE CODE ACCESS
 434
 435 We have a public git repo:
 436
 437  git clone git://jules.scsys.co.uk/gitmo/Mouse.git
 438
 439 =head1 AUTHORS
 440
 441 Shawn M Moore, C<< <sartak at gmail.com> >>
 442
 443 Yuval Kogman, C<< <nothingmuch at woobling.org> >>
 444
 445 tokuhirom
 446
 447 Yappo
 448
 449 wu-lee
 450
 451 Goro Fuji (gfx) C<< <gfuji at cpan.org> >>
 452
 453 with plenty of code borrowed from L<Class::MOP> and L<Moose>
 454
 455 =head1 BUGS
 456
 457 There is a known issue with Mouse on 5.6.2 regarding the @ISA tests. Until
 458 this is resolve the minimum version of Perl for Mouse is set to 5.8.0. Patches
 459 to resolve these tests are more than welcome.
 460
 461 Please report any bugs through RT: email
 462 C<bug-mouse at rt.cpan.org>, or browse
 463 L<http://rt.cpan.org/NoAuth/ReportBug.html?Queue=Mouse>.
 464
 465 =head1 COPYRIGHT AND LICENSE
 466
 467 Copyright 2008-2009 Infinity Interactive, Inc.
 468
 469 http://www.iinteractive.com/
 470
 471 This program is free software; you can redistribute it and/or modify it
 472 under the same terms as Perl itself.
 473
 474 =cut
 475