[gitmo/Mouse.git] / lib / Mouse / PurePerl.pm

package Mouse::PurePerl;

require Mouse::Util;

package Mouse::Util;

use strict;
use warnings;

use warnings FATAL => 'redefine'; # to avoid to load Mouse::PurePerl

use B ();


# taken from Class/MOP.pm
sub is_valid_class_name {
    my $class = shift;

    return 0 if ref($class);
    return 0 unless defined($class);

    return 1 if $class =~ /\A \w+ (?: :: \w+ )* \z/xms;

    return 0;
}

sub is_class_loaded {
    my $class = shift;

    return 0 if ref($class) || !defined($class) || !length($class);

    # walk the symbol table tree to avoid autovififying
    # \*{${main::}{"Foo::"}{"Bar::"}} == \*main::Foo::Bar::

    my $pack = \%::;
    foreach my $part (split('::', $class)) {
        $part .= '::';
        return 0 if !exists $pack->{$part};

        my $entry = \$pack->{$part};
        return 0 if ref($entry) ne 'GLOB';
        $pack = *{$entry}{HASH};
    }

    return 0 if !%{$pack};

    # check for $VERSION or @ISA
    return 1 if exists $pack->{VERSION}
             && defined *{$pack->{VERSION}}{SCALAR} && defined ${ $pack->{VERSION} };
    return 1 if exists $pack->{ISA}
             && defined *{$pack->{ISA}}{ARRAY} && @{ $pack->{ISA} } != 0;

    # check for any method
    foreach my $name( keys %{$pack} ) {
        my $entry = \$pack->{$name};
        return 1 if ref($entry) ne 'GLOB' || defined *{$entry}{CODE};
    }

    # fail
    return 0;
}


# taken from Sub::Identify
sub get_code_info {
    my ($coderef) = @_;
    ref($coderef) or return;

    my $cv = B::svref_2object($coderef);
    $cv->isa('B::CV') or return;

    my $gv = $cv->GV;
    $gv->isa('B::GV') or return;

    return ($gv->STASH->NAME, $gv->NAME);
}

sub get_code_package{
    my($coderef) = @_;

    my $cv = B::svref_2object($coderef);
    $cv->isa('B::CV') or return '';

    my $gv = $cv->GV;
    $gv->isa('B::GV') or return '';

    return $gv->STASH->NAME;
}

sub get_code_ref{
    my($package, $name) = @_;
    no strict 'refs';
    no warnings 'once';
    use warnings FATAL => 'uninitialized';
    return *{$package . '::' . $name}{CODE};
}

sub generate_isa_predicate_for {
    my($for_class, $name) = @_;

    my $predicate = sub{ Scalar::Util::blessed($_[0]) && $_[0]->isa($for_class) };

    if(defined $name){
        no strict 'refs';
        *{ caller() . '::' . $name } = $predicate;
        return;
    }

    return $predicate;
}

sub generate_can_predicate_for {
    my($methods_ref, $name) = @_;

    my @methods = @{$methods_ref};

    my $predicate = sub{
        my($instance) = @_;
        if(Scalar::Util::blessed($instance)){
            foreach my $method(@methods){
                if(!$instance->can($method)){
                    return 0;
                }
            }
            return 1;
        }
        return 0;
    };

    if(defined $name){
        no strict 'refs';
        *{ caller() . '::' . $name } = $predicate;
        return;
    }

    return $predicate;
}

package Mouse::Util::TypeConstraints;

use Scalar::Util qw(blessed looks_like_number openhandle);

sub Any        { 1 }
sub Item       { 1 }

sub Bool       { $_[0] ? $_[0] eq '1' : 1 }
sub Undef      { !defined($_[0]) }
sub Defined    {  defined($_[0])  }
sub Value      {  defined($_[0]) && !ref($_[0]) }
sub Num        { !ref($_[0]) && looks_like_number($_[0]) }
sub Int        {  defined($_[0]) && !ref($_[0]) && $_[0] =~ /^-?[0-9]+$/ }
sub Str        {
    my($value) = @_;
    return defined($value) && ref(\$value) eq 'SCALAR';
}

sub Ref        { ref($_[0]) }
sub ScalarRef  {
    my($value) = @_;
    return ref($value) eq 'SCALAR'
}
sub ArrayRef   { ref($_[0]) eq 'ARRAY'  }
sub HashRef    { ref($_[0]) eq 'HASH'   }
sub CodeRef    { ref($_[0]) eq 'CODE'   }
sub RegexpRef  { ref($_[0]) eq 'Regexp' }
sub GlobRef    { ref($_[0]) eq 'GLOB'   }

sub FileHandle {
    return openhandle($_[0])  || (blessed($_[0]) && $_[0]->isa("IO::Handle"))
}

sub Object     { blessed($_[0]) && blessed($_[0]) ne 'Regexp' }

sub ClassName  { Mouse::Util::is_class_loaded($_[0]) }
sub RoleName   { (Mouse::Util::class_of($_[0]) || return 0)->isa('Mouse::Meta::Role') }

sub _parameterize_ArrayRef_for {
    my($type_parameter) = @_;
    my $check = $type_parameter->_compiled_type_constraint;

    return sub {
        foreach my $value (@{$_}) {
            return undef unless $check->($value);
        }
        return 1;
    }
}

sub _parameterize_HashRef_for {
    my($type_parameter) = @_;
    my $check = $type_parameter->_compiled_type_constraint;

    return sub {
        foreach my $value(values %{$_}){
            return undef unless $check->($value);
        }
        return 1;
    };
}

# 'Maybe' type accepts 'Any', so it requires parameters
sub _parameterize_Maybe_for {
    my($type_parameter) = @_;
    my $check = $type_parameter->_compiled_type_constraint;

    return sub{
        return !defined($_) || $check->($_);
    };
};


