[gitmo/Mouse.git] / lib / Mouse / PurePerl.pm

package Mouse::PurePerl;

require Mouse::Util;

package
    Mouse::Util;

use strict;
use warnings;

use warnings FATAL => 'redefine'; # to avoid to load Mouse::PurePerl

use B ();

sub is_class_loaded {
    my $class = shift;

    return 0 if ref($class) || !defined($class) || !length($class);

    # walk the symbol table tree to avoid autovififying
    # \*{${main::}{"Foo::"}{"Bar::"}} == \*main::Foo::Bar::

    my $pack = \%::;
    foreach my $part (split('::', $class)) {
        $part .= '::';
        return 0 if !exists $pack->{$part};

        my $entry = \$pack->{$part};
        return 0 if ref($entry) ne 'GLOB';
        $pack = *{$entry}{HASH};
    }

    return 0 if !%{$pack};

    # check for $VERSION or @ISA
    return 1 if exists $pack->{VERSION}
             && defined *{$pack->{VERSION}}{SCALAR} && defined ${ $pack->{VERSION} };
    return 1 if exists $pack->{ISA}
             && defined *{$pack->{ISA}}{ARRAY} && @{ $pack->{ISA} } != 0;

    # check for any method
    foreach my $name( keys %{$pack} ) {
        my $entry = \$pack->{$name};
        return 1 if ref($entry) ne 'GLOB' || defined *{$entry}{CODE};
    }

    # fail
    return 0;
}


# taken from Sub::Identify
sub get_code_info {
    my ($coderef) = @_;
    ref($coderef) or return;

    my $cv = B::svref_2object($coderef);
    $cv->isa('B::CV') or return;

    my $gv = $cv->GV;
    $gv->isa('B::GV') or return;

    return ($gv->STASH->NAME, $gv->NAME);
}

sub get_code_package{
    my($coderef) = @_;

    my $cv = B::svref_2object($coderef);
    $cv->isa('B::CV') or return '';

    my $gv = $cv->GV;
    $gv->isa('B::GV') or return '';

    return $gv->STASH->NAME;
}

sub get_code_ref{
    my($package, $name) = @_;
    no strict 'refs';
    no warnings 'once';
    use warnings FATAL => 'uninitialized';
    return *{$package . '::' . $name}{CODE};
}

sub generate_isa_predicate_for {
    my($for_class, $name) = @_;

    my $predicate = sub{ Scalar::Util::blessed($_[0]) && $_[0]->isa($for_class) };

    if(defined $name){
        no strict 'refs';
        *{ caller() . '::' . $name } = $predicate;
        return;
    }

    return $predicate;
}

sub generate_can_predicate_for {
    my($methods_ref, $name) = @_;

    my @methods = @{$methods_ref};

    my $predicate = sub{
        my($instance) = @_;
        if(Scalar::Util::blessed($instance)){
            foreach my $method(@methods){
                if(!$instance->can($method)){
                    return 0;
                }
            }
            return 1;
        }
        return 0;
    };

    if(defined $name){
        no strict 'refs';
        *{ caller() . '::' . $name } = $predicate;
        return;
    }

    return $predicate;
}

package
    Mouse::Util::TypeConstraints;

use Scalar::Util qw(blessed looks_like_number openhandle);

sub Any        { 1 }
sub Item       { 1 }

sub Bool       { $_[0] ? $_[0] eq '1' : 1 }
sub Undef      { !defined($_[0]) }
sub Defined    {  defined($_[0])  }
sub Value      {  defined($_[0]) && !ref($_[0]) }
sub Num        { !ref($_[0]) && looks_like_number($_[0]) }
sub Int        {  defined($_[0]) && !ref($_[0]) && $_[0] =~ /^-?[0-9]+$/ }
sub Str        {
    my($value) = @_;
    return defined($value) && ref(\$value) eq 'SCALAR';
}

sub Ref        { ref($_[0]) }
sub ScalarRef  {
    my($value) = @_;
    return ref($value) eq 'SCALAR'
}
sub ArrayRef   { ref($_[0]) eq 'ARRAY'  }
sub HashRef    { ref($_[0]) eq 'HASH'   }
sub CodeRef    { ref($_[0]) eq 'CODE'   }
sub RegexpRef  { ref($_[0]) eq 'Regexp' }
sub GlobRef    { ref($_[0]) eq 'GLOB'   }

sub FileHandle {
    return openhandle($_[0])  || (blessed($_[0]) && $_[0]->isa("IO::Handle"))
}

sub Object     { blessed($_[0]) && blessed($_[0]) ne 'Regexp' }

sub ClassName  { Mouse::Util::is_class_loaded($_[0]) }
sub RoleName   { (Mouse::Util::class_of($_[0]) || return 0)->isa('Mouse::Meta::Role') }

sub _parameterize_ArrayRef_for {
    my($type_parameter) = @_;
    my $check = $type_parameter->_compiled_type_constraint;

    return sub {
        foreach my $value (@{$_}) {
            return undef unless $check->($value);
        }
        return 1;
    }
}

sub _parameterize_HashRef_for {
    my($type_parameter) = @_;
    my $check = $type_parameter->_compiled_type_constraint;

    return sub {
        foreach my $value(values %{$_}){
            return undef unless $check->($value);
        }
        return 1;
    };
}

# 'Maybe' type accepts 'Any', so it requires parameters
sub _parameterize_Maybe_for {
    my($type_parameter) = @_;
    my $check = $type_parameter->_compiled_type_constraint;

    return sub{
        return !defined($_) || $check->($_);
    };
};


