Makefile.PL

   1 # for developpers:
   2 BEGIN{
   3     if(grep{ $_ eq '--author' } @ARGV){
   4         print "^X -S cpanm < author/requires.cpanm\n";
   5         system "$^X -S cpanm < author/requires.cpanm";
   6     }
   7 }
   8
   9 use strict;
  10 use warnings;
  11 use inc::Module::Install;
  12
  13 # for co-developpers
  14 use Module::Install::XSUtil 0.22;
  15 use Module::Install::AuthorTests;
  16
  17 system($^X, 'tool/generate-mouse-tiny.pl', 'lib/Mouse/Tiny.pm') == 0
  18     or warn "Cannot generate Mouse::Tiny: $!";
  19
  20 name     'Mouse';
  21 all_from 'lib/Mouse.pm';
  22
  23 # Scalar::Util < 1.14 has a bug.
  24 # > Fixed looks_like_number(undef) to return false for perl >= 5.009002
  25 requires 'Scalar::Util' => 1.14;
  26
  27 test_requires 'Test::More'      => 0.88;
  28 test_requires 'Test::Exception' => 0.29;
  29 # test_requires 'Test::Output'    => 0.16; # too many dependencies!
  30
  31 if($] < 5.010) {
  32     recommends 'Class::C3';
  33 }
  34
  35 my %suggests = (
  36     'Class::Method::Modifiers::Fast' => 0.041,
  37     'MouseX::AttributeHelpers'       => 0.06,
  38 );
  39
  40 while(my($mod, $least) = each %suggests){
  41     if(can_use($mod)){
  42         if(!eval { $mod->VERSION($least) }){
  43             my $ver = $mod->VERSION;
  44             warn("\n",
  45                 "WARNING: $mod is installed, but its version ($ver) is too old (< $least).\n",
  46                 "         Please update $mod after installation of Mouse.\n",
  47                 "\n"
  48             );
  49         }
  50     }
  51 }
  52
  53 require 'lib/Mouse/Spec.pm'; # for the version
  54
  55 #if(Mouse::Spec->MouseVersion =~ /_/){ # DEVEL RELEASE
  56 #    require Carp::Always; Carp::Always->import();
  57 #    include_deps 'Carp::Always';
  58 #}
  59
  60 # cc_available recognizes the '--pp' and '--xs' options
  61 my $use_xs = ($] >= 5.008_001 && cc_available());
  62
  63 if($use_xs){
  64     print "Mouse configured with XS.\n",
  65           "NOTE: You can try --pp option to configure Mouse with Pure Perl.\n";
  66
  67     cc_warnings();
  68     use_ppport(3.19);
  69     cc_src_paths('xs-src');
  70 }
  71 else{
  72     print "Mouse configured with Pure Perl.\n";
  73 }
  74
  75
  76 tests 't/*.t t/*/*.t';
  77 author_tests 'xt';
  78
  79
  80 repository 'git://git.moose.perl.org/Mouse.git';
  81
  82 clean_files 'lib/Mouse/Tiny.pm $(O_FILES) test-mydeps-*.log';
  83
  84
  85 if (author_context()) {
  86     my $require_version = Mouse::Spec->MooseVersion;
  87
  88     if (eval { require Moose; Moose->VERSION($require_version) }) {
  89         print "You have Moose ", Moose->VERSION, ".\n";
  90         if (eval { require Module::Install::AuthorTests }) {
  91             do 'tool/create-moose-compatibility-tests.pl';
  92             # repeat testing
  93             # see also ExtUtils::MM_Any::test_via_harness()
  94             my $t_moose =  q{$(FULLPERLRUN) -MExtUtils::Command::MM -e}
  95                           .q{ "test_harness($(TEST_VERBOSE), '$(INST_LIB)', '$(INST_ARCHLIB)')"}
  96                           .q{ xt/compatibility/t/*/*.t } . "\n";
  97
  98             postamble qq{test_dynamic :: test_moose\n\n}
  99                     . qq{test_moose :: pure_all\n}
 100                     . qq{\t} . $t_moose;
 101         } else {
 102             print "You don't have a M::I::AuthorTests.\n";
 103         }
 104     } else {
 105         print "You don't have Moose $require_version. skipping moose compatibility test\n";
 106     }
 107
 108     if($use_xs){
 109         # repeat testing
 110         # see also ExtUtils::MM_Any::test_via_harness()
 111         my $t_pp =  q{$(FULLPERLRUN) -MExtUtils::Command::MM -e}
 112                    .q{ "do 'tool/force-pp.pl'; test_harness($(TEST_VERBOSE), '$(INST_LIB)', '$(INST_ARCHLIB)')"}
 113                    .q{ $(TEST_FILES)} . "\n";
 114
 115         postamble qq{test_dynamic :: test_pp\n\n}
 116                 . qq{test_pp :: pure_all\n}
 117                 . qq{\t} . $t_pp;
 118     }
 119 }
 120
 121
 122 WriteAll check_nmake => 0;