[gitmo/Mouse.git] / lib / Mouse / PurePerl.pm

package Mouse::PurePerl;

require Mouse::Util;

package
    Mouse::Util;

use strict;
use warnings;

use warnings FATAL => 'redefine'; # to avoid to load Mouse::PurePerl

use B ();

sub is_class_loaded {
    my $class = shift;

    return 0 if ref($class) || !defined($class) || !length($class);

    # walk the symbol table tree to avoid autovififying
    # \*{${main::}{"Foo::"}} == \*main::Foo::

    my $pack = \%::;
    foreach my $part (split('::', $class)) {
        my $entry = \$pack->{$part . '::'};
        return 0 if ref($entry) ne 'GLOB';
        $pack = *{$entry}{HASH} or return 0;
    }

    # check for $VERSION or @ISA
    return 1 if exists $pack->{VERSION}
             && defined *{$pack->{VERSION}}{SCALAR} && defined ${ $pack->{VERSION} };
    return 1 if exists $pack->{ISA}
             && defined *{$pack->{ISA}}{ARRAY} && @{ $pack->{ISA} } != 0;

    # check for any method
    foreach my $name( keys %{$pack} ) {
        my $entry = \$pack->{$name};
        return 1 if ref($entry) ne 'GLOB' || defined *{$entry}{CODE};
    }

    # fail
    return 0;
}


# taken from Sub::Identify
sub get_code_info {
    my ($coderef) = @_;
    ref($coderef) or return;

    my $cv = B::svref_2object($coderef);
    $cv->isa('B::CV') or return;

    my $gv = $cv->GV;
    $gv->isa('B::GV') or return;

    return ($gv->STASH->NAME, $gv->NAME);
}

sub get_code_package{
    my($coderef) = @_;

    my $cv = B::svref_2object($coderef);
    $cv->isa('B::CV') or return '';

    my $gv = $cv->GV;
    $gv->isa('B::GV') or return '';

    return $gv->STASH->NAME;
}

sub get_code_ref{
    my($package, $name) = @_;
    no strict 'refs';
    no warnings 'once';
    use warnings FATAL => 'uninitialized';
    return *{$package . '::' . $name}{CODE};
}

sub generate_isa_predicate_for {
    my($for_class, $name) = @_;

    my $predicate = sub{ Scalar::Util::blessed($_[0]) && $_[0]->isa($for_class) };

    if(defined $name){
        no strict 'refs';
        *{ caller() . '::' . $name } = $predicate;
        return;
    }

    return $predicate;
}


package
    Mouse::Util::TypeConstraints;

use Scalar::Util qw(blessed looks_like_number openhandle);

sub Any        { 1 }
sub Item       { 1 }

sub Bool       { $_[0] ? $_[0] eq '1' : 1 }
sub Undef      { !defined($_[0]) }
sub Defined    {  defined($_[0])  }
sub Value      {  defined($_[0]) && !ref($_[0]) }
sub Num        { !ref($_[0]) && looks_like_number($_[0]) }
sub Int        {  defined($_[0]) && !ref($_[0]) && $_[0] =~ /^-?[0-9]+$/ }
sub Str        {  defined($_[0]) && !ref($_[0]) }

sub Ref        { ref($_[0]) }
sub ScalarRef  { ref($_[0]) eq 'SCALAR' }
sub ArrayRef   { ref($_[0]) eq 'ARRAY'  }
sub HashRef    { ref($_[0]) eq 'HASH'   }
sub CodeRef    { ref($_[0]) eq 'CODE'   }
sub RegexpRef  { ref($_[0]) eq 'Regexp' }
sub GlobRef    { ref($_[0]) eq 'GLOB'   }

sub FileHandle {
    openhandle($_[0])  || (blessed($_[0]) && $_[0]->isa("IO::Handle"))
}

sub Object     { blessed($_[0]) && blessed($_[0]) ne 'Regexp' }

