lib/MooseX/Types/Combine.pm

   1 =head1 NAME
   2
   3 MooseX::Types::Combine - Combine type libraries for exporting
   4
   5 =cut
   6
   7 package MooseX::Types::Combine;
   8 our $VERSION = "0.26";
   9
  10 use strict;
  11 use warnings;
  12 use Class::MOP ();
  13
  14 =head1 SYNOPSIS
  15
  16     package CombinedTypeLib;
  17
  18     use base 'MooseX::Types::Combine';
  19
  20     __PACKAGE__->provide_types_from(qw/TypeLib1 TypeLib2/);
  21
  22     package UserClass;
  23
  24     use CombinedTypeLib qw/Type1 Type2 ... /;
  25
  26 =head1 DESCRIPTION
  27
  28 Allows you to export types from multiple type libraries.
  29
  30 Libraries on the right side of the type libs passed to L</provide_types_from>
  31 take precedence over those on the left in case of conflicts.
  32
  33 =cut
  34
  35 sub import {
  36     my ($class, @types) = @_;
  37     my $caller = caller;
  38
  39     my %types = $class->_provided_types;
  40
  41     my %from;
  42     for my $type (@types) {
  43         unless ($types{$type}) {
  44             my @type_libs = $class->provide_types_from;
  45
  46             die
  47                 "$caller asked for a type ($type) which is not found in any of the"
  48                 . " type libraries (@type_libs) combined by $class\n";
  49         }
  50
  51         push @{ $from{ $types{$type} } }, $type;
  52     }
  53
  54     $_->import({ -into => $caller }, @{ $from{ $_ } })
  55         for keys %from;
  56 }
  57
  58 =head1 CLASS METHODS
  59
  60 =head2 provide_types_from
  61
  62 Sets or returns a list of type libraries to re-export from.
  63
  64 =cut
  65
  66 sub provide_types_from {
  67     my ($class, @libs) = @_;
  68
  69     my $store =
  70      do { no strict 'refs'; \@{ "${class}::__MOOSEX_TYPELIBRARY_LIBRARIES" } };
  71
  72     if (@libs) {
  73         $class->_check_type_lib($_) for @libs;
  74         @$store = @libs;
  75
  76         my %types = map {
  77             my $lib = $_;
  78             map +( $_ => $lib ), $lib->type_names
  79         } @libs;
  80
  81         $class->_provided_types(%types);
  82     }
  83
  84     @$store;
  85 }
  86
  87 sub _check_type_lib {
  88     my ($class, $lib) = @_;
  89
  90     Class::MOP::load_class($lib);
  91
  92     die "Cannot use $lib in a combined type library, it does not provide any types"
  93         unless $lib->can('type_names');
  94 }
  95
  96 sub _provided_types {
  97     my ($class, %types) = @_;
  98
  99     my $types =
 100      do { no strict 'refs'; \%{ "${class}::__MOOSEX_TYPELIBRARY_TYPES" } };
 101
 102     %$types = %types
 103         if keys %types;
 104
 105     %$types;
 106 }
 107
 108 =head1 SEE ALSO
 109
 110 L<MooseX::Types>
 111
 112 =head1 AUTHOR
 113
 114 See L<MooseX::Types/AUTHOR>.
 115
 116 =head1 LICENSE
 117
 118 This program is free software; you can redistribute it and/or modify
 119 it under the same terms as perl itself.
 120
 121 =cut
 122
 123 1;