package
    Mouse::Meta::Module;

sub name          { $_[0]->{package} }

sub _method_map   { $_[0]->{methods} }
sub _attribute_map{ $_[0]->{attributes} }

sub namespace{
    my $name = $_[0]->{package};
    no strict 'refs';
    return \%{ $name . '::' };
}

sub add_method {
    my($self, $name, $code) = @_;

    if(!defined $name){
        $self->throw_error('You must pass a defined name');
    }
    if(!defined $code){
        $self->throw_error('You must pass a defined code');
    }

    if(ref($code) ne 'CODE'){
        $code = \&{$code}; # coerce
    }

    $self->{methods}->{$name} = $code; # Moose stores meta object here.

    my $pkg = $self->name;
    no strict 'refs';
    no warnings 'redefine', 'once';
    *{ $pkg . '::' . $name } = $code;
    return;
}

package
    Mouse::Meta::Class;

sub method_metaclass    { $_[0]->{method_metaclass}    || 'Mouse::Meta::Method'    }
sub attribute_metaclass { $_[0]->{attribute_metaclass} || 'Mouse::Meta::Attribute' }

sub constructor_class { $_[0]->{constructor_class} || 'Mouse::Meta::Method::Constructor' }
sub destructor_class  { $_[0]->{destructor_class}  || 'Mouse::Meta::Method::Destructor'  }

sub is_anon_class{
    return exists $_[0]->{anon_serial_id};
}

sub roles { $_[0]->{roles} }

sub linearized_isa { @{ get_linear_isa($_[0]->{package}) } }

sub get_all_attributes {
    my($self) = @_;
    my %attrs = map { %{ $self->initialize($_)->{attributes} } } reverse $self->linearized_isa;
    return values %attrs;
}

sub new_object {
    my $self = shift;
    my %args = (@_ == 1 ? %{$_[0]} : @_);

    my $object = bless {}, $self->name;

    $self->_initialize_object($object, \%args);
    return $object;
}

sub _initialize_object{
    my($self, $object, $args, $ignore_triggers) = @_;

    my @triggers_queue;

    foreach my $attribute ($self->get_all_attributes) {
        my $init_arg = $attribute->init_arg;
        my $slot     = $attribute->name;

        if (defined($init_arg) && exists($args->{$init_arg})) {
            $object->{$slot} = $attribute->_coerce_and_verify($args->{$init_arg}, $object);

            weaken($object->{$slot})
                if ref($object->{$slot}) && $attribute->is_weak_ref;

            if ($attribute->has_trigger) {
                push @triggers_queue, [ $attribute->trigger, $object->{$slot} ];
            }
        }
        else { # no init arg
            if ($attribute->has_default || $attribute->has_builder) {
                if (!$attribute->is_lazy) {
                    my $default = $attribute->default;
                    my $builder = $attribute->builder;
                    my $value =   $builder                ? $object->$builder()
                                : ref($default) eq 'CODE' ? $object->$default()
                                :                           $default;

                    $object->{$slot} = $attribute->_coerce_and_verify($value, $object);

                    weaken($object->{$slot})
                        if ref($object->{$slot}) && $attribute->is_weak_ref;
                }
            }
            elsif($attribute->is_required) {
                $self->throw_error("Attribute (".$attribute->name.") is required");
            }
        }
    }

    if(!$ignore_triggers){
        foreach my $trigger_and_value(@triggers_queue){
            my($trigger, $value) = @{$trigger_and_value};
            $trigger->($object, $value);
        }
    }

    if($self->is_anon_class){
        $object->{__METACLASS__} = $self;
    }

    return;
}

sub is_immutable {  $_[0]->{is_immutable} }

package
    Mouse::Meta::Role;

sub method_metaclass{ $_[0]->{method_metaclass} || 'Mouse::Meta::Role::Method' }

sub is_anon_role{
    return exists $_[0]->{anon_serial_id};
}

sub get_roles { $_[0]->{roles} }

package
    Mouse::Meta::Attribute;

require Mouse::Meta::Method::Accessor;

sub accessor_metaclass{ $_[0]->{accessor_metaclass} || 'Mouse::Meta::Method::Accessor' }

# readers

sub name                 { $_[0]->{name}                   }
sub associated_class     { $_[0]->{associated_class}       }

sub accessor             { $_[0]->{accessor}               }
sub reader               { $_[0]->{reader}                 }
sub writer               { $_[0]->{writer}                 }
sub predicate            { $_[0]->{predicate}              }
sub clearer              { $_[0]->{clearer}                }
sub handles              { $_[0]->{handles}                }

sub _is_metadata         { $_[0]->{is}                     }
sub is_required          { $_[0]->{required}               }
sub default              { $_[0]->{default}                }
sub is_lazy              { $_[0]->{lazy}                   }
sub is_lazy_build        { $_[0]->{lazy_build}             }
sub is_weak_ref          { $_[0]->{weak_ref}               }
sub init_arg             { $_[0]->{init_arg}               }
sub type_constraint      { $_[0]->{type_constraint}        }

sub trigger              { $_[0]->{trigger}                }
sub builder              { $_[0]->{builder}                }
sub should_auto_deref    { $_[0]->{auto_deref}             }
sub should_coerce        { $_[0]->{coerce}                 }

sub documentation        { $_[0]->{documentation}          }

# predicates