sub ClassName  { Mouse::Util::is_class_loaded($_[0]) }
sub RoleName   { (Mouse::Util::class_of($_[0]) || return 0)->isa('Mouse::Meta::Role') }

sub _parameterize_ArrayRef_for {
    my($type_parameter) = @_;
    my $check = $type_parameter->_compiled_type_constraint;

    return sub {
        foreach my $value (@{$_}) {
            return undef unless $check->($value);
        }
        return 1;
    }
}

sub _parameterize_HashRef_for {
    my($type_parameter) = @_;
    my $check = $type_parameter->_compiled_type_constraint;

    return sub {
        foreach my $value(values %{$_}){
            return undef unless $check->($value);
        }
        return 1;
    };
}

# 'Maybe' type accepts 'Any', so it requires parameters
sub _parameterize_Maybe_for {
    my($type_parameter) = @_;
    my $check = $type_parameter->_compiled_type_constraint;

    return sub{
        return !defined($_) || $check->($_);
    };
};


package
    Mouse::Meta::Module;

sub name          { $_[0]->{package} }

sub _method_map   { $_[0]->{methods} }
sub _attribute_map{ $_[0]->{attributes} }

sub namespace{
    my $name = $_[0]->{package};
    no strict 'refs';
    return \%{ $name . '::' };
}

sub add_method {
    my($self, $name, $code) = @_;

    if(!defined $name){
        $self->throw_error('You must pass a defined name');
    }
    if(!defined $code){
        $self->throw_error('You must pass a defined code');
    }

    if(ref($code) ne 'CODE'){
        $code = \&{$code}; # coerce
    }

    $self->{methods}->{$name} = $code; # Moose stores meta object here.

    my $pkg = $self->name;
    no strict 'refs';
    no warnings 'redefine', 'once';
    *{ $pkg . '::' . $name } = $code;
    return;
}


package
    Mouse::Meta::Class;

sub method_metaclass    { $_[0]->{method_metaclass}    || 'Mouse::Meta::Method'    }
sub attribute_metaclass { $_[0]->{attribute_metaclass} || 'Mouse::Meta::Attribute' }

sub constructor_class { $_[0]->{constructor_class} || 'Mouse::Meta::Method::Constructor' }
sub destructor_class  { $_[0]->{destructor_class}  || 'Mouse::Meta::Method::Destructor'  }

sub is_anon_class{
    return exists $_[0]->{anon_serial_id};
}

sub roles { $_[0]->{roles} }

sub linearized_isa { @{ get_linear_isa($_[0]->{package}) } }

sub get_all_attributes {
    my($self) = @_;
    my %attrs = map { %{ $self->initialize($_)->{attributes} } } reverse $self->linearized_isa;
    return values %attrs;
}

sub _initialize_object{
    my($self, $object, $args, $ignore_triggers) = @_;

    my @triggers_queue;

    foreach my $attribute ($self->get_all_attributes) {
        my $init_arg = $attribute->init_arg;
        my $slot     = $attribute->name;

        if (defined($init_arg) && exists($args->{$init_arg})) {
            $object->{$slot} = $attribute->_coerce_and_verify($args->{$init_arg}, $object);

            weaken($object->{$slot})
                if ref($object->{$slot}) && $attribute->is_weak_ref;

            if ($attribute->has_trigger) {
                push @triggers_queue, [ $attribute->trigger, $object->{$slot} ];
            }
        }
        else { # no init arg
            if ($attribute->has_default || $attribute->has_builder) {
                if (!$attribute->is_lazy) {
                    my $default = $attribute->default;
                    my $builder = $attribute->builder;
                    my $value =   $builder                ? $object->$builder()
                                : ref($default) eq 'CODE' ? $object->$default()
                                :                           $default;

                    $object->{$slot} = $attribute->_coerce_and_verify($value, $object);

                    weaken($object->{$slot})
                        if ref($object->{$slot}) && $attribute->is_weak_ref;
                }
            }
            elsif($attribute->is_required) {
                $self->throw_error("Attribute (".$attribute->name.") is required");
            }
        }
    }

    if(!$ignore_triggers){
        foreach my $trigger_and_value(@triggers_queue){
            my($trigger, $value) = @{$trigger_and_value};
            $trigger->($object, $value);
        }
    }

    if($self->is_anon_class){
        $object->{__METACLASS__} = $self;
    }

    return;
}


