lib/MooseX/Storage/Engine.pm

   1
   2 package MooseX::Storage::Engine;
   3 use Moose;
   4 use Scalar::Util qw(refaddr);
   5
   6 our $VERSION   = '0.18';
   7 our $AUTHORITY = 'cpan:STEVAN';
   8
   9 # the class marker when
  10 # serializing an object.
  11 our $CLASS_MARKER = '__CLASS__';
  12
  13 has 'storage' => (
  14     is      => 'ro',
  15     isa     => 'HashRef',
  16     default => sub {{}}
  17 );
  18
  19 has 'seen' => (
  20     is      => 'ro',
  21     isa     => 'HashRef[Int]', # int is the refaddr
  22     default => sub {{}}
  23 );
  24
  25 has 'object' => (is => 'rw', isa => 'Object');
  26 has 'class'  => (is => 'rw', isa => 'Str');
  27
  28 ## this is the API used by other modules ...
  29
  30 sub collapse_object {
  31     my ( $self, %options ) = @_;
  32
  33         # NOTE:
  34         # mark the root object as seen ...
  35         $self->seen->{refaddr $self->object} = undef;
  36
  37     $self->map_attributes('collapse_attribute', \%options);
  38     $self->storage->{$CLASS_MARKER} = $self->object->meta->identifier;
  39         return $self->storage;
  40 }
  41
  42 sub expand_object {
  43     my ($self, $data, %options) = @_;
  44
  45     $options{check_version}   = 1 unless exists $options{check_version};
  46     $options{check_authority} = 1 unless exists $options{check_authority};
  47
  48         # NOTE:
  49         # mark the root object as seen ...
  50         $self->seen->{refaddr $data} = undef;
  51
  52     $self->map_attributes('expand_attribute', $data, \%options);
  53         return $self->storage;
  54 }
  55
  56 ## this is the internal API ...
  57
  58 sub collapse_attribute {
  59     my ($self, $attr, $options)  = @_;
  60     my $value = $self->collapse_attribute_value($attr, $options);
  61     return if !defined($value);
  62     $self->storage->{$attr->name} = $value;
  63 }
  64
  65 sub expand_attribute {
  66     my ($self, $attr, $data, $options)  = @_;
  67     my $value = $self->expand_attribute_value($attr, $data->{$attr->name}, $options);
  68     $self->storage->{$attr->name} = defined $value ? $value : return;
  69 }
  70
  71 sub collapse_attribute_value {
  72     my ($self, $attr, $options)  = @_;
  73     # Faster, but breaks attributes without readers, do we care?
  74         #my $value = $attr->get_read_method_ref->($self->object);
  75         my $value = $attr->get_value($self->object);
  76
  77         # NOTE:
  78         # this might not be enough, we might
  79         # need to make it possible for the
  80         # cycle checker to return the value
  81     $self->check_for_cycle_in_collapse($attr, $value)
  82         if ref $value;
  83
  84     if (defined $value && $attr->has_type_constraint) {
  85         my $type_converter = $self->find_type_handler($attr->type_constraint);
  86         (defined $type_converter)
  87             || confess "Cannot convert " . $attr->type_constraint->name;
  88         $value = $type_converter->{collapse}->($value, $options);
  89     }
  90         return $value;
  91 }
  92
  93 sub expand_attribute_value {
  94     my ($self, $attr, $value, $options)  = @_;
  95
  96         # NOTE:
  97         # (see comment in method above ^^)
  98     $self->check_for_cycle_in_expansion($attr, $value)
  99         if ref $value;
 100
 101     if (defined $value && $attr->has_type_constraint) {
 102         my $type_converter = $self->find_type_handler($attr->type_constraint);
 103         $value = $type_converter->{expand}->($value, $options);
 104     }
 105         return $value;
 106 }
 107
 108 # NOTE:
 109 # possibly these two methods will
 110 # be used by a cycle supporting
 111 # engine. However, I am not sure
 112 # if I can make a cycle one work
 113 # anyway.
 114
 115 sub check_for_cycle_in_collapse {
 116     my ($self, $attr, $value) = @_;
 117     (!exists $self->seen->{refaddr $value})
 118         || confess "Basic Engine does not support cycles in class("
 119                  . ($attr->associated_class->name) . ").attr("
 120                  . ($attr->name) . ") with $value";
 121     $self->seen->{refaddr $value} = undef;
 122 }
 123
 124 sub check_for_cycle_in_expansion {
 125     my ($self, $attr, $value) = @_;
 126     (!exists $self->seen->{refaddr $value})
 127     || confess "Basic Engine does not support cycles in class("
 128              . ($attr->associated_class->name) . ").attr("
 129              . ($attr->name) . ") with $value";
 130     $self->seen->{refaddr $value} = undef;
 131 }
 132
 133 # util methods ...
 134
 135 sub map_attributes {
 136     my ($self, $method_name, @args) = @_;
 137
 138     # The $self->object check is here to differentiate a ->pack from a
 139     # ->unpack; ->object is only defined for a ->pack
 140
 141     # no checks needed if this is class based (ie, restore)
 142     unless( $self->object ) {
 143         return map { $self->$method_name($_, @args) }
 144             $self->class->meta->get_all_attributes;
 145     }
 146
 147     # if it's object based, it's a store -- in that case,
 148     # check thoroughly
 149     my @rv;
 150     my $o = $self->object;
 151     for my $attr ( $o->meta->get_all_attributes ) {
 152
 153         # Skip our special skip attribute :)
 154         next if $attr->does(
 155             'MooseX::Storage::Meta::Attribute::Trait::DoNotSerialize');
 156
 157         # If we're invoked with the 'OnlyWhenBuilt' trait, we should
 158         # only serialize the attribute if it's already built. So, go ahead
 159         # and check if the attribute has a predicate. If so, check if it's
 160         # set  and then go ahead and look it up.
 161         if( $o->does('MooseX::Storage::Traits::OnlyWhenBuilt') and
 162             my $pred = $attr->predicate
 163         ) {
 164             next unless $self->object->$pred;
 165         }
 166         push @rv, $self->$method_name($attr, @args);
 167     }
 168
 169     return @rv;
 170 }
 171
 172 ## ------------------------------------------------------------------
 173 ## This is all the type handler stuff, it is in a state of flux
 174 ## right now, so this may change, or it may just continue to be
 175 ## improved upon. Comments and suggestions are welcomed.
 176 ## ------------------------------------------------------------------
 177
 178 # NOTE:
 179 # these are needed by the
 180 # ArrayRef and HashRef handlers
 181 # below, so I need easy access
 182 my %OBJECT_HANDLERS = (
 183     expand => sub {
 184         my ($data, $options) = @_;
 185         (exists $data->{$CLASS_MARKER})
 186             || confess "Serialized item has no class marker";
 187         # check the class more thoroughly here ...
 188         my ($class, $version, $authority) = (split '-' => $data->{$CLASS_MARKER});
 189         my $meta = eval { $class->meta };
 190         confess "Class ($class) is not loaded, cannot unpack" if $@;
 191
 192         if ($options->{check_version}) {
 193             my $meta_version = $meta->version;
 194             if (defined $meta_version && $version) {
 195                 if ($options->{check_version} eq 'allow_less_than') {
 196                     ($meta_version <= $version)
 197                         || confess "Class ($class) versions is not less than currently available."
 198                                  . " got=($version) available=($meta_version)";
 199                 }
 200                 elsif ($options->{check_version} eq 'allow_greater_than') {
 201                     ($meta->version >= $version)
 202                         || confess "Class ($class) versions is not greater than currently available."
 203                                  . " got=($version) available=($meta_version)";
 204                 }
 205                 else {
 206                     ($meta->version == $version)
 207                         || confess "Class ($class) versions don't match."
 208                                  . " got=($version) available=($meta_version)";
 209                 }
 210             }
 211         }
 212
 213         if ($options->{check_authority}) {
 214             my $meta_authority = $meta->authority;
 215             ($meta->authority eq $authority)
 216                 || confess "Class ($class) authorities don't match."
 217                          . " got=($authority) available=($meta_authority)"
 218                 if defined $meta_authority && defined $authority;
 219         }
 220
 221         # all is well ...
 222         $class->unpack($data, %$options);
 223     },
 224     collapse => sub {
 225         my ( $obj, $options ) = @_;
 226 #        ($obj->can('does') && $obj->does('MooseX::Storage::Basic'))
 227 #            || confess "Bad object ($obj) does not do MooseX::Storage::Basic role";
 228         ($obj->can('pack'))
 229             || confess "Object ($obj) does not have a &pack method, cannot collapse";
 230         $obj->pack(%$options);
 231     },
 232 );
 233
 234
 235 my %TYPES = (
 236     # NOTE:
 237     # we need to make sure that we properly numify the numbers
 238     # before and after them being futzed with, because some of
 239     # the JSON engines are stupid/annoying/frustrating
 240     'Int'      => { expand => sub { $_[0] + 0 }, collapse => sub { $_[0] + 0 } },
 241     'Num'      => { expand => sub { $_[0] + 0 }, collapse => sub { $_[0] + 0 } },
 242     # These are boring ones, so they use the identity function ...
 243     'Str'      => { expand => sub { shift }, collapse => sub { shift } },
 244     'Bool'     => { expand => sub { shift }, collapse => sub { shift } },
 245     # These are the trickier ones, (see notes)
 246     # NOTE:
 247     # Because we are nice guys, we will check
 248     # your ArrayRef and/or HashRef one level
 249     # down and inflate any objects we find.
 250     # But this is where it ends, it is too
 251     # expensive to try and do this any more
 252     # recursively, when it is probably not
 253     # nessecary in most of the use cases.
 254     # However, if you need more then this, subtype
 255     # and add a custom handler.
 256     'ArrayRef' => {
 257         expand => sub {
 258             my ( $array, @args ) = @_;
 259             foreach my $i (0 .. $#{$array}) {
 260                 next unless ref($array->[$i]) eq 'HASH'
 261                          && exists $array->[$i]->{$CLASS_MARKER};
 262                 $array->[$i] = $OBJECT_HANDLERS{expand}->($array->[$i], @args);
 263             }
 264             $array;
 265         },
 266         collapse => sub {
 267             my ( $array, @args ) = @_;
 268             # NOTE:
 269             # we need to make a copy cause
 270             # otherwise it will affect the
 271             # other real version.
 272             [ map {
 273                 blessed($_)
 274                     ? $OBJECT_HANDLERS{collapse}->($_, @args)
 275                     : $_
 276             } @$array ]
 277         }
 278     },
 279     'HashRef'  => {
 280         expand   => sub {
 281             my ( $hash, @args ) = @_;
 282             foreach my $k (keys %$hash) {
 283                 next unless ref($hash->{$k}) eq 'HASH'
 284                          && exists $hash->{$k}->{$CLASS_MARKER};
 285                 $hash->{$k} = $OBJECT_HANDLERS{expand}->($hash->{$k}, @args);
 286             }
 287             $hash;
 288         },
 289         collapse => sub {
 290             my ( $hash, @args ) = @_;
 291             # NOTE:
 292             # we need to make a copy cause
 293             # otherwise it will affect the
 294             # other real version.
 295             +{ map {
 296                 blessed($hash->{$_})
 297                     ? ($_ => $OBJECT_HANDLERS{collapse}->($hash->{$_}, @args))
 298                     : ($_ => $hash->{$_})
 299             } keys %$hash }
 300         }
 301     },
 302     'Object'   => \%OBJECT_HANDLERS,
 303     # NOTE:
 304     # The sanity of enabling this feature by
 305     # default is very questionable.
 306     # - SL
 307     #'CodeRef' => {
 308     #    expand   => sub {}, # use eval ...
 309     #    collapse => sub {}, # use B::Deparse ...
 310     #}
 311 );
 312
 313 sub add_custom_type_handler {
 314     my ($class, $type_name, %handlers) = @_;
 315     (exists $handlers{expand} && exists $handlers{collapse})
 316         || confess "Custom type handlers need an expand *and* a collapse method";
 317     $TYPES{$type_name} = \%handlers;
 318 }
 319
 320 sub remove_custom_type_handler {
 321     my ($class, $type_name) = @_;
 322     delete $TYPES{$type_name} if exists $TYPES{$type_name};
 323 }
 324
 325 sub find_type_handler {
 326     my ($self, $type_constraint) = @_;
 327
 328     # check if the type is a Maybe and
 329     # if its parent is not parameterized.
 330     # If both is true recurse this method
 331     # using ->type_parameter.
 332     return $self->find_type_handler($type_constraint->type_parameter)
 333         if $type_constraint->parent eq 'Maybe'
 334           and not $type_constraint->parent->can('type_parameter');
 335
 336     # this should handle most type usages
 337     # since they they are usually just
 338     # the standard set of built-ins
 339     return $TYPES{$type_constraint->name}
 340         if exists $TYPES{$type_constraint->name};
 341
 342     # the next possibility is they are
 343     # a subtype of the built-in types,
 344     # in which case this will DWIM in
 345     # most cases. It is probably not
 346     # 100% ideal though, but until I
 347     # come up with a decent test case
 348     # it will do for now.
 349     foreach my $type (keys %TYPES) {
 350         return $TYPES{$type}
 351             if $type_constraint->is_subtype_of($type);
 352     }
 353
 354     # NOTE:
 355     # the reason the above will work has to
 356     # do with the fact that custom subtypes
 357     # are mostly used for validation of
 358     # the guts of a type, and not for some
 359     # weird structural thing which would
 360     # need to be accomidated by the serializer.
 361     # Of course, mst or phaylon will probably
 362     # do something to throw this assumption
 363     # totally out the door ;)
 364     # - SL
 365
 366     # NOTE:
 367     # if this method hasnt returned by now
 368     # then we have no been able to find a
 369     # type constraint handler to match
 370     confess "Cannot handle type constraint (" . $type_constraint->name . ")";
 371 }
 372
 373 sub find_type_handler_for {
 374     my ($self, $type_handler_name) = @_;
 375     $TYPES{$type_handler_name}
 376 }
 377
 378 1;
 379
 380 __END__
 381
 382 =pod
 383
 384 =head1 NAME
 385
 386 MooseX::Storage::Engine - The meta-engine to handle collapsing and expanding objects
 387
 388 =head1 DESCRIPTION
 389
 390 No user serviceable parts inside. If you really want to know, read the source :)
 391
 392 =head1 METHODS
 393
 394 =head2 Accessors
 395
 396 =over 4
 397
 398 =item B<class>
 399
 400 =item B<object>
 401
 402 =item B<storage>
 403
 404 =item B<seen>
 405
 406 =back
 407
 408 =head2 API
 409
 410 =over 4
 411
 412 =item B<expand_object>
 413
 414 =item B<collapse_object>
 415
 416 =back
 417
 418 =head2 ...
 419
 420 =over 4
 421
 422 =item B<collapse_attribute>
 423
 424 =item B<collapse_attribute_value>
 425
 426 =item B<expand_attribute>
 427
 428 =item B<expand_attribute_value>
 429
 430 =item B<check_for_cycle_in_collapse>
 431
 432 =item B<check_for_cycle_in_expansion>
 433
 434 =item B<map_attributes>
 435
 436 =back
 437
 438 =head2 Type Constraint Handlers
 439
 440 =over 4
 441
 442 =item B<find_type_handler ($type)>
 443
 444 =item B<find_type_handler_for ($name)>
 445
 446 =item B<add_custom_type_handler ($name, %handlers)>
 447
 448 =item B<remove_custom_type_handler ($name)>
 449
 450 =back
 451
 452 =head2 Introspection
 453
 454 =over 4
 455
 456 =item B<meta>
 457
 458 =back
 459
 460 =head1 BUGS
 461
 462 All complex software has bugs lurking in it, and this module is no
 463 exception. If you find a bug please either email me, or add the bug
 464 to cpan-RT.
 465
 466 =head1 AUTHOR
 467
 468 Chris Prather E<lt>chris.prather@iinteractive.comE<gt>
 469
 470 Stevan Little E<lt>stevan.little@iinteractive.comE<gt>
 471
 472 =head1 COPYRIGHT AND LICENSE
 473
 474 Copyright 2007-2008 by Infinity Interactive, Inc.
 475
 476 L<http://www.iinteractive.com>
 477
 478 This library is free software; you can redistribute it and/or modify
 479 it under the same terms as Perl itself.
 480
 481 =cut
 482
 483
 484