sub has_accessor         { exists $_[0]->{accessor}        }
sub has_reader           { exists $_[0]->{reader}          }
sub has_writer           { exists $_[0]->{writer}          }
sub has_predicate        { exists $_[0]->{predicate}       }
sub has_clearer          { exists $_[0]->{clearer}         }
sub has_handles          { exists $_[0]->{handles}         }

sub has_default          { exists $_[0]->{default}         }
sub has_type_constraint  { exists $_[0]->{type_constraint} }
sub has_trigger          { exists $_[0]->{trigger}         }
sub has_builder          { exists $_[0]->{builder}         }

sub has_documentation    { exists $_[0]->{documentation}   }

sub _process_options{
    my($class, $name, $args) = @_;

    # taken from Class::MOP::Attribute::new

    defined($name)
        or $class->throw_error('You must provide a name for the attribute');

    if(!exists $args->{init_arg}){
        $args->{init_arg} = $name;
    }

    # 'required' requires eigher 'init_arg', 'builder', or 'default'
    my $can_be_required = defined( $args->{init_arg} );

    if(exists $args->{builder}){
        # XXX:
        # Moose refuses a CODE ref builder, but Mouse doesn't for backward compatibility
        # This feature will be changed in a future. (gfx)
        $class->throw_error('builder must be a defined scalar value which is a method name')
            #if ref $args->{builder} || !defined $args->{builder};
            if !defined $args->{builder};

        $can_be_required++;
    }
    elsif(exists $args->{default}){
        if(ref $args->{default} && ref($args->{default}) ne 'CODE'){
            $class->throw_error("References are not allowed as default values, you must "
                              . "wrap the default of '$name' in a CODE reference (ex: sub { [] } and not [])");
        }
        $can_be_required++;
    }

    if( $args->{required} && !$can_be_required ) {
        $class->throw_error("You cannot have a required attribute ($name) without a default, builder, or an init_arg");
    }

    # taken from Mouse::Meta::Attribute->new and ->_process_args

    if(exists $args->{is}){
        my $is = $args->{is};

        if($is eq 'ro'){
            $args->{reader} ||= $name;
        }
        elsif($is eq 'rw'){
            if(exists $args->{writer}){
                $args->{reader} ||= $name;
             }
             else{
                $args->{accessor} ||= $name;
             }
        }
        elsif($is eq 'bare'){
            # do nothing, but don't complain (later) about missing methods
        }
        else{
            $is = 'undef' if !defined $is;
            $class->throw_error("I do not understand this option (is => $is) on attribute ($name)");
        }
    }

    my $tc;
    if(exists $args->{isa}){
        $args->{type_constraint} = Mouse::Util::TypeConstraints::find_or_create_isa_type_constraint($args->{isa});
    }
    elsif(exists $args->{does}){
        $args->{type_constraint} = Mouse::Util::TypeConstraints::find_or_create_does_type_constraint($args->{does});
    }
    $tc = $args->{type_constraint};

    if($args->{coerce}){
        defined($tc)
            || $class->throw_error("You cannot have coercion without specifying a type constraint on attribute ($name)");

        $args->{weak_ref}
            && $class->throw_error("You cannot have a weak reference to a coerced value on attribute ($name)");
    }

    if ($args->{lazy_build}) {
        exists($args->{default})
            && $class->throw_error("You can not use lazy_build and default for the same attribute ($name)");

        $args->{lazy}      = 1;
        $args->{builder} ||= "_build_${name}";
        if ($name =~ /^_/) {
            $args->{clearer}   ||= "_clear${name}";
            $args->{predicate} ||= "_has${name}";
        }
        else {
            $args->{clearer}   ||= "clear_${name}";
            $args->{predicate} ||= "has_${name}";
        }
    }

    if ($args->{auto_deref}) {
        defined($tc)
            || $class->throw_error("You cannot auto-dereference without specifying a type constraint on attribute ($name)");

        ( $tc->is_a_type_of('ArrayRef') || $tc->is_a_type_of('HashRef') )
            || $class->throw_error("You cannot auto-dereference anything other than a ArrayRef or HashRef on attribute ($name)");
    }

    if (exists $args->{trigger}) {
        ('CODE' eq ref $args->{trigger})
            || $class->throw_error("Trigger must be a CODE ref on attribute ($name)");
    }

    if ($args->{lazy}) {
        (exists $args->{default} || defined $args->{builder})
            || $class->throw_error("You cannot have lazy attribute ($name) without specifying a default value for it");
    }

    return;
}


package
    Mouse::Meta::TypeConstraint;

sub name    { $_[0]->{name}    }
sub parent  { $_[0]->{parent}  }
sub message { $_[0]->{message} }

sub _compiled_type_constraint{ $_[0]->{compiled_type_constraint} }

sub _compiled_type_coercion  { $_[0]->{_compiled_type_coercion}  }

sub has_coercion{ exists $_[0]->{_compiled_type_coercion} }