package Mouse::Meta::Module;

sub name          { $_[0]->{package} }

sub _method_map   { $_[0]->{methods} }
sub _attribute_map{ $_[0]->{attributes} }

sub namespace{
    my $name = $_[0]->{package};
    no strict 'refs';
    return \%{ $name . '::' };
}

sub add_method {
    my($self, $name, $code) = @_;

    if(!defined $name){
        $self->throw_error('You must pass a defined name');
    }
    if(!defined $code){
        $self->throw_error('You must pass a defined code');
    }

    if(ref($code) ne 'CODE'){
        $code = \&{$code}; # coerce
    }

    $self->{methods}->{$name} = $code; # Moose stores meta object here.

    my $pkg = $self->name;
    no strict 'refs';
    no warnings 'redefine', 'once';
    *{ $pkg . '::' . $name } = $code;
    return;
}

package Mouse::Meta::Class;

sub method_metaclass    { $_[0]->{method_metaclass}    || 'Mouse::Meta::Method'    }
sub attribute_metaclass { $_[0]->{attribute_metaclass} || 'Mouse::Meta::Attribute' }

sub constructor_class { $_[0]->{constructor_class} || 'Mouse::Meta::Method::Constructor' }
sub destructor_class  { $_[0]->{destructor_class}  || 'Mouse::Meta::Method::Destructor'  }

sub is_anon_class{
    return exists $_[0]->{anon_serial_id};
}

sub roles { $_[0]->{roles} }

sub linearized_isa { @{ get_linear_isa($_[0]->{package}) } }

sub get_all_attributes {
    my($self) = @_;
    my %attrs = map { %{ $self->initialize($_)->{attributes} } } reverse $self->linearized_isa;
    return values %attrs;
}

sub new_object {
    my $self = shift;
    my %args = (@_ == 1 ? %{$_[0]} : @_);

    my $object = bless {}, $self->name;

    $self->_initialize_object($object, \%args);
    return $object;
}

sub _initialize_object{
    my($self, $object, $args, $ignore_triggers) = @_;

    my @triggers_queue;

    foreach my $attribute ($self->get_all_attributes) {
        my $init_arg = $attribute->init_arg;
        my $slot     = $attribute->name;

        if (defined($init_arg) && exists($args->{$init_arg})) {
            $object->{$slot} = $attribute->_coerce_and_verify($args->{$init_arg}, $object);

            weaken($object->{$slot})
                if ref($object->{$slot}) && $attribute->is_weak_ref;

            if ($attribute->has_trigger) {
                push @triggers_queue, [ $attribute->trigger, $object->{$slot} ];
            }
        }
        else { # no init arg
            if ($attribute->has_default || $attribute->has_builder) {
                if (!$attribute->is_lazy) {
                    my $default = $attribute->default;
                    my $builder = $attribute->builder;
                    my $value =   $builder                ? $object->$builder()
                                : ref($default) eq 'CODE' ? $object->$default()
                                :                           $default;

                    $object->{$slot} = $attribute->_coerce_and_verify($value, $object);

                    weaken($object->{$slot})
                        if ref($object->{$slot}) && $attribute->is_weak_ref;
                }
            }
            elsif($attribute->is_required) {
                $self->throw_error("Attribute (".$attribute->name.") is required");
            }
        }
    }

    if(!$ignore_triggers){
        foreach my $trigger_and_value(@triggers_queue){
            my($trigger, $value) = @{$trigger_and_value};
            $trigger->($object, $value);
        }
    }

    if($self->is_anon_class){
        $object->{__METACLASS__} = $self;
    }

    return;
}

sub is_immutable {  $_[0]->{is_immutable} }

sub __strict_constructor{ $_[0]->{strict_constructor} }

package Mouse::Meta::Role;

sub method_metaclass{ $_[0]->{method_metaclass} || 'Mouse::Meta::Role::Method' }

sub is_anon_role{
    return exists $_[0]->{anon_serial_id};
}

sub get_roles { $_[0]->{roles} }

package Mouse::Meta::Attribute;

require Mouse::Meta::Method::Accessor;

sub accessor_metaclass{ $_[0]->{accessor_metaclass} || 'Mouse::Meta::Method::Accessor' }

# readers

sub name                 { $_[0]->{name}                   }
sub associated_class     { $_[0]->{associated_class}       }

sub accessor             { $_[0]->{accessor}               }
sub reader               { $_[0]->{reader}                 }
sub writer               { $_[0]->{writer}                 }
sub predicate            { $_[0]->{predicate}              }
sub clearer              { $_[0]->{clearer}                }
sub handles              { $_[0]->{handles}                }

sub _is_metadata         { $_[0]->{is}                     }
sub is_required          { $_[0]->{required}               }
sub default              { $_[0]->{default}                }
sub is_lazy              { $_[0]->{lazy}                   }
sub is_lazy_build        { $_[0]->{lazy_build}             }
sub is_weak_ref          { $_[0]->{weak_ref}               }
sub init_arg             { $_[0]->{init_arg}               }
sub type_constraint      { $_[0]->{type_constraint}        }

sub trigger              { $_[0]->{trigger}                }
sub builder              { $_[0]->{builder}                }
sub should_auto_deref    { $_[0]->{auto_deref}             }
sub should_coerce        { $_[0]->{coerce}                 }

sub documentation        { $_[0]->{documentation}          }

# predicates

sub has_accessor         { exists $_[0]->{accessor}        }
sub has_reader           { exists $_[0]->{reader}          }
sub has_writer           { exists $_[0]->{writer}          }
sub has_predicate        { exists $_[0]->{predicate}       }
sub has_clearer          { exists $_[0]->{clearer}         }
sub has_handles          { exists $_[0]->{handles}         }