package
    Mouse::Meta::Role;

sub method_metaclass{ $_[0]->{method_metaclass} || 'Mouse::Meta::Role::Method' }

sub is_anon_role{
    return exists $_[0]->{anon_serial_id};
}

sub get_roles { $_[0]->{roles} }

package
    Mouse::Meta::Attribute;

require Mouse::Meta::Method::Accessor;

sub accessor_metaclass{ $_[0]->{accessor_metaclass} || 'Mouse::Meta::Method::Accessor' }

# readers

sub name                 { $_[0]->{name}                   }
sub associated_class     { $_[0]->{associated_class}       }

sub accessor             { $_[0]->{accessor}               }
sub reader               { $_[0]->{reader}                 }
sub writer               { $_[0]->{writer}                 }
sub predicate            { $_[0]->{predicate}              }
sub clearer              { $_[0]->{clearer}                }
sub handles              { $_[0]->{handles}                }

sub _is_metadata         { $_[0]->{is}                     }
sub is_required          { $_[0]->{required}               }
sub default              { $_[0]->{default}                }
sub is_lazy              { $_[0]->{lazy}                   }
sub is_lazy_build        { $_[0]->{lazy_build}             }
sub is_weak_ref          { $_[0]->{weak_ref}               }
sub init_arg             { $_[0]->{init_arg}               }
sub type_constraint      { $_[0]->{type_constraint}        }

sub trigger              { $_[0]->{trigger}                }
sub builder              { $_[0]->{builder}                }
sub should_auto_deref    { $_[0]->{auto_deref}             }
sub should_coerce        { $_[0]->{coerce}                 }

sub documentation        { $_[0]->{documentation}          }

# predicates

sub has_accessor         { exists $_[0]->{accessor}        }
sub has_reader           { exists $_[0]->{reader}          }
sub has_writer           { exists $_[0]->{writer}          }
sub has_predicate        { exists $_[0]->{predicate}       }
sub has_clearer          { exists $_[0]->{clearer}         }
sub has_handles          { exists $_[0]->{handles}         }

sub has_default          { exists $_[0]->{default}         }
sub has_type_constraint  { exists $_[0]->{type_constraint} }
sub has_trigger          { exists $_[0]->{trigger}         }
sub has_builder          { exists $_[0]->{builder}         }

sub has_documentation    { exists $_[0]->{documentation}   }

package
    Mouse::Meta::TypeConstraint;

sub name    { $_[0]->{name}    }
sub parent  { $_[0]->{parent}  }
sub message { $_[0]->{message} }

sub _compiled_type_constraint{ $_[0]->{compiled_type_constraint} }

sub _compiled_type_coercion  { $_[0]->{_compiled_type_coercion}  }

sub has_coercion{ exists $_[0]->{_compiled_type_coercion} }


sub compile_type_constraint{
    my($self) = @_;

    # add parents first
    my @checks;
    for(my $parent = $self->{parent}; defined $parent; $parent = $parent->{parent}){
         if($parent->{hand_optimized_type_constraint}){
            unshift @checks, $parent->{hand_optimized_type_constraint};
            last; # a hand optimized constraint must include all the parents
        }
        elsif($parent->{constraint}){
            unshift @checks, $parent->{constraint};
        }
    }

    # then add child
    if($self->{constraint}){
        push @checks, $self->{constraint};
    }

    if($self->{type_constraints}){ # Union
        my @types = map{ $_->{compiled_type_constraint} } @{ $self->{type_constraints} };
        push @checks, sub{
            foreach my $c(@types){
                return 1 if $c->($_[0]);
            }
            return 0;
        };
    }

    if(@checks == 0){
        $self->{compiled_type_constraint} = \&Mouse::Util::TypeConstraints::Any;
    }
    else{
        $self->{compiled_type_constraint} =  sub{
            my(@args) = @_;
            local $_ = $args[0];
            foreach my $c(@checks){
                return undef if !$c->(@args);
            }
            return 1;
        };
    }
    return;
}