sub compile_type_constraint{
    my($self) = @_;

    # add parents first
    my @checks;
    for(my $parent = $self->{parent}; defined $parent; $parent = $parent->{parent}){
         if($parent->{hand_optimized_type_constraint}){
            unshift @checks, $parent->{hand_optimized_type_constraint};
            last; # a hand optimized constraint must include all the parents
        }
        elsif($parent->{constraint}){
            unshift @checks, $parent->{constraint};
        }
    }

    # then add child
    if($self->{constraint}){
        push @checks, $self->{constraint};
    }

    if($self->{type_constraints}){ # Union
        my @types = map{ $_->{compiled_type_constraint} } @{ $self->{type_constraints} };
        push @checks, sub{
            foreach my $c(@types){
                return 1 if $c->($_[0]);
            }
            return 0;
        };
    }

    if(@checks == 0){
        $self->{compiled_type_constraint} = \&Mouse::Util::TypeConstraints::Any;
    }
    else{
        $self->{compiled_type_constraint} =  sub{
            my(@args) = @_;
            local $_ = $args[0];
            foreach my $c(@checks){
                return undef if !$c->(@args);
            }
            return 1;
        };
    }
    return;
}

package
    Mouse::Object;


sub BUILDARGS {
    my $class = shift;

    if (scalar @_ == 1) {
        (ref($_[0]) eq 'HASH')
            || $class->meta->throw_error("Single parameters to new() must be a HASH ref");

        return {%{$_[0]}};
    }
    else {
        return {@_};
    }
}

sub new {
    my $class = shift;

    $class->meta->throw_error('Cannot call new() on an instance') if ref $class;

    my $args = $class->BUILDARGS(@_);

    my $meta = Mouse::Meta::Class->initialize($class);
    my $self = $meta->new_object($args);

    # BUILDALL
    if( $self->can('BUILD') ) {
        for my $class (reverse $meta->linearized_isa) {
            my $build = Mouse::Util::get_code_ref($class, 'BUILD')
                || next;

            $self->$build($args);
        }
    }

    return $self;
}

sub DESTROY {
    my $self = shift;

    return unless $self->can('DEMOLISH'); # short circuit

    local $?;

    my $e = do{
        local $@;
        eval{

            # DEMOLISHALL

            # We cannot count on being able to retrieve a previously made
            # metaclass, _or_ being able to make a new one during global
            # destruction. However, we should still be able to use mro at
            # that time (at least tests suggest so ;)

            foreach my $class (@{ Mouse::Util::get_linear_isa(ref $self) }) {
                my $demolish = Mouse::Util::get_code_ref($class, 'DEMOLISH')
                    || next;

                $self->$demolish($Mouse::Util::in_global_destruction);
            }
        };
        $@;
    };

    no warnings 'misc';
    die $e if $e; # rethrow
}

sub BUILDALL {
    my $self = shift;

    # short circuit
    return unless $self->can('BUILD');

    for my $class (reverse $self->meta->linearized_isa) {
        my $build = Mouse::Util::get_code_ref($class, 'BUILD')
            || next;

        $self->$build(@_);
    }
    return;
}

sub DEMOLISHALL;
*DEMOLISHALL = \&DESTROY;

1;
__END__

=head1 NAME

Mouse::PurePerl - A Mouse guts in pure Perl

=head1 VERSION

This document describes Mouse version 0.50_01

=head1 SEE ALSO

L<Mouse::XS>

=cut
Commit	Line	Data
ccb38d0b	1	package Mouse::PurePerl;
ccb38d0b	2
a52cca04	3	require Mouse::Util;
a52cca04	4
df6dd016	5	package
	6	Mouse::Util;
	7
	8	use strict;
	9	use warnings;
	10
	11	use warnings FATAL => 'redefine'; # to avoid to load Mouse::PurePerl
	12
	13	use B ();
	14
	15	sub is_class_loaded {
	16	my $class = shift;
	17
	18	return 0 if ref($class) \|\| !defined($class) \|\| !length($class);
	19
	20	# walk the symbol table tree to avoid autovififying
3bb9e54e	21	# \{${main::}{"Foo::"}{"Bar::"}} == \main::Foo::Bar::
df6dd016	22
	23	my $pack = \%::;
	24	foreach my $part (split('::', $class)) {
3bb9e54e	25	$part .= '::';
	26	return 0 if !exists $pack->{$part};
	27
	28	my $entry = \$pack->{$part};
df6dd016	29	return 0 if ref($entry) ne 'GLOB';
3bb9e54e	30	$pack = *{$entry}{HASH};
df6dd016	31	}
df6dd016	32
3bb9e54e	33	return 0 if !%{$pack};
3bb9e54e	34
df6dd016	35	# check for $VERSION or @ISA
	36	return 1 if exists $pack->{VERSION}
	37	&& defined *{$pack->{VERSION}}{SCALAR} && defined ${ $pack->{VERSION} };
	38	return 1 if exists $pack->{ISA}
	39	&& defined *{$pack->{ISA}}{ARRAY} && @{ $pack->{ISA} } != 0;
	40
	41	# check for any method
	42	foreach my $name( keys %{$pack} ) {
	43	my $entry = \$pack->{$name};
	44	return 1 if ref($entry) ne 'GLOB' \|\| defined *{$entry}{CODE};
	45	}
	46
	47	# fail
	48	return 0;
	49	}
	50
	51
	52	# taken from Sub::Identify
	53	sub get_code_info {
	54	my ($coderef) = @_;
	55	ref($coderef) or return;
	56
	57	my $cv = B::svref_2object($coderef);
	58	$cv->isa('B::CV') or return;
	59
	60	my $gv = $cv->GV;
	61	$gv->isa('B::GV') or return;
	62
	63	return ($gv->STASH->NAME, $gv->NAME);
	64	}
	65
	66	sub get_code_package{
	67	my($coderef) = @_;
	68
	69	my $cv = B::svref_2object($coderef);
	70	$cv->isa('B::CV') or return '';
	71
	72	my $gv = $cv->GV;
	73	$gv->isa('B::GV') or return '';
	74
	75	return $gv->STASH->NAME;
	76	}
	77
