lib/MooseX/Storage/Deferred.pm

   1 package MooseX::Storage::Deferred;
   2 use Moose::Role;
   3
   4 with 'MooseX::Storage::Basic';
   5
   6 sub __get_method {
   7     my ( $self, $basename, $value, $method_name ) = @_;
   8
   9     my $role   = MooseX::Storage->_expand_role($basename => $value)->meta;
  10     my $method = $role->get_method($method_name)->body;
  11 }
  12
  13 sub thaw {
  14     my ( $class, $packed, $type, @args ) = @_;
  15
  16     (exists $type->{format})
  17         || confess "You must specify a format type to thaw from";
  18
  19     my $code = $class->__get_method(Format => $type->{format} => 'thaw');
  20
  21     $class->$code($packed, @args);
  22 }
  23
  24 sub freeze {
  25     my ( $self, $type, @args ) = @_;
  26
  27     (exists $type->{format})
  28         || confess "You must specify a format type to freeze into";
  29
  30     my $code = $self->__get_method(Format => $type->{format} => 'freeze');
  31
  32     $self->$code(@args);
  33 }
  34
  35 sub load {
  36     my ( $class, $filename, $type, @args ) = @_;
  37
  38     (exists $type->{io})
  39         || confess "You must specify an I/O type to load with";
  40
  41     my $code = $class->__get_method(IO => $type->{io} => 'load');
  42
  43     $class->$code($filename, $type, @args);
  44 }
  45
  46 sub store {
  47     my ( $self, $filename, $type, @args ) = @_;
  48
  49     (exists $type->{io})
  50         || confess "You must specify an I/O type to store with";
  51
  52     my $code = $self->__get_method(IO => $type->{io} => 'store');
  53
  54     $self->$code($filename, $type, @args);
  55 }
  56
  57 no Moose::Role;
  58
  59 1;
  60
  61 __END__
  62
  63 =pod
  64
  65 =head1 NAME
  66
  67 MooseX::Storage::Deferred - A role for undecisive programmers
  68
  69 =head1 SYNOPSIS
  70
  71   package Point;
  72   use Moose;
  73   use MooseX::Storage;
  74
  75   with 'MooseX::Storage::Deferred';
  76
  77   has 'x' => (is => 'rw', isa => 'Int');
  78   has 'y' => (is => 'rw', isa => 'Int');
  79
  80   1;
  81
  82   my $p = Point->new(x => 10, y => 10);
  83
  84   ## methods to freeze/thaw into
  85   ## a specified serialization format
  86   ## (in this case JSON)
  87
  88   # pack the class into a JSON string
  89   $p->freeze({ format => 'JSON' }); # { "__CLASS__" : "Point", "x" : 10, "y" : 10 }
  90
  91   # pack the class into a JSON string using parameterized JSONpm role
  92   $p->freeze({ format => [ JSONpm => { json_opts => { pretty => 1 } } ] });
  93
  94   # unpack the JSON string into a class
  95   my $p2 = Point->thaw(
  96       '{ "__CLASS__" : "Point", "x" : 10, "y" : 10 }',
  97       { format => 'JSON' }
  98   );
  99
 100 =head1 DESCRIPTION
 101
 102 This role is designed for those times when you need to
 103 serialize into many different formats or I/O options.
 104
 105 It basically allows you to choose the format and IO
 106 options only when you actually use them (see the
 107 SYNOPSIS for more info)
 108
 109 =head1 SUPPORTED FORMATS
 110
 111 =over 4
 112
 113 =item I<JSON>
 114
 115 =item I<JSONpm>
 116
 117 =item I<YAML>
 118
 119 =item I<Storable>
 120
 121 =back
 122
 123 =head1 SUPPORTED I/O
 124
 125 =over 4
 126
 127 =item I<File>
 128
 129 =item I<AtomicFile>
 130
 131 =back
 132
 133 B<NOTE:> The B<StorableFile> I/O option is not supported,
 134 this is because it does not mix well with options who also
 135 have a C<thaw> and C<freeze> methods like this. It is possible
 136 to probably work around this issue, but I don't currently
 137 have the need for it. If you need this supported, talk to me
 138 and I will see what I can do.
 139
 140 =head1 METHODS
 141
 142 =over 4
 143
 144 =item B<freeze ($type_desc)>
 145
 146 =item B<thaw ($data, $type_desc)>
 147
 148 =item B<load ($filename, $type_desc)>
 149
 150 =item B<store ($filename, $type_desc)>
 151
 152 =back
 153
 154 =head2 Introspection
 155
 156 =over 4
 157
 158 =item B<meta>
 159
 160 =back
 161
 162 =head1 BUGS
 163
 164 All complex software has bugs lurking in it, and this module is no
 165 exception. If you find a bug please either email me, or add the bug
 166 to cpan-RT.
 167
 168 =head1 AUTHOR
 169
 170 Stevan Little E<lt>stevan.little@iinteractive.comE<gt>
 171
 172 =head1 COPYRIGHT AND LICENSE
 173
 174 Copyright 2007-2008 by Infinity Interactive, Inc.
 175
 176 L<http://www.iinteractive.com>
 177
 178 This library is free software; you can redistribute it and/or modify
 179 it under the same terms as Perl itself.
 180
 181 =cut