package
    Mouse::Object;


sub BUILDARGS {
    my $class = shift;

    if (scalar @_ == 1) {
        (ref($_[0]) eq 'HASH')
            || $class->meta->throw_error("Single parameters to new() must be a HASH ref");

        return {%{$_[0]}};
    }
    else {
        return {@_};
    }
}

sub new {
    my $class = shift;

    $class->meta->throw_error('Cannot call new() on an instance') if ref $class;

    my $args = $class->BUILDARGS(@_);

    my $meta = Mouse::Meta::Class->initialize($class);
    my $self = $meta->new_object($args);

    # BUILDALL
    if( $self->can('BUILD') ) {
        for my $class (reverse $meta->linearized_isa) {
            my $build = Mouse::Util::get_code_ref($class, 'BUILD')
                || next;

            $self->$build($args);
        }
    }

    return $self;
}

sub DESTROY {
    my $self = shift;

    return unless $self->can('DEMOLISH'); # short circuit

    local $?;

    my $e = do{
        local $@;
        eval{

            # DEMOLISHALL

            # We cannot count on being able to retrieve a previously made
            # metaclass, _or_ being able to make a new one during global
            # destruction. However, we should still be able to use mro at
            # that time (at least tests suggest so ;)

            foreach my $class (@{ Mouse::Util::get_linear_isa(ref $self) }) {
                my $demolish = Mouse::Util::get_code_ref($class, 'DEMOLISH')
                    || next;

                $self->$demolish();
            }
        };
        $@;
    };

    no warnings 'misc';
    die $e if $e; # rethrow
}

1;
__END__

=head1 NAME

Mouse::PurePerl - A Mouse guts in pure Perl

=head1 VERSION

This document describes Mouse version 0.40_06

=head1 SEE ALSO

L<Mouse::XS>

=cut
Commit	Line	Data
ccb38d0b	1	package Mouse::PurePerl;
ccb38d0b	2
a52cca04	3	require Mouse::Util;
a52cca04	4
df6dd016	5	package
	6	Mouse::Util;
	7
	8	use strict;
	9	use warnings;
	10
	11	use warnings FATAL => 'redefine'; # to avoid to load Mouse::PurePerl
	12
	13	use B ();
	14
	15	sub is_class_loaded {
	16	my $class = shift;
	17
	18	return 0 if ref($class) \|\| !defined($class) \|\| !length($class);
	19
	20	# walk the symbol table tree to avoid autovififying
	21	# \{${main::}{"Foo::"}} == \main::Foo::
	22
	23	my $pack = \%::;
	24	foreach my $part (split('::', $class)) {
	25	my $entry = \$pack->{$part . '::'};
	26	return 0 if ref($entry) ne 'GLOB';
	27	$pack = *{$entry}{HASH} or return 0;
	28	}
	29
	30	# check for $VERSION or @ISA
	31	return 1 if exists $pack->{VERSION}
	32	&& defined *{$pack->{VERSION}}{SCALAR} && defined ${ $pack->{VERSION} };
	33	return 1 if exists $pack->{ISA}
	34	&& defined *{$pack->{ISA}}{ARRAY} && @{ $pack->{ISA} } != 0;
	35
	36	# check for any method
	37	foreach my $name( keys %{$pack} ) {
	38	my $entry = \$pack->{$name};
	39	return 1 if ref($entry) ne 'GLOB' \|\| defined *{$entry}{CODE};
	40	}
	41
	42	# fail
	43	return 0;
	44	}
	45
	46
	47	# taken from Sub::Identify
	48	sub get_code_info {
	49	my ($coderef) = @_;
	50	ref($coderef) or return;
	51
	52	my $cv = B::svref_2object($coderef);
	53	$cv->isa('B::CV') or return;
	54
	55	my $gv = $cv->GV;
	56	$gv->isa('B::GV') or return;
	57
	58	return ($gv->STASH->NAME, $gv->NAME);
	59	}
	60
	61	sub get_code_package{
	62	my($coderef) = @_;
	63
	64	my $cv = B::svref_2object($coderef);
	65	$cv->isa('B::CV') or return '';
	66
	67	my $gv = $cv->GV;
	68	$gv->isa('B::GV') or return '';
69
70	return $gv->STASH->NAME;
71	}
72
7d96ae4d	73	sub get_code_ref{
	74	my($package, $name) = @_;
	75	no strict 'refs';
	76	no warnings 'once';
	77	use warnings FATAL => 'uninitialized';
	78	return *{$package . '::' . $name}{CODE};
	79	}
	80