7d96ae4d	78	sub get_code_ref{
	79	my($package, $name) = @_;
	80	no strict 'refs';
	81	no warnings 'once';
	82	use warnings FATAL => 'uninitialized';
	83	return *{$package . '::' . $name}{CODE};
	84	}
	85
e3540312	86	sub generate_isa_predicate_for {
1d5ecd5f	87	my($for_class, $name) = @_;
1d5ecd5f	88
f48920c1	89	my $predicate = sub{ Scalar::Util::blessed($_[0]) && $_[0]->isa($for_class) };
1d5ecd5f	90
	91	if(defined $name){
	92	no strict 'refs';
	93	*{ caller() . '::' . $name } = $predicate;
	94	return;
	95	}
	96
	97	return $predicate;
	98	}
	99
ebe91068	100	sub generate_can_predicate_for {
	101	my($methods_ref, $name) = @_;
	102
	103	my @methods = @{$methods_ref};
	104
	105	my $predicate = sub{
	106	my($instance) = @_;
	107	if(Scalar::Util::blessed($instance)){
	108	foreach my $method(@methods){
	109	if(!$instance->can($method)){
	110	return 0;
	111	}
	112	}
	113	return 1;
	114	}
	115	return 0;
	116	};
	117
	118	if(defined $name){
	119	no strict 'refs';
	120	*{ caller() . '::' . $name } = $predicate;
	121	return;
	122	}
	123
	124	return $predicate;
	125	}
1d5ecd5f	126
f48920c1	127	package
	128	Mouse::Util::TypeConstraints;
	129
	130	use Scalar::Util qw(blessed looks_like_number openhandle);
	131
7d96ae4d	132	sub Any { 1 }
7d96ae4d	133	sub Item { 1 }
7d96ae4d	134
	135	sub Bool { $_[0] ? $_[0] eq '1' : 1 }
	136	sub Undef { !defined($_[0]) }
	137	sub Defined { defined($_[0]) }
	138	sub Value { defined($_[0]) && !ref($_[0]) }
	139	sub Num { !ref($_[0]) && looks_like_number($_[0]) }
	140	sub Int { defined($_[0]) && !ref($_[0]) && $_[0] =~ /^-?[0-9]+$/ }
9848d3e1	141	sub Str {
	142	my($value) = @_;
	143	return defined($value) && ref(\$value) eq 'SCALAR';
	144	}
7d96ae4d	145
7d96ae4d	146	sub Ref { ref($_[0]) }
9848d3e1	147	sub ScalarRef {
	148	my($value) = @_;
	149	return ref($value) eq 'SCALAR'
	150	}
7d96ae4d	151	sub ArrayRef { ref($_[0]) eq 'ARRAY' }
	152	sub HashRef { ref($_[0]) eq 'HASH' }
	153	sub CodeRef { ref($_[0]) eq 'CODE' }
	154	sub RegexpRef { ref($_[0]) eq 'Regexp' }
	155	sub GlobRef { ref($_[0]) eq 'GLOB' }
	156
	157	sub FileHandle {
9848d3e1	158	return openhandle($_[0]) \|\| (blessed($_[0]) && $_[0]->isa("IO::Handle"))
7d96ae4d	159	}
	160
	161	sub Object { blessed($_[0]) && blessed($_[0]) ne 'Regexp' }
	162
	163	sub ClassName { Mouse::Util::is_class_loaded($_[0]) }
	164	sub RoleName { (Mouse::Util::class_of($_[0]) \|\| return 0)->isa('Mouse::Meta::Role') }
	165
619338ac	166	sub _parameterize_ArrayRef_for {
	167	my($type_parameter) = @_;
	168	my $check = $type_parameter->_compiled_type_constraint;
	169
	170	return sub {
	171	foreach my $value (@{$_}) {
	172	return undef unless $check->($value);
	173	}
	174	return 1;
	175	}
	176	}
	177
	178	sub _parameterize_HashRef_for {
	179	my($type_parameter) = @_;
	180	my $check = $type_parameter->_compiled_type_constraint;
	181
	182	return sub {
	183	foreach my $value(values %{$_}){
	184	return undef unless $check->($value);
	185	}
	186	return 1;
	187	};
	188	}
	189
	190	# 'Maybe' type accepts 'Any', so it requires parameters
	191	sub _parameterize_Maybe_for {
	192	my($type_parameter) = @_;
	193	my $check = $type_parameter->_compiled_type_constraint;
	194
	195	return sub{
	196	return !defined($_) \|\| $check->($_);
	197	};
	198	};
	199
	200
7d96ae4d	201
43165725	202	package
	203	Mouse::Meta::Module;
	204
926404f2	205	sub name { $_[0]->{package} }
	206
	207	sub _method_map { $_[0]->{methods} }
c5f6ad05	208	sub _attribute_map{ $_[0]->{attributes} }
43165725	209
2591e962	210	sub namespace{
	211	my $name = $_[0]->{package};
	212	no strict 'refs';
	213	return \%{ $name . '::' };
	214	}
	215
