lib/MooseX/Storage.pm

   1
   2 package MooseX::Storage;
   3 use Moose qw(confess);
   4
   5 use MooseX::Storage::Meta::Attribute::DoNotSerialize;
   6
   7 our $VERSION = '0.02';
   8
   9 sub import {
  10     my $pkg = caller();
  11
  12     return if $pkg eq 'main';
  13
  14     ($pkg->can('meta'))
  15         || confess "This package can only be used in Moose based classes";
  16
  17     $pkg->meta->alias_method('Storage' => sub {
  18         my %params = @_;
  19
  20         $params{'base'} ||= 'Basic';
  21
  22         my @roles = (
  23             ('MooseX::Storage::' . $params{'base'}),
  24         );
  25
  26         # NOTE:
  27         # you don't have to have a format
  28         # role, this just means you dont
  29         # get anything other than pack/unpack
  30         push @roles => 'MooseX::Storage::Format::' . $params{'format'}
  31             if exists $params{'format'};
  32
  33         # NOTE:
  34         # if you do choose an IO role, then
  35         # you *must* have a format role chosen
  36         # since load/store require freeze/thaw
  37         if (exists $params{'io'}) {
  38             (exists $params{'format'})
  39                 || confess "You must specify a format role in order to use an IO role";
  40             push @roles => 'MooseX::Storage::IO::' . $params{'io'};
  41         }
  42
  43         Class::MOP::load_class($_)
  44             || die "Could not load role (" . $_ . ") for package ($pkg)"
  45                 foreach @roles;
  46
  47         return @roles;
  48     });
  49 }
  50
  51 1;
  52
  53 __END__
  54
  55 =pod
  56
  57 =head1 NAME
  58
  59 MooseX::Storage - An serialization framework for Moose classes
  60
  61 =head1 SYNOPSIS
  62
  63   package Point;
  64   use Moose;
  65   use MooseX::Storage;
  66
  67   with Storage('format' => 'JSON', 'io' => 'File');
  68
  69   has 'x' => (is => 'rw', isa => 'Int');
  70   has 'y' => (is => 'rw', isa => 'Int');
  71
  72   1;
  73
  74   my $p = Point->new(x => 10, y => 10);
  75
  76   ## methods to pack/unpack an
  77   ## object in perl data structures
  78
  79   # pack the class into a hash
  80   $p->pack(); # { __CLASS__ => 'Point', x => 10, y => 10 }
  81
  82   # unpack the hash into a class
  83   my $p2 = Point->unpack({ __CLASS__ => 'Point', x => 10, y => 10 });
  84
  85   ## methods to freeze/thaw into
  86   ## a specified serialization format
  87   ## (in this case JSON)
  88
  89   # pack the class into a JSON string
  90   $p->freeze(); # { "__CLASS__" : "Point", "x" : 10, "y" : 10 }
  91
  92   # unpack the JSON string into a class
  93   my $p2 = Point->thaw('{ "__CLASS__" : "Point", "x" : 10, "y" : 10 }');
  94
  95   ## methods to load/store a class
  96   ## on the file system
  97
  98   $p->store('my_point.json');
  99
 100   my $p2 = Point->load('my_point.json');
 101
 102 =head1 DESCRIPTION
 103
 104 MooseX::Storage is a serialization framework for Moose, it provides
 105 a very flexible and highly pluggable way to serialize Moose classes
 106 to a number of different formats and styles.
 107
 108 =head2 Important Note
 109
 110 This is still an early release of this module, so use with caution.
 111 It's outward facing serialization API should be considered stable,
 112 but I still reserve the right to make tweaks if I need too. Anything
 113 beyond the basic pack/unpack, freeze/thaw and load/store should not
 114 be relied on.
 115
 116 =head2 Levels of Serialization
 117
 118 There are 3 levels to the serialization, each of which builds upon
 119 the other and each of which can be customized to the specific needs
 120 of your class.
 121
 122 =over 4
 123
 124 =item B<base>
 125
 126 The first (base) level is C<pack> and C<unpack>. In this level the
 127 class is serialized into a Perl HASH reference, it is tagged with the
 128 class name and each instance attribute is stored. Very simple.
 129
 130 This level is not optional, it is the bare minumum that
 131 MooseX::Storage provides and all other levels build on top of this.
 132
 133 =item B<format>
 134
 135 The second (format) level is C<freeze> and C<thaw>. In this level the
 136 output of C<pack> is sent to C<freeze> or the output of C<thaw> is sent
 137 to C<unpack>. This levels primary role is to convert to and from the
 138 specific serialization format and Perl land.
 139
 140 This level is optional, if you don't want/need it, you don't have to
 141 have it. You can just use C<pack>/C<unpack> instead.
 142
 143 =item B<io>
 144
 145 The third (io) level is C<load> and C<store>. In this level we are reading
 146 and writing data to file/network/database/etc.
 147
 148 This level is also optional, it does however require the C<format> level
 149 to be present (at least the current state does).
 150
 151 =back
 152
 153 =head2 How we serialize
 154
 155 There are always limits to any serialization framework, there are just
 156 some things which are really difficult to serialize properly and some
 157 things which cannot be serialized at all.
 158
 159 =head2 What can be serialized?
 160
 161 Currently only numbers, string, ARRAY refs, HASH refs and other
 162 MooseX::Storage enabled objects are supported.
 163
 164 With Array and Hash references the first level down is inspected and
 165 any objects found are serialized/deserialized for you. We do not do
 166 this recusively by default, however this feature may become an
 167 option eventually.
 168
 169 The specific serialize/deserialize routine is determined by the
 170 Moose type constraint a specific attribute has. In most cases subtypes
 171 of the supported types are handled correctly, and there is a facility
 172 for adding handlers for custom types as well. This will get documented
 173 eventually, but it is currently still in development.
 174
 175 =head2 What can not be serialized?
 176
 177 We do not support CODE references yet, but this support might be added
 178 in using B::Deparse or some other deep magic.
 179
 180 Scalar refs are not supported, mostly because there is no way to know
 181 if the value being referenced will be there when the object is inflated.
 182 I highly doubt will be ever support this in a general sense, but it
 183 would be possible to add this yourself for a small specific case.
 184
 185 Circular references are specifically disallowed, however if you break
 186 the cycles yourself then re-assemble them later you can get around this.
 187 The reason we disallow circular refs is because they are not always supported
 188 in all formats we use, and they tend to be very tricky to do for all
 189 possible cases. It is almost always something you want to have tight control
 190 over anyway.
 191
 192 =head1 CAVEAT
 193
 194 This is B<not> a persistence framework, changes to your object after
 195 you load or store it will not be reflected in the stored class.
 196
 197 =head1 EXPORTS
 198
 199 =over 4
 200
 201 =item B<Storage (%options)>
 202
 203 This module will export the C<Storage> method will can be used to
 204 load a specific set of MooseX::Storage roles to implement a specific
 205 combination of features. It is meant to make things easier, but it
 206 is by no means the only way. You can still compose your roles by
 207 hand if you like.
 208
 209 =back
 210
 211 =head1 METHODS
 212
 213 =over 4
 214
 215 =item B<import>
 216
 217 =back
 218
 219 =head2 Introspection
 220
 221 =over 4
 222
 223 =item B<meta>
 224
 225 =back
 226
 227 =head1 TODO
 228
 229 This module needs docs and probably a Cookbook of some kind as well.
 230 This is an early release, so that is my excuse for now :)
 231
 232 For the time being, please read the tests and feel free to email me
 233 if you have any questions. This module can also be discussed on IRC
 234 in the #moose channel on irc.perl.org.
 235
 236 =head1 BUGS
 237
 238 All complex software has bugs lurking in it, and this module is no
 239 exception. If you find a bug please either email me, or add the bug
 240 to cpan-RT.
 241
 242 =head1 AUTHOR
 243
 244 Chris Prather E<lt>chris.prather@iinteractive.comE<gt>
 245
 246 Stevan Little E<lt>stevan.little@iinteractive.comE<gt>
 247
 248 =head1 COPYRIGHT AND LICENSE
 249
 250 Copyright 2007 by Infinity Interactive, Inc.
 251
 252 L<http://www.iinteractive.com>
 253
 254 This library is free software; you can redistribute it and/or modify
 255 it under the same terms as Perl itself.
 256
 257 =cut