e3540312	81	sub generate_isa_predicate_for {
1d5ecd5f	82	my($for_class, $name) = @_;
1d5ecd5f	83
f48920c1	84	my $predicate = sub{ Scalar::Util::blessed($_[0]) && $_[0]->isa($for_class) };
1d5ecd5f	85
	86	if(defined $name){
	87	no strict 'refs';
	88	*{ caller() . '::' . $name } = $predicate;
	89	return;
	90	}
	91
	92	return $predicate;
	93	}
	94
	95
f48920c1	96	package
	97	Mouse::Util::TypeConstraints;
	98
	99	use Scalar::Util qw(blessed looks_like_number openhandle);
	100
7d96ae4d	101	sub Any { 1 }
7d96ae4d	102	sub Item { 1 }
7d96ae4d	103
	104	sub Bool { $_[0] ? $_[0] eq '1' : 1 }
	105	sub Undef { !defined($_[0]) }
	106	sub Defined { defined($_[0]) }
	107	sub Value { defined($_[0]) && !ref($_[0]) }
	108	sub Num { !ref($_[0]) && looks_like_number($_[0]) }
	109	sub Int { defined($_[0]) && !ref($_[0]) && $_[0] =~ /^-?[0-9]+$/ }
	110	sub Str { defined($_[0]) && !ref($_[0]) }
	111
	112	sub Ref { ref($_[0]) }
	113	sub ScalarRef { ref($_[0]) eq 'SCALAR' }
	114	sub ArrayRef { ref($_[0]) eq 'ARRAY' }
	115	sub HashRef { ref($_[0]) eq 'HASH' }
	116	sub CodeRef { ref($_[0]) eq 'CODE' }
	117	sub RegexpRef { ref($_[0]) eq 'Regexp' }
	118	sub GlobRef { ref($_[0]) eq 'GLOB' }
	119
	120	sub FileHandle {
	121	openhandle($_[0]) \|\| (blessed($_[0]) && $_[0]->isa("IO::Handle"))
	122	}
	123
	124	sub Object { blessed($_[0]) && blessed($_[0]) ne 'Regexp' }
	125
	126	sub ClassName { Mouse::Util::is_class_loaded($_[0]) }
	127	sub RoleName { (Mouse::Util::class_of($_[0]) \|\| return 0)->isa('Mouse::Meta::Role') }
	128
619338ac	129	sub _parameterize_ArrayRef_for {
	130	my($type_parameter) = @_;
	131	my $check = $type_parameter->_compiled_type_constraint;
	132
	133	return sub {
	134	foreach my $value (@{$_}) {
	135	return undef unless $check->($value);
	136	}
	137	return 1;
	138	}
	139	}
	140
	141	sub _parameterize_HashRef_for {
	142	my($type_parameter) = @_;
	143	my $check = $type_parameter->_compiled_type_constraint;
	144
	145	return sub {
	146	foreach my $value(values %{$_}){
	147	return undef unless $check->($value);
	148	}
	149	return 1;
	150	};
	151	}
	152
	153	# 'Maybe' type accepts 'Any', so it requires parameters
	154	sub _parameterize_Maybe_for {
	155	my($type_parameter) = @_;
	156	my $check = $type_parameter->_compiled_type_constraint;
	157
	158	return sub{
	159	return !defined($_) \|\| $check->($_);
	160	};
	161	};
	162
	163