3e44140b	216	sub add_method {
	217	my($self, $name, $code) = @_;
	218
	219	if(!defined $name){
	220	$self->throw_error('You must pass a defined name');
	221	}
	222	if(!defined $code){
	223	$self->throw_error('You must pass a defined code');
	224	}
	225
	226	if(ref($code) ne 'CODE'){
	227	$code = \&{$code}; # coerce
	228	}
	229
	230	$self->{methods}->{$name} = $code; # Moose stores meta object here.
	231
	232	my $pkg = $self->name;
	233	no strict 'refs';
	234	no warnings 'redefine', 'once';
	235	*{ $pkg . '::' . $name } = $code;
	236	return;
	237	}
	238
43165725	239	package
	240	Mouse::Meta::Class;
	241
e058b279	242	sub method_metaclass { $_[0]->{method_metaclass} \|\| 'Mouse::Meta::Method' }
	243	sub attribute_metaclass { $_[0]->{attribute_metaclass} \|\| 'Mouse::Meta::Attribute' }
	244
	245	sub constructor_class { $_[0]->{constructor_class} \|\| 'Mouse::Meta::Method::Constructor' }
	246	sub destructor_class { $_[0]->{destructor_class} \|\| 'Mouse::Meta::Method::Destructor' }
4e7e3250	247
43165725	248	sub is_anon_class{
	249	return exists $_[0]->{anon_serial_id};
	250	}
	251
	252	sub roles { $_[0]->{roles} }
	253
cccb83de	254	sub linearized_isa { @{ get_linear_isa($_[0]->{package}) } }
cccb83de	255
da4432f3	256	sub get_all_attributes {
da4432f3	257	my($self) = @_;
047d7af0	258	my %attrs = map { %{ $self->initialize($_)->{attributes} } } reverse $self->linearized_isa;
da4432f3	259	return values %attrs;
	260	}
	261
ba153b33	262	sub new_object {
	263	my $self = shift;
	264	my %args = (@_ == 1 ? %{$_[0]} : @_);
	265
	266	my $object = bless {}, $self->name;
	267
	268	$self->_initialize_object($object, \%args);
	269	return $object;
	270	}
	271
4e7e3250	272	sub _initialize_object{
	273	my($self, $object, $args, $ignore_triggers) = @_;
	274
	275	my @triggers_queue;
	276
	277	foreach my $attribute ($self->get_all_attributes) {
	278	my $init_arg = $attribute->init_arg;
	279	my $slot = $attribute->name;
	280
	281	if (defined($init_arg) && exists($args->{$init_arg})) {
	282	$object->{$slot} = $attribute->_coerce_and_verify($args->{$init_arg}, $object);
	283
	284	weaken($object->{$slot})
	285	if ref($object->{$slot}) && $attribute->is_weak_ref;
	286
	287	if ($attribute->has_trigger) {
	288	push @triggers_queue, [ $attribute->trigger, $object->{$slot} ];
	289	}
	290	}
	291	else { # no init arg
	292	if ($attribute->has_default \|\| $attribute->has_builder) {
	293	if (!$attribute->is_lazy) {
	294	my $default = $attribute->default;
	295	my $builder = $attribute->builder;
	296	my $value = $builder ? $object->$builder()
	297	: ref($default) eq 'CODE' ? $object->$default()
	298	: $default;
	299
	300	$object->{$slot} = $attribute->_coerce_and_verify($value, $object);
	301
	302	weaken($object->{$slot})
	303	if ref($object->{$slot}) && $attribute->is_weak_ref;
	304	}
	305	}
	306	elsif($attribute->is_required) {
	307	$self->throw_error("Attribute (".$attribute->name.") is required");
	308	}
	309	}
	310	}
	311
	312	if(!$ignore_triggers){
	313	foreach my $trigger_and_value(@triggers_queue){
	314	my($trigger, $value) = @{$trigger_and_value};
	315	$trigger->($object, $value);
	316	}
	317	}
	318
	319	if($self->is_anon_class){
	320	$object->{__METACLASS__} = $self;
	321	}
	322
	323	return;
	324	}
	325
80efe911	326	sub is_immutable { $_[0]->{is_immutable} }
4e7e3250	327
43165725	328	package
	329	Mouse::Meta::Role;
	330
e058b279	331	sub method_metaclass{ $_[0]->{method_metaclass} \|\| 'Mouse::Meta::Role::Method' }
e058b279	332
43165725	333	sub is_anon_role{
	334	return exists $_[0]->{anon_serial_id};
	335	}
	336
	337	sub get_roles { $_[0]->{roles} }
	338
	339	package
	340	Mouse::Meta::Attribute;
	341
e058b279	342	require Mouse::Meta::Method::Accessor;
	343
	344	sub accessor_metaclass{ $_[0]->{accessor_metaclass} \|\| 'Mouse::Meta::Method::Accessor' }
43165725	345
	346	# readers
	347
	348	sub name { $_[0]->{name} }
	349	sub associated_class { $_[0]->{associated_class} }
	350
	351	sub accessor { $_[0]->{accessor} }
	352	sub reader { $_[0]->{reader} }
	353	sub writer { $_[0]->{writer} }
	354	sub predicate { $_[0]->{predicate} }
	355	sub clearer { $_[0]->{clearer} }
	356	sub handles { $_[0]->{handles} }
	357
	358	sub _is_metadata { $_[0]->{is} }
	359	sub is_required { $_[0]->{required} }
	360	sub default { $_[0]->{default} }
	361	sub is_lazy { $_[0]->{lazy} }
	362	sub is_lazy_build { $_[0]->{lazy_build} }
	363	sub is_weak_ref { $_[0]->{weak_ref} }
	364	sub init_arg { $_[0]->{init_arg} }
	365	sub type_constraint { $_[0]->{type_constraint} }
	366
	367	sub trigger { $_[0]->{trigger} }
	368	sub builder { $_[0]->{builder} }
	369	sub should_auto_deref { $_[0]->{auto_deref} }
	370	sub should_coerce { $_[0]->{coerce} }
	371