sub has_default          { exists $_[0]->{default}         }
sub has_type_constraint  { exists $_[0]->{type_constraint} }
sub has_trigger          { exists $_[0]->{trigger}         }
sub has_builder          { exists $_[0]->{builder}         }

sub has_documentation    { exists $_[0]->{documentation}   }

sub _process_options{
    my($class, $name, $args) = @_;

    # taken from Class::MOP::Attribute::new

    defined($name)
        or $class->throw_error('You must provide a name for the attribute');

    if(!exists $args->{init_arg}){
        $args->{init_arg} = $name;
    }

    # 'required' requires eigher 'init_arg', 'builder', or 'default'
    my $can_be_required = defined( $args->{init_arg} );

    if(exists $args->{builder}){
        # XXX:
        # Moose refuses a CODE ref builder, but Mouse doesn't for backward compatibility
        # This feature will be changed in a future. (gfx)
        $class->throw_error('builder must be a defined scalar value which is a method name')
            #if ref $args->{builder} || !defined $args->{builder};
            if !defined $args->{builder};

        $can_be_required++;
    }
    elsif(exists $args->{default}){
        if(ref $args->{default} && ref($args->{default}) ne 'CODE'){
            $class->throw_error("References are not allowed as default values, you must "
                              . "wrap the default of '$name' in a CODE reference (ex: sub { [] } and not [])");
        }
        $can_be_required++;
    }

    if( $args->{required} && !$can_be_required ) {
        $class->throw_error("You cannot have a required attribute ($name) without a default, builder, or an init_arg");
    }

    # taken from Mouse::Meta::Attribute->new and ->_process_args

    if(exists $args->{is}){
        my $is = $args->{is};

        if($is eq 'ro'){
            $args->{reader} ||= $name;
        }
        elsif($is eq 'rw'){
            if(exists $args->{writer}){
                $args->{reader} ||= $name;
             }
             else{
                $args->{accessor} ||= $name;
             }
        }
        elsif($is eq 'bare'){
            # do nothing, but don't complain (later) about missing methods
        }
        else{
            $is = 'undef' if !defined $is;
            $class->throw_error("I do not understand this option (is => $is) on attribute ($name)");
        }
    }

    my $tc;
    if(exists $args->{isa}){
        $tc = $args->{type_constraint} = Mouse::Util::TypeConstraints::find_or_create_isa_type_constraint($args->{isa});
    }

    if(exists $args->{does}){
        if(defined $tc){ # both isa and does supplied
            my $does_ok = do{
                local $@;
                eval{ "$tc"->does($args) };
            };
            if(!$does_ok){
                $class->throw_error("Cannot have both an isa option and a does option because '$tc' does not do '$args->{does}' on attribute ($name)");
            }
        }
        else {
            $tc = $args->{type_constraint} = Mouse::Util::TypeConstraints::find_or_create_does_type_constraint($args->{does});
        }
    }

    if($args->{coerce}){
        defined($tc)
            || $class->throw_error("You cannot have coercion without specifying a type constraint on attribute ($name)");

        $args->{weak_ref}
            && $class->throw_error("You cannot have a weak reference to a coerced value on attribute ($name)");
    }

    if ($args->{lazy_build}) {
        exists($args->{default})
            && $class->throw_error("You can not use lazy_build and default for the same attribute ($name)");

        $args->{lazy}      = 1;
        $args->{builder} ||= "_build_${name}";
        if ($name =~ /^_/) {
            $args->{clearer}   ||= "_clear${name}";
            $args->{predicate} ||= "_has${name}";
        }
        else {
            $args->{clearer}   ||= "clear_${name}";
            $args->{predicate} ||= "has_${name}";
        }
    }

    if ($args->{auto_deref}) {
        defined($tc)
            || $class->throw_error("You cannot auto-dereference without specifying a type constraint on attribute ($name)");

        ( $tc->is_a_type_of('ArrayRef') || $tc->is_a_type_of('HashRef') )
            || $class->throw_error("You cannot auto-dereference anything other than a ArrayRef or HashRef on attribute ($name)");
    }

    if (exists $args->{trigger}) {
        ('CODE' eq ref $args->{trigger})
            || $class->throw_error("Trigger must be a CODE ref on attribute ($name)");
    }

    if ($args->{lazy}) {
        (exists $args->{default} || defined $args->{builder})
            || $class->throw_error("You cannot have lazy attribute ($name) without specifying a default value for it");
    }

    return;
}


package Mouse::Meta::TypeConstraint;

sub name    { $_[0]->{name}    }
sub parent  { $_[0]->{parent}  }
sub message { $_[0]->{message} }

sub type_parameter { $_[0]->{type_parameter} }
sub __is_parameterized { exists $_[0]->{type_parameter} }

sub _compiled_type_constraint{ $_[0]->{compiled_type_constraint} }

sub _compiled_type_coercion  { $_[0]->{_compiled_type_coercion}  }

sub has_coercion{ exists $_[0]->{_compiled_type_coercion} }