7d96ae4d	164
43165725	165	package
	166	Mouse::Meta::Module;
	167
926404f2	168	sub name { $_[0]->{package} }
	169
	170	sub _method_map { $_[0]->{methods} }
c5f6ad05	171	sub _attribute_map{ $_[0]->{attributes} }
43165725	172
2591e962	173	sub namespace{
	174	my $name = $_[0]->{package};
	175	no strict 'refs';
	176	return \%{ $name . '::' };
	177	}
	178
3e44140b	179	sub add_method {
	180	my($self, $name, $code) = @_;
	181
	182	if(!defined $name){
	183	$self->throw_error('You must pass a defined name');
	184	}
	185	if(!defined $code){
	186	$self->throw_error('You must pass a defined code');
	187	}
	188
	189	if(ref($code) ne 'CODE'){
	190	$code = \&{$code}; # coerce
	191	}
	192
	193	$self->{methods}->{$name} = $code; # Moose stores meta object here.
	194
	195	my $pkg = $self->name;
	196	no strict 'refs';
	197	no warnings 'redefine', 'once';
	198	*{ $pkg . '::' . $name } = $code;
	199	return;
	200	}
	201
	202
43165725	203	package
	204	Mouse::Meta::Class;
	205
e058b279	206	sub method_metaclass { $_[0]->{method_metaclass} \|\| 'Mouse::Meta::Method' }
	207	sub attribute_metaclass { $_[0]->{attribute_metaclass} \|\| 'Mouse::Meta::Attribute' }
	208
	209	sub constructor_class { $_[0]->{constructor_class} \|\| 'Mouse::Meta::Method::Constructor' }
	210	sub destructor_class { $_[0]->{destructor_class} \|\| 'Mouse::Meta::Method::Destructor' }
4e7e3250	211
43165725	212	sub is_anon_class{
	213	return exists $_[0]->{anon_serial_id};
	214	}
	215
	216	sub roles { $_[0]->{roles} }
	217
cccb83de	218	sub linearized_isa { @{ get_linear_isa($_[0]->{package}) } }
cccb83de	219
da4432f3	220	sub get_all_attributes {
da4432f3	221	my($self) = @_;
047d7af0	222	my %attrs = map { %{ $self->initialize($_)->{attributes} } } reverse $self->linearized_isa;
da4432f3	223	return values %attrs;
	224	}
	225
4e7e3250	226	sub _initialize_object{
	227	my($self, $object, $args, $ignore_triggers) = @_;
	228
	229	my @triggers_queue;
	230
	231	foreach my $attribute ($self->get_all_attributes) {
	232	my $init_arg = $attribute->init_arg;
	233	my $slot = $attribute->name;
	234
	235	if (defined($init_arg) && exists($args->{$init_arg})) {
	236	$object->{$slot} = $attribute->_coerce_and_verify($args->{$init_arg}, $object);
	237
	238	weaken($object->{$slot})
	239	if ref($object->{$slot}) && $attribute->is_weak_ref;
	240
	241	if ($attribute->has_trigger) {
	242	push @triggers_queue, [ $attribute->trigger, $object->{$slot} ];
	243	}
	244	}
	245	else { # no init arg
	246	if ($attribute->has_default \|\| $attribute->has_builder) {
	247	if (!$attribute->is_lazy) {
	248	my $default = $attribute->default;
	249	my $builder = $attribute->builder;
	250	my $value = $builder ? $object->$builder()
	251	: ref($default) eq 'CODE' ? $object->$default()
	252	: $default;
	253
	254	$object->{$slot} = $attribute->_coerce_and_verify($value, $object);
	255
	256	weaken($object->{$slot})
	257	if ref($object->{$slot}) && $attribute->is_weak_ref;
	258	}
	259	}
	260	elsif($attribute->is_required) {
	261	$self->throw_error("Attribute (".$attribute->name.") is required");
	262	}
	263	}
	264	}
	265
	266	if(!$ignore_triggers){
	267	foreach my $trigger_and_value(@triggers_queue){
	268	my($trigger, $value) = @{$trigger_and_value};
	269	$trigger->($object, $value);
	270	}
	271	}
	272
	273	if($self->is_anon_class){
	274	$object->{__METACLASS__} = $self;
	275	}
	276
	277	return;
	278	}
	279
	280