d899d3e7	372	sub documentation { $_[0]->{documentation} }
d899d3e7	373
43165725	374	# predicates
	375
	376	sub has_accessor { exists $_[0]->{accessor} }
	377	sub has_reader { exists $_[0]->{reader} }
	378	sub has_writer { exists $_[0]->{writer} }
	379	sub has_predicate { exists $_[0]->{predicate} }
	380	sub has_clearer { exists $_[0]->{clearer} }
	381	sub has_handles { exists $_[0]->{handles} }
	382
	383	sub has_default { exists $_[0]->{default} }
	384	sub has_type_constraint { exists $_[0]->{type_constraint} }
	385	sub has_trigger { exists $_[0]->{trigger} }
	386	sub has_builder { exists $_[0]->{builder} }
	387
d899d3e7	388	sub has_documentation { exists $_[0]->{documentation} }
d899d3e7	389
ba1f50a2	390	sub _process_options{
	391	my($class, $name, $args) = @_;
	392
	393	# taken from Class::MOP::Attribute::new
	394
	395	defined($name)
	396	or $class->throw_error('You must provide a name for the attribute');
	397
	398	if(!exists $args->{init_arg}){
	399	$args->{init_arg} = $name;
	400	}
	401
	402	# 'required' requires eigher 'init_arg', 'builder', or 'default'
	403	my $can_be_required = defined( $args->{init_arg} );
	404
	405	if(exists $args->{builder}){
	406	# XXX:
	407	# Moose refuses a CODE ref builder, but Mouse doesn't for backward compatibility
	408	# This feature will be changed in a future. (gfx)
	409	$class->throw_error('builder must be a defined scalar value which is a method name')
	410	#if ref $args->{builder} \|\| !defined $args->{builder};
	411	if !defined $args->{builder};
	412
	413	$can_be_required++;
	414	}
	415	elsif(exists $args->{default}){
	416	if(ref $args->{default} && ref($args->{default}) ne 'CODE'){
	417	$class->throw_error("References are not allowed as default values, you must "
	418	. "wrap the default of '$name' in a CODE reference (ex: sub { [] } and not [])");
	419	}
	420	$can_be_required++;
	421	}
	422
	423	if( $args->{required} && !$can_be_required ) {
	424	$class->throw_error("You cannot have a required attribute ($name) without a default, builder, or an init_arg");
	425	}
	426
	427	# taken from Mouse::Meta::Attribute->new and ->_process_args
	428
	429	if(exists $args->{is}){
	430	my $is = $args->{is};
	431
	432	if($is eq 'ro'){
	433	$args->{reader} \|\|= $name;
	434	}
	435	elsif($is eq 'rw'){
	436	if(exists $args->{writer}){
	437	$args->{reader} \|\|= $name;
	438	}
	439	else{
	440	$args->{accessor} \|\|= $name;
	441	}
	442	}
	443	elsif($is eq 'bare'){
	444	# do nothing, but don't complain (later) about missing methods
	445	}
	446	else{
	447	$is = 'undef' if !defined $is;
	448	$class->throw_error("I do not understand this option (is => $is) on attribute ($name)");
	449	}
	450	}
	451
	452	my $tc;
	453	if(exists $args->{isa}){
454	$args->{type_constraint} = Mouse::Util::TypeConstraints::find_or_create_isa_type_constraint($args->{isa});
455	}
456	elsif(exists $args->{does}){
457	$args->{type_constraint} = Mouse::Util::TypeConstraints::find_or_create_does_type_constraint($args->{does});
458	}
459	$tc = $args->{type_constraint};
460
461	if($args->{coerce}){
462	defined($tc)
463	\|\| $class->throw_error("You cannot have coercion without specifying a type constraint on attribute ($name)");
464
465	$args->{weak_ref}
466	&& $class->throw_error("You cannot have a weak reference to a coerced value on attribute ($name)");
467	}
468
469	if ($args->{lazy_build}) {
470	exists($args->{default})
471	&& $class->throw_error("You can not use lazy_build and default for the same attribute ($name)");
472
473	$args->{lazy} = 1;
474	$args->{builder} \|\|= "_build_${name}";
475	if ($name =~ /^_/) {
476	$args->{clearer} \|\|= "_clear${name}";
477	$args->{predicate} \|\|= "_has${name}";
478	}
479	else {
480	$args->{clearer} \|\|= "clear_${name}";
481	$args->{predicate} \|\|= "has_${name}";
482	}
483	}
484
485	if ($args->{auto_deref}) {
486	defined($tc)
487	\|\| $class->throw_error("You cannot auto-dereference without specifying a type constraint on attribute ($name)");
488
489	( $tc->is_a_type_of('ArrayRef') \|\| $tc->is_a_type_of('HashRef') )
490	\|\| $class->throw_error("You cannot auto-dereference anything other than a ArrayRef or HashRef on attribute ($name)");
491	}
492
493	if (exists $args->{trigger}) {
494	('CODE' eq ref $args->{trigger})
495	\|\| $class->throw_error("Trigger must be a CODE ref on attribute ($name)");
496	}
497
498	if ($args->{lazy}) {
499	(exists $args->{default} \|\| defined $args->{builder})
500	\|\| $class->throw_error("You cannot have lazy attribute ($name) without specifying a default value for it");
501	}
502
503	return;
504	}
505
506
43165725	507	package
	508	Mouse::Meta::TypeConstraint;
	509
	510	sub name { $_[0]->{name} }
	511	sub parent { $_[0]->{parent} }
	512	sub message { $_[0]->{message} }
	513
	514	sub _compiled_type_constraint{ $_[0]->{compiled_type_constraint} }
	515
