Makefile.PL

   1 use strict;
   2 use warnings;
   3 use inc::Module::Install;
   4 use 5.008;
   5
   6 name     'Mouse';
   7 all_from 'lib/Mouse.pm';
   8
   9 tests 't/*.t t/*/*.t';
  10
  11 # Scalar::Util < 1.14 has a bug.
  12 # > Fixed looks_like_number(undef) to return false for perl >= 5.009002
  13 requires 'Scalar::Util' => 1.14;
  14
  15 test_requires 'Test::Exception' => 0.21;
  16 test_requires 'Test::More'      => 0.80;
  17
  18 if ($Module::Install::AUTHOR) {
  19     local @INC = ('lib', @INC);
  20     require 'lib/Mouse.pm'; # for moose_version()
  21     my $require_version = Mouse->moose_version;
  22
  23     if (eval{ require Moose; Moose->VERSION($require_version) }) {
  24         if (eval 'use Module::Install::AuthorTests; 1') {
  25             create_moose_compatibility_test();
  26             recursive_author_tests('xt');
  27         } else {
  28             print "you don't have a M::I::AuthorTests.\n";
  29         }
  30     } else {
  31         print "you don't have Moose $require_version. skipping moose compatibility test\n";
  32     }
  33     system("author/generate-mouse-tiny.pl");
  34 }
  35
  36 auto_include;
  37 WriteAll;
  38
  39 sub create_moose_compatibility_test {
  40     require File::Path;
  41     require File::Spec;
  42     require File::Basename;
  43
  44     print "Creating compatibility tests in xt/compatibility/* ...\n";
  45
  46     File::Path::rmtree(File::Spec->catfile('xt', 'compatibility'));
  47
  48     # some test does not pass... currently skip it.
  49     my %SKIP_TEST = (
  50         '016-trigger.t'    => "trigger's argument is incompatble :(",
  51         '029-new.t'        => 'Class->new(undef) incompatible',
  52         '010-isa-or.t'     => 'Mouse has a [BUG]',
  53         '044-attribute-metaclass.t' => 'Moose::Meta::Attribute does not have a "create"',
  54         '047-attribute-metaclass-role.t' => 'Moose::Meta::Attribute does not have a "create"',
  55         '201-squirrel.t'      => 'skip Squirrel',
  56         '202-squirrel-role.t' => 'Squirrel is ...',
  57         '600-tiny-tiny.t'     => "Moose doesn't support ::Tiny",
  58         '601-tiny-mouse.t'    => "Moose doesn't support ::Tiny",
  59         '602-mouse-tiny.t'    => "Moose doesn't support ::Tiny",
  60         '031_roles_applied_in_create.t' => 't/lib/* classes are not Moose classes/roles',
  61     );
  62
  63     my @compat_tests;
  64
  65     File::Find::find(
  66         {
  67             wanted => sub {
  68                 return unless -f $_;
  69
  70                 return if /failing/; # skip tests in failing/ directories
  71
  72                 my $basename = File::Basename::basename($_);
  73                 return if $basename =~ /^\./;
  74
  75                 if(exists $SKIP_TEST{$basename}){
  76                     print "# skip $basename because: $SKIP_TEST{$basename}\n";
  77                     return;
  78                 }
  79
  80                 my $dirname = File::Basename::dirname($_);
  81
  82                 my $tmpdir = File::Spec->catfile('xt', 'compatibility', $dirname);
  83                 File::Path::mkpath($tmpdir);
  84
  85                 my $tmpfile = File::Spec->catfile($tmpdir, $basename);
  86                 open my $wfh, '>', $tmpfile or die $!;
  87                 print $wfh do {
  88                     my $src = do {
  89                         open my $rfh, '<', $_ or die $!;
  90                         my $s = do { local $/; <$rfh> };
  91                         close $rfh;
  92                         $s;
  93                     };
  94                     $src =~ s/Mouse::(?:Util::)?is_class_loaded/Class::MOP::is_class_loaded/g;
  95                     $src =~ s/Mouse::(?:Util::)?load_class/Class::MOP::load_class/g;
  96                     $src =~ s/Mouse/Moose/g;
  97                     $src;
  98                 };
  99                 close $wfh;
 100                 push @compat_tests, $tmpfile;
 101             },
 102             no_chdir => 1
 103         },
 104         't',
 105     );
 106     print "Compatibility tests created.\n";
 107
 108     clean_files "@compat_tests";
 109 }
 110