sub compile_type_constraint{
    my($self) = @_;

    # add parents first
    my @checks;
    for(my $parent = $self->{parent}; defined $parent; $parent = $parent->{parent}){
         if($parent->{hand_optimized_type_constraint}){
            unshift @checks, $parent->{hand_optimized_type_constraint};
            last; # a hand optimized constraint must include all the parents
        }
        elsif($parent->{constraint}){
            unshift @checks, $parent->{constraint};
        }
    }

    # then add child
    if($self->{constraint}){
        push @checks, $self->{constraint};
    }

    if($self->{type_constraints}){ # Union
        my @types = map{ $_->{compiled_type_constraint} } @{ $self->{type_constraints} };
        push @checks, sub{
            foreach my $c(@types){
                return 1 if $c->($_[0]);
            }
            return 0;
        };
    }

    if(@checks == 0){
        $self->{compiled_type_constraint} = \&Mouse::Util::TypeConstraints::Any;
    }
    else{
        $self->{compiled_type_constraint} =  sub{
            my(@args) = @_;
            local $_ = $args[0];
            foreach my $c(@checks){
                return undef if !$c->(@args);
            }
            return 1;
        };
    }
    return;
}

package Mouse::Object;


sub BUILDARGS {
    my $class = shift;

    if (scalar @_ == 1) {
        (ref($_[0]) eq 'HASH')
            || $class->meta->throw_error("Single parameters to new() must be a HASH ref");

        return {%{$_[0]}};
    }
    else {
        return {@_};
    }
}

sub new {
    my $class = shift;

    $class->meta->throw_error('Cannot call new() on an instance') if ref $class;

    my $args = $class->BUILDARGS(@_);

    my $meta = Mouse::Meta::Class->initialize($class);
    my $self = $meta->new_object($args);

    # BUILDALL
    if( $self->can('BUILD') ) {
        for my $class (reverse $meta->linearized_isa) {
            my $build = Mouse::Util::get_code_ref($class, 'BUILD')
                || next;

            $self->$build($args);
        }
    }

    return $self;
}

sub DESTROY {
    my $self = shift;

    return unless $self->can('DEMOLISH'); # short circuit

    local $?;

    my $e = do{
        local $@;
        eval{

            # DEMOLISHALL

            # We cannot count on being able to retrieve a previously made
            # metaclass, _or_ being able to make a new one during global
            # destruction. However, we should still be able to use mro at
            # that time (at least tests suggest so ;)

            foreach my $class (@{ Mouse::Util::get_linear_isa(ref $self) }) {
                my $demolish = Mouse::Util::get_code_ref($class, 'DEMOLISH')
                    || next;

                $self->$demolish($Mouse::Util::in_global_destruction);
            }
        };
        $@;
    };

    no warnings 'misc';
    die $e if $e; # rethrow
}

sub BUILDALL {
    my $self = shift;

    # short circuit
    return unless $self->can('BUILD');

    for my $class (reverse $self->meta->linearized_isa) {
        my $build = Mouse::Util::get_code_ref($class, 'BUILD')
            || next;

        $self->$build(@_);
    }
    return;
}

sub DEMOLISHALL;
*DEMOLISHALL = \&DESTROY;

1;
__END__

=head1 NAME

Mouse::PurePerl - A Mouse guts in pure Perl

=head1 VERSION

This document describes Mouse version 0.50_03

=head1 SEE ALSO

L<Mouse::XS>

=cut
Commit	Line	Data
ccb38d0b	1	package Mouse::PurePerl;
ccb38d0b	2
a52cca04	3	require Mouse::Util;
a52cca04	4
6fffa617	5	package Mouse::Util;
df6dd016	6
	7	use strict;
	8	use warnings;
	9
	10	use warnings FATAL => 'redefine'; # to avoid to load Mouse::PurePerl
	11
	12	use B ();
	13
0ffc4183	14
	15	# taken from Class/MOP.pm
	16	sub is_valid_class_name {
	17	my $class = shift;
	18
	19	return 0 if ref($class);
	20	return 0 unless defined($class);
	21
	22	return 1 if $class =~ /\A \w+ (?: :: \w+ )* \z/xms;
	23
	24	return 0;
	25	}
	26
df6dd016	27	sub is_class_loaded {
	28	my $class = shift;
	29
	30	return 0 if ref($class) \|\| !defined($class) \|\| !length($class);
	31
	32	# walk the symbol table tree to avoid autovififying
3bb9e54e	33	# \{${main::}{"Foo::"}{"Bar::"}} == \main::Foo::Bar::
df6dd016	34
	35	my $pack = \%::;
	36	foreach my $part (split('::', $class)) {
3bb9e54e	37	$part .= '::';
	38	return 0 if !exists $pack->{$part};
	39
	40	my $entry = \$pack->{$part};
df6dd016	41	return 0 if ref($entry) ne 'GLOB';
3bb9e54e	42	$pack = *{$entry}{HASH};
df6dd016	43	}
df6dd016	44
3bb9e54e	45	return 0 if !%{$pack};
3bb9e54e	46
df6dd016	47	# check for $VERSION or @ISA
	48	return 1 if exists $pack->{VERSION}
	49	&& defined *{$pack->{VERSION}}{SCALAR} && defined ${ $pack->{VERSION} };
	50	return 1 if exists $pack->{ISA}
	51	&& defined *{$pack->{ISA}}{ARRAY} && @{ $pack->{ISA} } != 0;
	52
	53	# check for any method
	54	foreach my $name( keys %{$pack} ) {
	55	my $entry = \$pack->{$name};
	56	return 1 if ref($entry) ne 'GLOB' \|\| defined *{$entry}{CODE};
	57	}
	58
	59	# fail
	60	return 0;
	61	}
	62
	63
	64	# taken from Sub::Identify
	65	sub get_code_info {
	66	my ($coderef) = @_;
	67	ref($coderef) or return;
	68
	69	my $cv = B::svref_2object($coderef);
	70	$cv->isa('B::CV') or return;
	71
	72	my $gv = $cv->GV;
	73	$gv->isa('B::GV') or return;
	74
	75	return ($gv->STASH->NAME, $gv->NAME);
	76	}
	77
	78	sub get_code_package{
	79	my($coderef) = @_;
	80
	81	my $cv = B::svref_2object($coderef);
	82	$cv->isa('B::CV') or return '';
	83
	84	my $gv = $cv->GV;
	85	$gv->isa('B::GV') or return '';
	86
	87	return $gv->STASH->NAME;
	88	}
	89