93540011	516	sub _compiled_type_coercion { $_[0]->{_compiled_type_coercion} }
df6dd016	517
93540011	518	sub has_coercion{ exists $_[0]->{_compiled_type_coercion} }
df6dd016	519
f790c46b	520
	521	sub compile_type_constraint{
	522	my($self) = @_;
	523
	524	# add parents first
	525	my @checks;
	526	for(my $parent = $self->{parent}; defined $parent; $parent = $parent->{parent}){
	527	if($parent->{hand_optimized_type_constraint}){
	528	unshift @checks, $parent->{hand_optimized_type_constraint};
	529	last; # a hand optimized constraint must include all the parents
	530	}
	531	elsif($parent->{constraint}){
	532	unshift @checks, $parent->{constraint};
	533	}
	534	}
	535
	536	# then add child
	537	if($self->{constraint}){
	538	push @checks, $self->{constraint};
	539	}
	540
	541	if($self->{type_constraints}){ # Union
	542	my @types = map{ $_->{compiled_type_constraint} } @{ $self->{type_constraints} };
	543	push @checks, sub{
	544	foreach my $c(@types){
	545	return 1 if $c->($_[0]);
	546	}
	547	return 0;
	548	};
	549	}
	550
	551	if(@checks == 0){
	552	$self->{compiled_type_constraint} = \&Mouse::Util::TypeConstraints::Any;
	553	}
	554	else{
	555	$self->{compiled_type_constraint} = sub{
	556	my(@args) = @_;
	557	local $_ = $args[0];
	558	foreach my $c(@checks){
	559	return undef if !$c->(@args);
	560	}
	561	return 1;
	562	};
	563	}
	564	return;
	565	}
	566
aa2d2e2c	567	package
	568	Mouse::Object;
	569
	570
	571	sub BUILDARGS {
	572	my $class = shift;
f790c46b	573
aa2d2e2c	574	if (scalar @_ == 1) {
	575	(ref($_[0]) eq 'HASH')
	576	\|\| $class->meta->throw_error("Single parameters to new() must be a HASH ref");
	577
	578	return {%{$_[0]}};
	579	}
	580	else {
	581	return {@_};
	582	}
	583	}
f790c46b	584
af04626d	585	sub new {
	586	my $class = shift;
	587
	588	$class->meta->throw_error('Cannot call new() on an instance') if ref $class;
	589
	590	my $args = $class->BUILDARGS(@_);
	591
	592	my $meta = Mouse::Meta::Class->initialize($class);
	593	my $self = $meta->new_object($args);
	594
	595	# BUILDALL
	596	if( $self->can('BUILD') ) {
	597	for my $class (reverse $meta->linearized_isa) {
	598	my $build = Mouse::Util::get_code_ref($class, 'BUILD')
	599	\|\| next;
	600
	601	$self->$build($args);
	602	}
	603	}
	604
	605	return $self;
	606	}
	607
a5c683f6	608	sub DESTROY {
	609	my $self = shift;
	610
	611	return unless $self->can('DEMOLISH'); # short circuit
	612
	613	local $?;
	614
	615	my $e = do{
	616	local $@;
	617	eval{
	618
	619	# DEMOLISHALL
	620
	621	# We cannot count on being able to retrieve a previously made
	622	# metaclass, _or_ being able to make a new one during global
	623	# destruction. However, we should still be able to use mro at
	624	# that time (at least tests suggest so ;)
	625
	626	foreach my $class (@{ Mouse::Util::get_linear_isa(ref $self) }) {
	627	my $demolish = Mouse::Util::get_code_ref($class, 'DEMOLISH')
	628	\|\| next;
	629
6514735e	630	$self->$demolish($Mouse::Util::in_global_destruction);
a5c683f6	631	}
	632	};
	633	$@;
	634	};
	635
	636	no warnings 'misc';
	637	die $e if $e; # rethrow
	638	}
	639
adb5eb76	640	sub BUILDALL {
	641	my $self = shift;
	642
	643	# short circuit
	644	return unless $self->can('BUILD');
	645
	646	for my $class (reverse $self->meta->linearized_isa) {
	647	my $build = Mouse::Util::get_code_ref($class, 'BUILD')
	648	\|\| next;
	649
	650	$self->$build(@_);
	651	}
	652	return;
	653	}
	654
	655	sub DEMOLISHALL;
	656	*DEMOLISHALL = \&DESTROY;
	657
df6dd016	658	1;
df6dd016	659	__END__
ccb38d0b	660
	661	=head1 NAME
	662
	663	Mouse::PurePerl - A Mouse guts in pure Perl
	664
	665	=head1 VERSION
	666
05a12aa4	667	This document describes Mouse version 0.50_01
ccb38d0b	668
	669	=head1 SEE ALSO
	670
	671	L<Mouse::XS>
	672
	673	=cut