lib/Mouse.pm

   1 package Mouse;
   2 use 5.006_002;
   3
   4 use Mouse::Exporter; # enables strict and warnings
   5
   6 our $VERSION = '0.37_04';
   7
   8 use Carp qw(confess);
   9 use Scalar::Util qw(blessed);
  10
  11 use Mouse::Util qw(load_class is_class_loaded get_code_package not_supported);
  12
  13 use Mouse::Meta::Module;
  14 use Mouse::Meta::Class;
  15 use Mouse::Meta::Role;
  16 use Mouse::Meta::Attribute;
  17 use Mouse::Object;
  18 use Mouse::Util::TypeConstraints ();
  19
  20 Mouse::Exporter->setup_import_methods(
  21     as_is => [qw(
  22         extends with
  23         has
  24         before after around
  25         override super
  26         augment  inner
  27     ),
  28         \&Scalar::Util::blessed,
  29         \&Carp::confess,
  30    ],
  31 );
  32
  33 # XXX: for backward compatibility
  34 our @EXPORT = qw(
  35     extends with
  36     has
  37     before after around
  38     override super
  39     augment  inner
  40     blessed confess
  41 );
  42
  43 sub extends { Mouse::Meta::Class->initialize(scalar caller)->superclasses(@_) }
  44
  45 sub has {
  46     my $meta = Mouse::Meta::Class->initialize(scalar caller);
  47     my $name = shift;
  48
  49     $meta->throw_error(q{Usage: has 'name' => ( key => value, ... )})\r
  50         if @_ % 2; # odd number of arguments
  51
  52     $meta->add_attribute($_ => @_) for ref($name) ? @{$name} : $name;
  53 }
  54
  55 sub before {
  56     my $meta = Mouse::Meta::Class->initialize(scalar caller);
  57
  58     my $code = pop;
  59
  60     for (@_) {
  61         $meta->add_before_method_modifier($_ => $code);
  62     }
  63 }
  64
  65 sub after {
  66     my $meta = Mouse::Meta::Class->initialize(scalar caller);
  67
  68     my $code = pop;
  69
  70     for (@_) {
  71         $meta->add_after_method_modifier($_ => $code);
  72     }
  73 }
  74
  75 sub around {
  76     my $meta = Mouse::Meta::Class->initialize(scalar caller);
  77
  78     my $code = pop;
  79
  80     for (@_) {
  81         $meta->add_around_method_modifier($_ => $code);
  82     }
  83 }
  84
  85 sub with {
  86     Mouse::Util::apply_all_roles(scalar(caller), @_);
  87 }
  88
  89 our $SUPER_PACKAGE;
  90 our $SUPER_BODY;
  91 our @SUPER_ARGS;
  92
  93 sub super {
  94     # This check avoids a recursion loop - see
  95     # t/100_bugs/020_super_recursion.t
  96     return if  defined $SUPER_PACKAGE && $SUPER_PACKAGE ne caller();
  97     return if !defined $SUPER_BODY;
  98     $SUPER_BODY->(@SUPER_ARGS);
  99 }
 100
 101 sub override {
 102     # my($name, $method) = @_;
 103     Mouse::Meta::Class->initialize(scalar caller)->add_override_method_modifier(@_);
 104 }
 105
 106 our %INNER_BODY;
 107 our %INNER_ARGS;
 108
 109 sub inner {
 110     my $pkg = caller();
 111     if ( my $body = $INNER_BODY{$pkg} ) {
 112         my $args = $INNER_ARGS{$pkg};
 113         local $INNER_ARGS{$pkg};
 114         local $INNER_BODY{$pkg};
 115         return $body->(@{$args});
 116     }
 117     else {
 118         return;
 119     }
 120 }
 121
 122 sub augment {
 123     #my($name, $method) = @_;
 124     Mouse::Meta::Class->initialize(scalar caller)->add_augment_method_modifier(@_);
 125 }
 126
 127 sub init_meta {
 128     shift;
 129     my %args = @_;
 130
 131     my $class = $args{for_class}
 132                     or confess("Cannot call init_meta without specifying a for_class");
 133     my $base_class = $args{base_class} || 'Mouse::Object';
 134     my $metaclass  = $args{metaclass}  || 'Mouse::Meta::Class';
 135
 136     # make a subtype for each Mouse class
 137     Mouse::Util::TypeConstraints::class_type($class)
 138         unless Mouse::Util::TypeConstraints::find_type_constraint($class);
 139
 140     my $meta = $metaclass->initialize($class);
 141
 142     $meta->add_method(meta => sub{
 143         return $metaclass->initialize(ref($_[0]) || $_[0]);
 144     });
 145
 146     $meta->superclasses($base_class)
 147         unless $meta->superclasses;
 148
 149     return $meta;
 150 }
 151
 152
 153 1;
 154 __END__
 155
 156 =head1 NAME
 157
 158 Mouse - Moose minus the antlers
 159
 160 =head1 VERSION
 161
 162 This document describes Mouse version 0.037_04
 163
 164 =head1 SYNOPSIS
 165
 166     package Point;
 167     use Mouse; # automatically turns on strict and warnings
 168
 169     has 'x' => (is => 'rw', isa => 'Int');
 170     has 'y' => (is => 'rw', isa => 'Int');
 171
 172     sub clear {
 173         my $self = shift;
 174         $self->x(0);
 175         $self->y(0);
 176     }
 177
 178     package Point3D;
 179     use Mouse;
 180
 181     extends 'Point';
 182
 183     has 'z' => (is => 'rw', isa => 'Int');
 184
 185     after 'clear' => sub {
 186         my $self = shift;
 187         $self->z(0);
 188     };
 189
 190 =head1 DESCRIPTION
 191
 192 L<Moose> is wonderful. B<Use Moose instead of Mouse.>
 193
 194 Unfortunately, Moose has a compile-time penalty. Though significant progress
 195 has been made over the years, the compile time penalty is a non-starter for
 196 some very specific applications. If you are writing a command-line application
 197 or CGI script where startup time is essential, you may not be able to use
 198 Moose. We recommend that you instead use L<HTTP::Engine> and FastCGI for the
 199 latter, if possible.
 200
 201 Mouse aims to alleviate this by providing a subset of Moose's functionality,
 202 faster.
 203
 204 We're also going as light on dependencies as possible.
 205 L<Class::Method::Modifiers::Fast> or L<Class::Method::Modifiers> is required
 206 if you want support for L</before>, L</after>, and L</around>.
 207
 208 =head2 MOOSE COMPATIBILITY
 209
 210 Compatibility with Moose has been the utmost concern. Fewer than 1% of the
 211 tests fail when run against Moose instead of Mouse. Mouse code coverage is also
 212 over 96%. Even the error messages are taken from Moose. The Mouse code just
 213 runs the test suite 4x faster.
 214
 215 The idea is that, if you need the extra power, you should be able to run
 216 C<s/Mouse/Moose/g> on your codebase and have nothing break. To that end,
 217 we have written L<Any::Moose> which will act as Mouse unless Moose is loaded,
 218 in which case it will act as Moose. Since Mouse is a little sloppier than
 219 Moose, if you run into weird errors, it would be worth running:
 220
 221     ANY_MOOSE=Moose perl your-script.pl
 222
 223 to see if the bug is caused by Mouse. Moose's diagnostics and validation are
 224 also much better.
 225
 226 =head2 MouseX
 227
 228 Please don't copy MooseX code to MouseX. If you need extensions, you really
 229 should upgrade to Moose. We don't need two parallel sets of extensions!
 230
 231 If you really must write a Mouse extension, please contact the Moose mailing
 232 list or #moose on IRC beforehand.
 233
 234 =head1 KEYWORDS
 235
 236 =head2 C<< $object->meta -> Mouse::Meta::Class >>
 237
 238 Returns this class' metaclass instance.
 239
 240 =head2 C<< extends superclasses >>
 241
 242 Sets this class' superclasses.
 243
 244 =head2 C<< before (method|methods) => CodeRef >>
 245
 246 Installs a "before" method modifier. See L<Moose/before> or
 247 L<Class::Method::Modifiers/before>.
 248
 249 Use of this feature requires L<Class::Method::Modifiers>!
 250
 251 =head2 C<< after (method|methods) => CodeRef >>
 252
 253 Installs an "after" method modifier. See L<Moose/after> or
 254 L<Class::Method::Modifiers/after>.
 255
 256 Use of this feature requires L<Class::Method::Modifiers>!
 257
 258 =head2 C<< around (method|methods) => CodeRef >>
 259
 260 Installs an "around" method modifier. See L<Moose/around> or
 261 L<Class::Method::Modifiers/around>.
 262
 263 Use of this feature requires L<Class::Method::Modifiers>!
 264
 265 =head2 C<< has (name|names) => parameters >>
 266
 267 Adds an attribute (or if passed an arrayref of names, multiple attributes) to
 268 this class. Options:
 269
 270 =over 4
 271
 272 =item C<< is => ro|rw|bare >>
 273
 274 If specified, inlines a read-only/read-write accessor with the same name as
 275 the attribute.
 276
 277 =item C<< isa => TypeConstraint >>
 278
 279 Provides type checking in the constructor and accessor. The following types are
 280 supported. Any unknown type is taken to be a class check
 281 (e.g. C<< isa => 'DateTime' >> would accept only L<DateTime> objects).
 282
 283     Any Item Bool Undef Defined Value Num Int Str ClassName
 284     Ref ScalarRef ArrayRef HashRef CodeRef RegexpRef GlobRef
 285     FileHandle Object
 286
 287 For more documentation on type constraints, see L<Mouse::Util::TypeConstraints>.
 288
 289
 290 =item C<< required => Bool >>
 291
 292 Whether this attribute is required to have a value. If the attribute is lazy or
 293 has a builder, then providing a value for the attribute in the constructor is
 294 optional.
 295
 296 =item C<< init_arg => Str | Undef >>
 297
 298 Allows you to use a different key name in the constructor.  If undef, the
 299 attribute can't be passed to the constructor.
 300
 301 =item C<< default => Value | CodeRef >>
 302
 303 Sets the default value of the attribute. If the default is a coderef, it will
 304 be invoked to get the default value. Due to quirks of Perl, any bare reference
 305 is forbidden, you must wrap the reference in a coderef. Otherwise, all
 306 instances will share the same reference.
 307
 308 =item C<< lazy => Bool >>
 309
 310 If specified, the default is calculated on demand instead of in the
 311 constructor.
 312
 313 =item C<< predicate => Str >>
 314
 315 Lets you specify a method name for installing a predicate method, which checks
 316 that the attribute has a value. It will not invoke a lazy default or builder
 317 method.
 318
 319 =item C<< clearer => Str >>
 320
 321 Lets you specify a method name for installing a clearer method, which clears
 322 the attribute's value from the instance. On the next read, lazy or builder will
 323 be invoked.
 324
 325 =item C<< handles => HashRef|ArrayRef >>
 326
 327 Lets you specify methods to delegate to the attribute. ArrayRef forwards the
 328 given method names to method calls on the attribute. HashRef maps local method
 329 names to remote method names called on the attribute. Other forms of
 330 L</handles>, such as regular expression and coderef, are not yet supported.
 331
 332 =item C<< weak_ref => Bool >>
 333
 334 Lets you automatically weaken any reference stored in the attribute.
 335
 336 Use of this feature requires L<Scalar::Util>!
 337
 338 =item C<< trigger => CodeRef >>
 339
 340 Any time the attribute's value is set (either through the accessor or the constructor), the trigger is called on it. The trigger receives as arguments the instance, the new value, and the attribute instance.
 341
 342 =item C<< builder => Str >>
 343
 344 Defines a method name to be called to provide the default value of the
 345 attribute. C<< builder => 'build_foo' >> is mostly equivalent to
 346 C<< default => sub { $_[0]->build_foo } >>.
 347
 348 =item C<< auto_deref => Bool >>
 349
 350 Allows you to automatically dereference ArrayRef and HashRef attributes in list
 351 context. In scalar context, the reference is returned (NOT the list length or
 352 bucket status). You must specify an appropriate type constraint to use
 353 auto_deref.
 354
 355 =item C<< lazy_build => Bool >>
 356
 357 Automatically define the following options:
 358
 359     has $attr => (
 360         # ...
 361         lazy      => 1
 362         builder   => "_build_$attr",
 363         clearer   => "clear_$attr",
 364         predicate => "has_$attr",
 365     );
 366
 367 =back
 368
 369 =head2 C<< confess(message) -> BOOM >>
 370
 371 L<Carp/confess> for your convenience.
 372
 373 =head2 C<< blessed(value) -> ClassName | undef >>
 374
 375 L<Scalar::Util/blessed> for your convenience.
 376
 377 =head1 MISC
 378
 379 =head2 import
 380
 381 Importing Mouse will default your class' superclass list to L<Mouse::Object>.
 382 You may use L</extends> to replace the superclass list.
 383
 384 =head2 unimport
 385
 386 Please unimport Mouse (C<no Mouse>) so that if someone calls one of the
 387 keywords (such as L</extends>) it will break loudly instead breaking subtly.
 388
 389 =head1 SOURCE CODE ACCESS
 390
 391 We have a public git repository:
 392
 393  git clone git://jules.scsys.co.uk/gitmo/Mouse.git
 394
 395 =head1 DEPENDENCIES
 396
 397 Perl 5.6.2 or later.
 398
 399 =head1 SEE ALSO
 400
 401 L<Moose>
 402
 403 L<Class::MOP>
 404
 405 =head1 AUTHORS
 406
 407 Shawn M Moore, E<lt>sartak at gmail.comE<gt>
 408
 409 Yuval Kogman, E<lt>nothingmuch at woobling.orgE<gt>
 410
 411 tokuhirom
 412
 413 Yappo
 414
 415 wu-lee
 416
 417 Goro Fuji (gfx) E<lt>gfuji at cpan.orgE<gt>
 418
 419 with plenty of code borrowed from L<Class::MOP> and L<Moose>
 420
 421 =head1 BUGS
 422
 423 All complex software has bugs lurking in it, and this module is no exception.
 424 Please report any bugs to C<bug-mouse at rt.cpan.org>, or through the web
 425 interface at L<http://rt.cpan.org/Public/Dist/Display.html?Name=Mouse>
 426
 427 =head1 COPYRIGHT AND LICENSE
 428
 429 Copyright 2008-2009 Infinity Interactive, Inc.
 430
 431 http://www.iinteractive.com/
 432
 433 This program is free software; you can redistribute it and/or modify it
 434 under the same terms as Perl itself.
 435
 436 =cut
 437