7d96ae4d	90	sub get_code_ref{
	91	my($package, $name) = @_;
	92	no strict 'refs';
	93	no warnings 'once';
	94	use warnings FATAL => 'uninitialized';
	95	return *{$package . '::' . $name}{CODE};
	96	}
	97
e3540312	98	sub generate_isa_predicate_for {
1d5ecd5f	99	my($for_class, $name) = @_;
1d5ecd5f	100
f48920c1	101	my $predicate = sub{ Scalar::Util::blessed($_[0]) && $_[0]->isa($for_class) };
1d5ecd5f	102
	103	if(defined $name){
	104	no strict 'refs';
	105	*{ caller() . '::' . $name } = $predicate;
	106	return;
	107	}
	108
	109	return $predicate;
	110	}
	111
ebe91068	112	sub generate_can_predicate_for {
	113	my($methods_ref, $name) = @_;
	114
	115	my @methods = @{$methods_ref};
	116
	117	my $predicate = sub{
	118	my($instance) = @_;
	119	if(Scalar::Util::blessed($instance)){
	120	foreach my $method(@methods){
	121	if(!$instance->can($method)){
	122	return 0;
	123	}
	124	}
	125	return 1;
	126	}
	127	return 0;
	128	};
	129
	130	if(defined $name){
	131	no strict 'refs';
	132	*{ caller() . '::' . $name } = $predicate;
	133	return;
	134	}
	135
	136	return $predicate;
	137	}
1d5ecd5f	138
6fffa617	139	package Mouse::Util::TypeConstraints;
f48920c1	140
	141	use Scalar::Util qw(blessed looks_like_number openhandle);
	142
7d96ae4d	143	sub Any { 1 }
7d96ae4d	144	sub Item { 1 }
7d96ae4d	145
	146	sub Bool { $_[0] ? $_[0] eq '1' : 1 }
	147	sub Undef { !defined($_[0]) }
	148	sub Defined { defined($_[0]) }
	149	sub Value { defined($_[0]) && !ref($_[0]) }
	150	sub Num { !ref($_[0]) && looks_like_number($_[0]) }
	151	sub Int { defined($_[0]) && !ref($_[0]) && $_[0] =~ /^-?[0-9]+$/ }
9848d3e1	152	sub Str {
	153	my($value) = @_;
	154	return defined($value) && ref(\$value) eq 'SCALAR';
	155	}
7d96ae4d	156
7d96ae4d	157	sub Ref { ref($_[0]) }
9848d3e1	158	sub ScalarRef {
	159	my($value) = @_;
	160	return ref($value) eq 'SCALAR'
	161	}
7d96ae4d	162	sub ArrayRef { ref($_[0]) eq 'ARRAY' }
	163	sub HashRef { ref($_[0]) eq 'HASH' }
	164	sub CodeRef { ref($_[0]) eq 'CODE' }
	165	sub RegexpRef { ref($_[0]) eq 'Regexp' }
	166	sub GlobRef { ref($_[0]) eq 'GLOB' }
	167
	168	sub FileHandle {
9848d3e1	169	return openhandle($_[0]) \|\| (blessed($_[0]) && $_[0]->isa("IO::Handle"))
7d96ae4d	170	}
	171
	172	sub Object { blessed($_[0]) && blessed($_[0]) ne 'Regexp' }
	173
	174	sub ClassName { Mouse::Util::is_class_loaded($_[0]) }
	175	sub RoleName { (Mouse::Util::class_of($_[0]) \|\| return 0)->isa('Mouse::Meta::Role') }
	176
619338ac	177	sub _parameterize_ArrayRef_for {
	178	my($type_parameter) = @_;
	179	my $check = $type_parameter->_compiled_type_constraint;
	180
	181	return sub {
	182	foreach my $value (@{$_}) {
	183	return undef unless $check->($value);
	184	}
	185	return 1;
	186	}
	187	}
	188
	189	sub _parameterize_HashRef_for {
	190	my($type_parameter) = @_;
	191	my $check = $type_parameter->_compiled_type_constraint;
	192
	193	return sub {
	194	foreach my $value(values %{$_}){
	195	return undef unless $check->($value);
	196	}
	197	return 1;
	198	};
	199	}
	200
	201	# 'Maybe' type accepts 'Any', so it requires parameters
	202	sub _parameterize_Maybe_for {
	203	my($type_parameter) = @_;
	204	my $check = $type_parameter->_compiled_type_constraint;
	205
	206	return sub{
	207	return !defined($_) \|\| $check->($_);
	208	};
	209	};
	210
	211
7d96ae4d	212
6fffa617	213	package Mouse::Meta::Module;
43165725	214
926404f2	215	sub name { $_[0]->{package} }
	216
	217	sub _method_map { $_[0]->{methods} }
c5f6ad05	218	sub _attribute_map{ $_[0]->{attributes} }
43165725	219
2591e962	220	sub namespace{
	221	my $name = $_[0]->{package};
	222	no strict 'refs';
	223	return \%{ $name . '::' };
	224	}
	225
3e44140b	226	sub add_method {
	227	my($self, $name, $code) = @_;
	228
	229	if(!defined $name){
	230	$self->throw_error('You must pass a defined name');
	231	}
	232	if(!defined $code){
	233	$self->throw_error('You must pass a defined code');
	234	}
	235
	236	if(ref($code) ne 'CODE'){
	237	$code = \&{$code}; # coerce
	238	}
	239
	240	$self->{methods}->{$name} = $code; # Moose stores meta object here.
	241
	242	my $pkg = $self->name;
	243	no strict 'refs';
	244	no warnings 'redefine', 'once';
	245	*{ $pkg . '::' . $name } = $code;
	246	return;
	247	}
	248
