t/010_basic_json.t

   1 #!/usr/bin/perl
   2
   3 use strict;
   4 use warnings;
   5
   6 use Test::More;
   7
   8 BEGIN {
   9     eval "use Test::JSON";
  10     plan skip_all => "Test::JSON is required for this test" if $@;
  11     eval "use JSON::Any";
  12     plan skip_all => "JSON::Any is required for this test" if $@;
  13     plan tests => 12;
  14     use_ok('MooseX::Storage');
  15 }
  16
  17 {
  18
  19     package Foo;
  20     use Moose;
  21     use MooseX::Storage;
  22
  23     with Storage( 'format' => 'JSON' );
  24
  25     has 'number' => ( is => 'ro', isa => 'Int' );
  26     has 'string' => ( is => 'ro', isa => 'Str' );
  27     has 'float'  => ( is => 'ro', isa => 'Num' );
  28     has 'array'  => ( is => 'ro', isa => 'ArrayRef' );
  29     has 'hash'   => ( is => 'ro', isa => 'HashRef' );
  30     has 'object' => ( is => 'ro', isa => 'Object' );
  31 }
  32
  33 {
  34     my $foo = Foo->new(
  35         number => 10,
  36         string => 'foo',
  37         float  => 10.5,
  38         array  => [ 1 .. 10 ],
  39         hash   => { map { $_ => undef } ( 1 .. 10 ) },
  40         object => Foo->new( number => 2 ),
  41     );
  42     isa_ok( $foo, 'Foo' );
  43
  44     my $json = $foo->freeze;
  45
  46     is_valid_json($json, '.. this is valid JSON');
  47
  48
  49     is_json(
  50         $json,
  51 '{"array":[1,2,3,4,5,6,7,8,9,10],"hash":{"6":null,"3":null,"7":null,"9":null,"2":null,"8":null,"1":null,"4":null,"10":null,"5":null},"float":10.5,"object":{"number":2,"__CLASS__":"Foo"},"number":10,"__CLASS__":"Foo","string":"foo"}',
  52         '... got the right JSON'
  53     );
  54
  55 }
  56
  57 {
  58     my $foo =
  59       Foo->thaw(
  60 '{"array":[1,2,3,4,5,6,7,8,9,10],"hash":{"6":null,"3":null,"7":null,"9":null,"2":null,"8":null,"1":null,"4":null,"10":null,"5":null},"float":10.5,"object":{"number":2,"__CLASS__":"Foo"},"number":10,"__CLASS__":"Foo","string":"foo"}'
  61       );
  62     isa_ok( $foo, 'Foo' );
  63
  64     is( $foo->number, 10,    '... got the right number' );
  65     is( $foo->string, 'foo', '... got the right string' );
  66     is( $foo->float,  10.5,  '... got the right float' );
  67     is_deeply( $foo->array, [ 1 .. 10 ], '... got the right array' );
  68     is_deeply(
  69         $foo->hash,
  70         { map { $_ => undef } ( 1 .. 10 ) },
  71         '... got the right hash'
  72     );
  73
  74     isa_ok( $foo->object, 'Foo' );
  75     is( $foo->object->number, 2,
  76         '... got the right number (in the embedded object)' );
  77 }
  78