Makefile.PL

   1 use strict;
   2 use warnings;
   3 use inc::Module::Install;
   4
   5 system($^X, 'author/generate-mouse-tiny.pl', 'lib/Mouse/Tiny.pm') == 0
   6     or warn "Cannot generate Mouse::Tiny: $!";
   7
   8 name     'Mouse';
   9 all_from 'lib/Mouse.pm';
  10
  11 tests 't/*.t t/*/*.t';
  12
  13 # Scalar::Util < 1.14 has a bug.
  14 # > Fixed looks_like_number(undef) to return false for perl >= 5.009002
  15 requires 'Scalar::Util' => 1.14;
  16
  17 test_requires 'Test::More'      => 0.88;
  18 test_requires 'Test::Exception' => 0.27;
  19 # test_requires 'Test::Output'    => 0.16; # too many dependencies!
  20
  21 include 'Test::Exception'; # work around 0.27_0x (its use of diehook might be wrong)
  22
  23 recommends 'MRO::Compat' if $] < 5.010;
  24
  25 if ($Module::Install::AUTHOR) {
  26     local @INC = ('lib', @INC);
  27     require 'lib/Mouse/Spec.pm';
  28     my $require_version = Mouse::Spec->MooseVersion;
  29
  30     if (eval{ require Moose; Moose->VERSION($require_version) }) {
  31         if (eval 'use Module::Install::AuthorTests; 1') {
  32             create_moose_compatibility_test();
  33             recursive_author_tests('xt');
  34         } else {
  35             print "you don't have a M::I::AuthorTests.\n";
  36         }
  37     } else {
  38         print "you don't have Moose $require_version. skipping moose compatibility test\n";
  39     }
  40 }
  41
  42 WriteAll check_nmake => 0;
  43
  44 sub create_moose_compatibility_test {
  45     require File::Path;
  46     require File::Spec;
  47     require File::Basename;
  48
  49     print "Creating compatibility tests in xt/compatibility/* ...\n";
  50
  51     File::Path::rmtree(File::Spec->catfile('xt', 'compatibility'));
  52
  53     # some test does not pass... currently skip it.
  54     my %SKIP_TEST = (
  55         '016-trigger.t'    => "trigger's argument is incompatble :(",
  56         '010-isa-or.t'     => "Mouse has a [BUG]",
  57
  58         '052-undefined-type-in-union.t' => "Mouse accepts undefined type as a member of union types",
  59         '054-anon-leak.t'     => 'Moose has memory leaks',
  60
  61         '600-tiny-tiny.t'     => "Moose doesn't support ::Tiny",
  62         '601-tiny-mouse.t'    => "Moose doesn't support ::Tiny",
  63         '602-mouse-tiny.t'    => "Moose doesn't support ::Tiny",
  64
  65         '031_roles_applied_in_create.t' => 't/lib/* classes are not Moose classes/roles',
  66     );
  67
  68     my @compat_tests;
  69
  70     File::Find::find(
  71         {
  72             wanted => sub {
  73                 return unless -f $_;
  74
  75                 return if /failing/; # skip tests in failing/ directories which  are Moose specific
  76
  77                 return if /with_moose/; # tests with Moose
  78                 return if /100_bugs/;   # some tests require Mouse specific files
  79                 return if /deprecated/;
  80
  81                 my $basename = File::Basename::basename($_);
  82                 return if $basename =~ /^\./;
  83
  84                 if(exists $SKIP_TEST{$basename}){
  85                     print "# skip $basename because: $SKIP_TEST{$basename}\n";
  86                     return;
  87                 }
  88
  89                 my $dirname = File::Basename::dirname($_);
  90
  91                 my $tmpdir = File::Spec->catfile('xt', 'compatibility', $dirname);
  92                 File::Path::mkpath($tmpdir);
  93
  94                 my $tmpfile = File::Spec->catfile($tmpdir, $basename);
  95                 open my $wfh, '>', $tmpfile or die $!;
  96                 print $wfh do {
  97                     my $src = do {
  98                         open my $rfh, '<', $_ or die $!;
  99                         my $s = do { local $/; <$rfh> };
 100                         close $rfh;
 101                         $s;
 102                     };
 103                     $src =~ s/Mouse::(?:Util::)?is_class_loaded/Class::MOP::is_class_loaded/g;
 104                     $src =~ s/Mouse::(?:Util::)?load_class/Class::MOP::load_class/g;
 105                     $src =~ s/Mouse/Moose/g;
 106                     $src;
 107                 };
 108                 close $wfh;
 109                 push @compat_tests, $tmpfile;
 110             },
 111             no_chdir => 1
 112         },
 113         't',
 114     );
 115     print "Compatibility tests created.\n";
 116
 117     clean_files "@compat_tests";
 118 }
 119