6fffa617	249	package Mouse::Meta::Class;
43165725	250
e058b279	251	sub method_metaclass { $_[0]->{method_metaclass} \|\| 'Mouse::Meta::Method' }
	252	sub attribute_metaclass { $_[0]->{attribute_metaclass} \|\| 'Mouse::Meta::Attribute' }
	253
	254	sub constructor_class { $_[0]->{constructor_class} \|\| 'Mouse::Meta::Method::Constructor' }
	255	sub destructor_class { $_[0]->{destructor_class} \|\| 'Mouse::Meta::Method::Destructor' }
4e7e3250	256
43165725	257	sub is_anon_class{
	258	return exists $_[0]->{anon_serial_id};
	259	}
	260
	261	sub roles { $_[0]->{roles} }
	262
cccb83de	263	sub linearized_isa { @{ get_linear_isa($_[0]->{package}) } }
cccb83de	264
da4432f3	265	sub get_all_attributes {
da4432f3	266	my($self) = @_;
047d7af0	267	my %attrs = map { %{ $self->initialize($_)->{attributes} } } reverse $self->linearized_isa;
da4432f3	268	return values %attrs;
	269	}
	270
ba153b33	271	sub new_object {
	272	my $self = shift;
	273	my %args = (@_ == 1 ? %{$_[0]} : @_);
	274
	275	my $object = bless {}, $self->name;
	276
	277	$self->_initialize_object($object, \%args);
	278	return $object;
	279	}
	280
4e7e3250	281	sub _initialize_object{
	282	my($self, $object, $args, $ignore_triggers) = @_;
	283
	284	my @triggers_queue;
	285
	286	foreach my $attribute ($self->get_all_attributes) {
	287	my $init_arg = $attribute->init_arg;
	288	my $slot = $attribute->name;
	289
	290	if (defined($init_arg) && exists($args->{$init_arg})) {
	291	$object->{$slot} = $attribute->_coerce_and_verify($args->{$init_arg}, $object);
	292
	293	weaken($object->{$slot})
	294	if ref($object->{$slot}) && $attribute->is_weak_ref;
	295
	296	if ($attribute->has_trigger) {
	297	push @triggers_queue, [ $attribute->trigger, $object->{$slot} ];
	298	}
	299	}
	300	else { # no init arg
	301	if ($attribute->has_default \|\| $attribute->has_builder) {
	302	if (!$attribute->is_lazy) {
	303	my $default = $attribute->default;
	304	my $builder = $attribute->builder;
	305	my $value = $builder ? $object->$builder()
	306	: ref($default) eq 'CODE' ? $object->$default()
	307	: $default;
	308
	309	$object->{$slot} = $attribute->_coerce_and_verify($value, $object);
	310
	311	weaken($object->{$slot})
	312	if ref($object->{$slot}) && $attribute->is_weak_ref;
	313	}
	314	}
	315	elsif($attribute->is_required) {
	316	$self->throw_error("Attribute (".$attribute->name.") is required");
	317	}
	318	}
	319	}
	320
	321	if(!$ignore_triggers){
	322	foreach my $trigger_and_value(@triggers_queue){
	323	my($trigger, $value) = @{$trigger_and_value};
	324	$trigger->($object, $value);
	325	}
	326	}
	327
	328	if($self->is_anon_class){
	329	$object->{__METACLASS__} = $self;
	330	}
	331
	332	return;
	333	}
	334
80efe911	335	sub is_immutable { $_[0]->{is_immutable} }
4e7e3250	336
e128626c	337	sub __strict_constructor{ $_[0]->{strict_constructor} }
e128626c	338
6fffa617	339	package Mouse::Meta::Role;
43165725	340
e058b279	341	sub method_metaclass{ $_[0]->{method_metaclass} \|\| 'Mouse::Meta::Role::Method' }
e058b279	342
43165725	343	sub is_anon_role{
	344	return exists $_[0]->{anon_serial_id};
	345	}
	346
	347	sub get_roles { $_[0]->{roles} }
	348
6fffa617	349	package Mouse::Meta::Attribute;
43165725	350
e058b279	351	require Mouse::Meta::Method::Accessor;
	352
	353	sub accessor_metaclass{ $_[0]->{accessor_metaclass} \|\| 'Mouse::Meta::Method::Accessor' }
43165725	354
	355	# readers
	356
	357	sub name { $_[0]->{name} }
	358	sub associated_class { $_[0]->{associated_class} }
	359
	360	sub accessor { $_[0]->{accessor} }
	361	sub reader { $_[0]->{reader} }
	362	sub writer { $_[0]->{writer} }
	363	sub predicate { $_[0]->{predicate} }
	364	sub clearer { $_[0]->{clearer} }
	365	sub handles { $_[0]->{handles} }
	366
	367	sub _is_metadata { $_[0]->{is} }
	368	sub is_required { $_[0]->{required} }
	369	sub default { $_[0]->{default} }
	370	sub is_lazy { $_[0]->{lazy} }
	371	sub is_lazy_build { $_[0]->{lazy_build} }
	372	sub is_weak_ref { $_[0]->{weak_ref} }
	373	sub init_arg { $_[0]->{init_arg} }
	374	sub type_constraint { $_[0]->{type_constraint} }
	375
	376	sub trigger { $_[0]->{trigger} }
	377	sub builder { $_[0]->{builder} }
	378	sub should_auto_deref { $_[0]->{auto_deref} }
	379	sub should_coerce { $_[0]->{coerce} }
	380