43165725	281	package
	282	Mouse::Meta::Role;
	283
e058b279	284	sub method_metaclass{ $_[0]->{method_metaclass} \|\| 'Mouse::Meta::Role::Method' }
e058b279	285
43165725	286	sub is_anon_role{
	287	return exists $_[0]->{anon_serial_id};
	288	}
	289
	290	sub get_roles { $_[0]->{roles} }
	291
	292	package
	293	Mouse::Meta::Attribute;
	294
e058b279	295	require Mouse::Meta::Method::Accessor;
	296
	297	sub accessor_metaclass{ $_[0]->{accessor_metaclass} \|\| 'Mouse::Meta::Method::Accessor' }
43165725	298
	299	# readers
	300
	301	sub name { $_[0]->{name} }
	302	sub associated_class { $_[0]->{associated_class} }
	303
	304	sub accessor { $_[0]->{accessor} }
	305	sub reader { $_[0]->{reader} }
	306	sub writer { $_[0]->{writer} }
	307	sub predicate { $_[0]->{predicate} }
	308	sub clearer { $_[0]->{clearer} }
	309	sub handles { $_[0]->{handles} }
	310
	311	sub _is_metadata { $_[0]->{is} }
	312	sub is_required { $_[0]->{required} }
	313	sub default { $_[0]->{default} }
	314	sub is_lazy { $_[0]->{lazy} }
	315	sub is_lazy_build { $_[0]->{lazy_build} }
	316	sub is_weak_ref { $_[0]->{weak_ref} }
	317	sub init_arg { $_[0]->{init_arg} }
	318	sub type_constraint { $_[0]->{type_constraint} }
	319
	320	sub trigger { $_[0]->{trigger} }
	321	sub builder { $_[0]->{builder} }
	322	sub should_auto_deref { $_[0]->{auto_deref} }
	323	sub should_coerce { $_[0]->{coerce} }
	324
d899d3e7	325	sub documentation { $_[0]->{documentation} }
d899d3e7	326
43165725	327	# predicates
	328
	329	sub has_accessor { exists $_[0]->{accessor} }
	330	sub has_reader { exists $_[0]->{reader} }
	331	sub has_writer { exists $_[0]->{writer} }
	332	sub has_predicate { exists $_[0]->{predicate} }
	333	sub has_clearer { exists $_[0]->{clearer} }
	334	sub has_handles { exists $_[0]->{handles} }
	335
	336	sub has_default { exists $_[0]->{default} }
	337	sub has_type_constraint { exists $_[0]->{type_constraint} }
	338	sub has_trigger { exists $_[0]->{trigger} }
	339	sub has_builder { exists $_[0]->{builder} }
	340
d899d3e7	341	sub has_documentation { exists $_[0]->{documentation} }
d899d3e7	342
43165725	343	package
	344	Mouse::Meta::TypeConstraint;
	345
	346	sub name { $_[0]->{name} }
	347	sub parent { $_[0]->{parent} }
	348	sub message { $_[0]->{message} }
	349
	350	sub _compiled_type_constraint{ $_[0]->{compiled_type_constraint} }
	351
