lib/MooseX/Storage/Util.pm

   1 package MooseX::Storage::Util;
   2 use Moose qw(confess blessed);
   3
   4 use MooseX::Storage::Engine ();
   5
   6 our $VERSION   = '0.02';
   7 our $AUTHORITY = 'cpan:STEVAN';
   8
   9 sub peek {
  10     my ($class, $data, %options) = @_;
  11
  12     if (exists $options{'format'}) {
  13
  14         my $inflater = $class->can('_inflate_' . lc($options{'format'}));
  15
  16         (defined $inflater)
  17             || confess "No inflater found for " . $options{'format'};
  18
  19         $data = $class->$inflater($data);
  20     }
  21
  22     (ref($data) && ref($data) eq 'HASH' && !blessed($data))
  23         || confess "The data has to be a HASH reference, but not blessed";
  24
  25     $options{'key'} ||= $MooseX::Storage::Engine::CLASS_MARKER;
  26
  27     return $data->{$options{'key'}};
  28
  29 }
  30
  31 sub _inflate_json {
  32     my ($class, $json) = @_;
  33
  34     require JSON::Any;
  35     eval { JSON::Any->import };
  36     confess "Could not load JSON module because : $@" if $@;
  37
  38     my $data = eval { JSON::Any->jsonToObj($json) };
  39     if ($@) {
  40         confess "There was an error when attempting to peek at JSON: $@";
  41     }
  42
  43     return $data;
  44 }
  45
  46 sub _inflate_yaml {
  47     my ($class, $yaml) = @_;
  48
  49     require Best;
  50     eval { Best->import([[ qw[YAML::Syck YAML] ]]) };
  51     confess "Could not load YAML module because : $@" if $@;
  52
  53
  54     my $inflater = Best->which('YAML::Syck')->can('Load');
  55
  56     (defined $inflater)
  57         || confess "Could not load the YAML inflator";
  58
  59     my $data = eval { $inflater->($yaml) };
  60     if ($@) {
  61         confess "There was an error when attempting to peek at YAML : $@";
  62     }
  63     return $data;
  64 }
  65
  66 1;
  67
  68 __END__
  69
  70 =pod
  71
  72 =head1 NAME
  73
  74 MooseX::Storage::Util - A MooseX::Storage swiss-army chainsaw
  75
  76 =head1 DESCRIPTION
  77
  78 This module provides a set of tools, some sharp and focused,
  79 others more blunt and crude. But no matter what, they are useful
  80 bits to have around when dealing with MooseX::Storage code.
  81
  82 =head1 METHODS
  83
  84 All the methods in this package are class methods and should
  85 be called appropriately.
  86
  87 =over 4
  88
  89 =item B<peek ($data, %options)>
  90
  91 This method will help you to verify that the serialized class you
  92 have gotten is what you expect it to be before you actually
  93 unfreeze/unpack it.
  94
  95 The C<$data> can be either a perl HASH ref or some kind of serialized
  96 data (JSON, YAML, etc.).
  97
  98 The C<%options> are as follows:
  99
 100 =over 4
 101
 102 =item I<format>
 103
 104 If this is left blank, we assume that C<$data> is a plain perl HASH ref
 105 otherwise we attempt to inflate C<$data> based on the value of this option.
 106
 107 Currently only JSON and YAML are supported here.
 108
 109 =item I<key>
 110
 111 The default is to try and extract the class name, but if you want to check
 112 another key in the data, you can set this option. It will return the value
 113 found in the key for you.
 114
 115 =back
 116
 117 =back
 118
 119 =head2 Introspection
 120
 121 =over 4
 122
 123 =item B<meta>
 124
 125 =back
 126
 127 =head1 TODO
 128
 129 Add more stuff to this module :)
 130
 131 =head1 BUGS
 132
 133 All complex software has bugs lurking in it, and this module is no
 134 exception. If you find a bug please either email me, or add the bug
 135 to cpan-RT.
 136
 137 =head1 AUTHOR
 138
 139 Stevan Little E<lt>stevan.little@iinteractive.comE<gt>
 140
 141 =head1 COPYRIGHT AND LICENSE
 142
 143 Copyright 2007 by Infinity Interactive, Inc.
 144
 145 L<http://www.iinteractive.com>
 146
 147 This library is free software; you can redistribute it and/or modify
 148 it under the same terms as Perl itself.
 149
 150 =cut