d899d3e7	381	sub documentation { $_[0]->{documentation} }
d899d3e7	382
43165725	383	# predicates
	384
	385	sub has_accessor { exists $_[0]->{accessor} }
	386	sub has_reader { exists $_[0]->{reader} }
	387	sub has_writer { exists $_[0]->{writer} }
	388	sub has_predicate { exists $_[0]->{predicate} }
	389	sub has_clearer { exists $_[0]->{clearer} }
	390	sub has_handles { exists $_[0]->{handles} }
	391
	392	sub has_default { exists $_[0]->{default} }
	393	sub has_type_constraint { exists $_[0]->{type_constraint} }
	394	sub has_trigger { exists $_[0]->{trigger} }
	395	sub has_builder { exists $_[0]->{builder} }
	396
d899d3e7	397	sub has_documentation { exists $_[0]->{documentation} }
d899d3e7	398
ba1f50a2	399	sub _process_options{
	400	my($class, $name, $args) = @_;
	401
	402	# taken from Class::MOP::Attribute::new
	403
	404	defined($name)
	405	or $class->throw_error('You must provide a name for the attribute');
	406
	407	if(!exists $args->{init_arg}){
	408	$args->{init_arg} = $name;
	409	}
	410
	411	# 'required' requires eigher 'init_arg', 'builder', or 'default'
	412	my $can_be_required = defined( $args->{init_arg} );
	413
	414	if(exists $args->{builder}){
	415	# XXX:
	416	# Moose refuses a CODE ref builder, but Mouse doesn't for backward compatibility
	417	# This feature will be changed in a future. (gfx)
	418	$class->throw_error('builder must be a defined scalar value which is a method name')
	419	#if ref $args->{builder} \|\| !defined $args->{builder};
	420	if !defined $args->{builder};
	421
	422	$can_be_required++;
	423	}
	424	elsif(exists $args->{default}){
	425	if(ref $args->{default} && ref($args->{default}) ne 'CODE'){
	426	$class->throw_error("References are not allowed as default values, you must "
	427	. "wrap the default of '$name' in a CODE reference (ex: sub { [] } and not [])");
	428	}
	429	$can_be_required++;
	430	}
	431
	432	if( $args->{required} && !$can_be_required ) {
	433	$class->throw_error("You cannot have a required attribute ($name) without a default, builder, or an init_arg");
	434	}
	435
	436	# taken from Mouse::Meta::Attribute->new and ->_process_args
	437
	438	if(exists $args->{is}){
	439	my $is = $args->{is};
	440
	441	if($is eq 'ro'){
	442	$args->{reader} \|\|= $name;
	443	}
	444	elsif($is eq 'rw'){
	445	if(exists $args->{writer}){
	446	$args->{reader} \|\|= $name;
	447	}
	448	else{
	449	$args->{accessor} \|\|= $name;
	450	}
	451	}
	452	elsif($is eq 'bare'){
	453	# do nothing, but don't complain (later) about missing methods
	454	}
	455	else{
	456	$is = 'undef' if !defined $is;
	457	$class->throw_error("I do not understand this option (is => $is) on attribute ($name)");
	458	}
	459	}
	460
	461	my $tc;
	462	if(exists $args->{isa}){
d503a4f3	463	$tc = $args->{type_constraint} = Mouse::Util::TypeConstraints::find_or_create_isa_type_constraint($args->{isa});
ba1f50a2	464	}
d503a4f3	465
	466	if(exists $args->{does}){
	467	if(defined $tc){ # both isa and does supplied
	468	my $does_ok = do{
	469	local $@;
	470	eval{ "$tc"->does($args) };
	471	};
	472	if(!$does_ok){
	473	$class->throw_error("Cannot have both an isa option and a does option because '$tc' does not do '$args->{does}' on attribute ($name)");
	474	}
	475	}
	476	else {
	477	$tc = $args->{type_constraint} = Mouse::Util::TypeConstraints::find_or_create_does_type_constraint($args->{does});
	478	}
ba1f50a2	479	}
ba1f50a2	480
	481	if($args->{coerce}){
	482	defined($tc)
	483	\|\| $class->throw_error("You cannot have coercion without specifying a type constraint on attribute ($name)");
	484
	485	$args->{weak_ref}
	486	&& $class->throw_error("You cannot have a weak reference to a coerced value on attribute ($name)");
	487	}
	488
	489	if ($args->{lazy_build}) {
	490	exists($args->{default})
	491	&& $class->throw_error("You can not use lazy_build and default for the same attribute ($name)");
	492
	493	$args->{lazy} = 1;
	494	$args->{builder} \|\|= "_build_${name}";
	495	if ($name =~ /^_/) {
	496	$args->{clearer} \|\|= "_clear${name}";
	497	$args->{predicate} \|\|= "_has${name}";
	498	}
	499	else {
	500	$args->{clearer} \|\|= "clear_${name}";
	501	$args->{predicate} \|\|= "has_${name}";
	502	}
	503	}
	504
	505	if ($args->{auto_deref}) {
	506	defined($tc)
	507	\|\| $class->throw_error("You cannot auto-dereference without specifying a type constraint on attribute ($name)");
	508
	509	( $tc->is_a_type_of('ArrayRef') \|\| $tc->is_a_type_of('HashRef') )
	510	\|\| $class->throw_error("You cannot auto-dereference anything other than a ArrayRef or HashRef on attribute ($name)");
	511	}
	512
	513	if (exists $args->{trigger}) {
	514	('CODE' eq ref $args->{trigger})
	515	\|\| $class->throw_error("Trigger must be a CODE ref on attribute ($name)");
	516	}
	517
	518	if ($args->{lazy}) {
	519	(exists $args->{default} \|\| defined $args->{builder})
	520	\|\| $class->throw_error("You cannot have lazy attribute ($name) without specifying a default value for it");
	521	}
	522
	523	return;
	524	}
	525
	526
