lib/MooseX/StrictConstructor/Trait/Method/Constructor.pm

   1 package MooseX::StrictConstructor::Trait::Method::Constructor;
   2
   3 use Moose::Role;
   4
   5 use namespace::autoclean;
   6
   7 use B ();
   8
   9 around '_generate_BUILDALL' => sub {
  10     my $orig = shift;
  11     my $self = shift;
  12
  13     my $source = $self->$orig();
  14     $source .= ";\n" if $source;
  15
  16     my @attrs = (
  17         '__INSTANCE__ => 1,',
  18         map { B::perlstring($_) . ' => 1,' }
  19         grep {defined}
  20         map  { $_->init_arg() } @{ $self->_attributes() }
  21     );
  22
  23     $source .= <<"EOF";
  24 my \%attrs = (@attrs);
  25
  26 my \@bad = sort grep { ! \$attrs{\$_} }  keys \%{ \$params };
  27
  28 if (\@bad) {
  29     Moose->throw_error("Found unknown attribute(s) passed to the constructor: \@bad");
  30 }
  31 EOF
  32
  33     return $source;
  34 };
  35
  36 1;
  37
  38 # ABSTRACT: A role to make immutable constructors strict
  39
  40 __END__
  41
  42 =pod
  43
  44 =head1 DESCRIPTION
  45
  46 This role simply wraps C<_generate_BUILDALL()> (from
  47 C<Moose::Meta::Method::Constructor>) so that immutable classes have a
  48 strict constructor.
  49
  50 =cut
  51