t/010_basic_json.t

   1 #!/usr/bin/perl
   2
   3 use strict;
   4 use warnings;
   5
   6 use Test::More;
   7
   8 use Test::Requires {
   9     'Test::JSON' => 0.01, # skip all if not installed
  10     'JSON::Any' => 0.01,
  11 };
  12
  13 BEGIN {
  14     plan tests => 12;
  15     use_ok('MooseX::Storage');
  16 }
  17
  18 {
  19
  20     package Foo;
  21     use Moose;
  22     use MooseX::Storage;
  23
  24     with Storage( 'format' => 'JSON' );
  25
  26     has 'number' => ( is => 'ro', isa => 'Int' );
  27     has 'string' => ( is => 'ro', isa => 'Str' );
  28     has 'float'  => ( is => 'ro', isa => 'Num' );
  29     has 'array'  => ( is => 'ro', isa => 'ArrayRef' );
  30     has 'hash'   => ( is => 'ro', isa => 'HashRef' );
  31     has 'object' => ( is => 'ro', isa => 'Object' );
  32 }
  33
  34 {
  35     my $foo = Foo->new(
  36         number => 10,
  37         string => 'foo',
  38         float  => 10.5,
  39         array  => [ 1 .. 10 ],
  40         hash   => { map { $_ => undef } ( 1 .. 10 ) },
  41         object => Foo->new( number => 2 ),
  42     );
  43     isa_ok( $foo, 'Foo' );
  44
  45     my $json = $foo->freeze;
  46
  47     is_valid_json($json, '.. this is valid JSON');
  48
  49
  50     is_json(
  51         $json,
  52 '{"array":[1,2,3,4,5,6,7,8,9,10],"hash":{"6":null,"3":null,"7":null,"9":null,"2":null,"8":null,"1":null,"4":null,"10":null,"5":null},"float":10.5,"object":{"number":2,"__CLASS__":"Foo"},"number":10,"__CLASS__":"Foo","string":"foo"}',
  53         '... got the right JSON'
  54     );
  55
  56 }
  57
  58 {
  59     my $foo =
  60       Foo->thaw(
  61 '{"array":[1,2,3,4,5,6,7,8,9,10],"hash":{"6":null,"3":null,"7":null,"9":null,"2":null,"8":null,"1":null,"4":null,"10":null,"5":null},"float":10.5,"object":{"number":2,"__CLASS__":"Foo"},"number":10,"__CLASS__":"Foo","string":"foo"}'
  62       );
  63     isa_ok( $foo, 'Foo' );
  64
  65     is( $foo->number, 10,    '... got the right number' );
  66     is( $foo->string, 'foo', '... got the right string' );
  67     is( $foo->float,  10.5,  '... got the right float' );
  68     is_deeply( $foo->array, [ 1 .. 10 ], '... got the right array' );
  69     is_deeply(
  70         $foo->hash,
  71         { map { $_ => undef } ( 1 .. 10 ) },
  72         '... got the right hash'
  73     );
  74
  75     isa_ok( $foo->object, 'Foo' );
  76     is( $foo->object->number, 2,
  77         '... got the right number (in the embedded object)' );
  78 }
  79