6fffa617	527	package Mouse::Meta::TypeConstraint;
43165725	528
	529	sub name { $_[0]->{name} }
	530	sub parent { $_[0]->{parent} }
	531	sub message { $_[0]->{message} }
	532
fc83f4cf	533	sub type_parameter { $_[0]->{type_parameter} }
	534	sub __is_parameterized { exists $_[0]->{type_parameter} }
	535
43165725	536	sub _compiled_type_constraint{ $_[0]->{compiled_type_constraint} }
43165725	537
93540011	538	sub _compiled_type_coercion { $_[0]->{_compiled_type_coercion} }
df6dd016	539
93540011	540	sub has_coercion{ exists $_[0]->{_compiled_type_coercion} }
df6dd016	541
f790c46b	542
	543	sub compile_type_constraint{
	544	my($self) = @_;
	545
	546	# add parents first
	547	my @checks;
	548	for(my $parent = $self->{parent}; defined $parent; $parent = $parent->{parent}){
	549	if($parent->{hand_optimized_type_constraint}){
	550	unshift @checks, $parent->{hand_optimized_type_constraint};
	551	last; # a hand optimized constraint must include all the parents
	552	}
	553	elsif($parent->{constraint}){
	554	unshift @checks, $parent->{constraint};
	555	}
	556	}
	557
	558	# then add child
	559	if($self->{constraint}){
	560	push @checks, $self->{constraint};
	561	}
	562
	563	if($self->{type_constraints}){ # Union
	564	my @types = map{ $_->{compiled_type_constraint} } @{ $self->{type_constraints} };
	565	push @checks, sub{
	566	foreach my $c(@types){
	567	return 1 if $c->($_[0]);
	568	}
	569	return 0;
	570	};
	571	}
	572
	573	if(@checks == 0){
	574	$self->{compiled_type_constraint} = \&Mouse::Util::TypeConstraints::Any;
	575	}
	576	else{
	577	$self->{compiled_type_constraint} = sub{
	578	my(@args) = @_;
	579	local $_ = $args[0];
	580	foreach my $c(@checks){
	581	return undef if !$c->(@args);
	582	}
	583	return 1;
	584	};
	585	}
	586	return;
	587	}
	588
6fffa617	589	package Mouse::Object;
aa2d2e2c	590
	591
	592	sub BUILDARGS {
	593	my $class = shift;
f790c46b	594
aa2d2e2c	595	if (scalar @_ == 1) {
	596	(ref($_[0]) eq 'HASH')
	597	\|\| $class->meta->throw_error("Single parameters to new() must be a HASH ref");
	598
	599	return {%{$_[0]}};
	600	}
	601	else {
	602	return {@_};
	603	}
	604	}
f790c46b	605
af04626d	606	sub new {
	607	my $class = shift;
	608
	609	$class->meta->throw_error('Cannot call new() on an instance') if ref $class;
	610
	611	my $args = $class->BUILDARGS(@_);
	612
	613	my $meta = Mouse::Meta::Class->initialize($class);
	614	my $self = $meta->new_object($args);
	615
	616	# BUILDALL
	617	if( $self->can('BUILD') ) {
	618	for my $class (reverse $meta->linearized_isa) {
	619	my $build = Mouse::Util::get_code_ref($class, 'BUILD')
	620	\|\| next;
	621
	622	$self->$build($args);
	623	}
	624	}
	625
	626	return $self;
	627	}
	628
a5c683f6	629	sub DESTROY {
	630	my $self = shift;
	631
	632	return unless $self->can('DEMOLISH'); # short circuit
	633
	634	local $?;
	635
	636	my $e = do{
	637	local $@;
	638	eval{
	639
	640	# DEMOLISHALL
	641
	642	# We cannot count on being able to retrieve a previously made
	643	# metaclass, _or_ being able to make a new one during global
	644	# destruction. However, we should still be able to use mro at
	645	# that time (at least tests suggest so ;)
	646
	647	foreach my $class (@{ Mouse::Util::get_linear_isa(ref $self) }) {
	648	my $demolish = Mouse::Util::get_code_ref($class, 'DEMOLISH')
	649	\|\| next;
	650
6514735e	651	$self->$demolish($Mouse::Util::in_global_destruction);
a5c683f6	652	}
	653	};
	654	$@;
	655	};
	656
	657	no warnings 'misc';
	658	die $e if $e; # rethrow
	659	}
	660
adb5eb76	661	sub BUILDALL {
	662	my $self = shift;
	663
	664	# short circuit
	665	return unless $self->can('BUILD');
	666
	667	for my $class (reverse $self->meta->linearized_isa) {
	668	my $build = Mouse::Util::get_code_ref($class, 'BUILD')
	669	\|\| next;
	670
	671	$self->$build(@_);
	672	}
	673	return;
	674	}
	675
	676	sub DEMOLISHALL;
	677	*DEMOLISHALL = \&DESTROY;
	678
df6dd016	679	1;
df6dd016	680	__END__
ccb38d0b	681
	682	=head1 NAME
	683
	684	Mouse::PurePerl - A Mouse guts in pure Perl
	685
	686	=head1 VERSION
	687
4bc73e47	688	This document describes Mouse version 0.50_03
ccb38d0b	689
	690	=head1 SEE ALSO
	691
	692	L<Mouse::XS>
	693
	694	=cut