93540011	352	sub _compiled_type_coercion { $_[0]->{_compiled_type_coercion} }
df6dd016	353
93540011	354	sub has_coercion{ exists $_[0]->{_compiled_type_coercion} }
df6dd016	355
f790c46b	356
	357	sub compile_type_constraint{
	358	my($self) = @_;
	359
	360	# add parents first
	361	my @checks;
	362	for(my $parent = $self->{parent}; defined $parent; $parent = $parent->{parent}){
	363	if($parent->{hand_optimized_type_constraint}){
	364	unshift @checks, $parent->{hand_optimized_type_constraint};
	365	last; # a hand optimized constraint must include all the parents
	366	}
	367	elsif($parent->{constraint}){
	368	unshift @checks, $parent->{constraint};
	369	}
	370	}
	371
	372	# then add child
	373	if($self->{constraint}){
	374	push @checks, $self->{constraint};
	375	}
	376
	377	if($self->{type_constraints}){ # Union
	378	my @types = map{ $_->{compiled_type_constraint} } @{ $self->{type_constraints} };
	379	push @checks, sub{
	380	foreach my $c(@types){
	381	return 1 if $c->($_[0]);
	382	}
	383	return 0;
	384	};
	385	}
	386
	387	if(@checks == 0){
	388	$self->{compiled_type_constraint} = \&Mouse::Util::TypeConstraints::Any;
	389	}
	390	else{
	391	$self->{compiled_type_constraint} = sub{
	392	my(@args) = @_;
	393	local $_ = $args[0];
	394	foreach my $c(@checks){
	395	return undef if !$c->(@args);
	396	}
	397	return 1;
	398	};
	399	}
	400	return;
	401	}
	402
aa2d2e2c	403	package
	404	Mouse::Object;
	405
	406
	407	sub BUILDARGS {
	408	my $class = shift;
f790c46b	409
aa2d2e2c	410	if (scalar @_ == 1) {
	411	(ref($_[0]) eq 'HASH')
	412	\|\| $class->meta->throw_error("Single parameters to new() must be a HASH ref");
	413
	414	return {%{$_[0]}};
	415	}
	416	else {
	417	return {@_};
	418	}
	419	}
f790c46b	420
af04626d	421	sub new {
	422	my $class = shift;
	423
	424	$class->meta->throw_error('Cannot call new() on an instance') if ref $class;
	425
	426	my $args = $class->BUILDARGS(@_);
	427
	428	my $meta = Mouse::Meta::Class->initialize($class);
	429	my $self = $meta->new_object($args);
	430
	431	# BUILDALL
	432	if( $self->can('BUILD') ) {
	433	for my $class (reverse $meta->linearized_isa) {
	434	my $build = Mouse::Util::get_code_ref($class, 'BUILD')
	435	\|\| next;
	436
	437	$self->$build($args);
	438	}
	439	}
	440
	441	return $self;
	442	}
	443
a5c683f6	444	sub DESTROY {
	445	my $self = shift;
	446
	447	return unless $self->can('DEMOLISH'); # short circuit
	448
	449	local $?;
	450
	451	my $e = do{
	452	local $@;
	453	eval{
	454
	455	# DEMOLISHALL
	456
	457	# We cannot count on being able to retrieve a previously made
	458	# metaclass, _or_ being able to make a new one during global
	459	# destruction. However, we should still be able to use mro at
	460	# that time (at least tests suggest so ;)
	461
	462	foreach my $class (@{ Mouse::Util::get_linear_isa(ref $self) }) {
	463	my $demolish = Mouse::Util::get_code_ref($class, 'DEMOLISH')
	464	\|\| next;
	465
	466	$self->$demolish();
	467	}
	468	};
	469	$@;
	470	};
	471
	472	no warnings 'misc';
	473	die $e if $e; # rethrow
	474	}
	475
df6dd016	476	1;
df6dd016	477	__END__
ccb38d0b	478
	479	=head1 NAME
	480
	481	Mouse::PurePerl - A Mouse guts in pure Perl
	482
	483	=head1 VERSION
	484
1e582397	485	This document describes Mouse version 0.40_06
ccb38d0b	486
	487	=head1 SEE ALSO
	488
	489	L<Mouse::XS>
	490
	491	=cut