[gitmo/MooseX-Storage.git] / lib / MooseX / Storage / Engine.pm


package MooseX::Storage::Engine;
use Moose;
use Scalar::Util qw(refaddr);

our $VERSION   = '0.18';
our $AUTHORITY = 'cpan:STEVAN';

# the class marker when 
# serializing an object. 
our $CLASS_MARKER = '__CLASS__';

has 'storage' => (
    is      => 'ro',
    isa     => 'HashRef',
    default => sub {{}}
);

has 'seen' => (
    is      => 'ro',
    isa     => 'HashRef[Int]', # int is the refaddr
    default => sub {{}}
);

has 'object' => (is => 'rw', isa => 'Object');
has 'class'  => (is => 'rw', isa => 'Str');

## this is the API used by other modules ...

sub collapse_object {
    my ( $self, %options ) = @_;

	# NOTE:
	# mark the root object as seen ...
	$self->seen->{refaddr $self->object} = undef;
	
    $self->map_attributes('collapse_attribute', \%options);
    $self->storage->{$CLASS_MARKER} = $self->object->meta->identifier;    
	return $self->storage;
}

sub expand_object {
    my ($self, $data, %options) = @_;
    
    $options{check_version}       = 1 unless exists $options{check_version};
    $options{check_authority}     = 1 unless exists $options{check_authority};   

	# NOTE:
	# mark the root object as seen ...
	$self->seen->{refaddr $data} = undef;    
    
    $self->map_attributes('expand_attribute', $data, \%options);
	return $self->storage;    
}

## this is the internal API ...

sub collapse_attribute {
    my ($self, $attr, $options)  = @_;
    my $value = $self->collapse_attribute_value($attr, $options);
    return if !defined($value);
    $self->storage->{$attr->name} = $value;
}

sub expand_attribute {
    my ($self, $attr, $data, $options)  = @_;
    my $value = $self->expand_attribute_value($attr, $data->{$attr->name}, $options);
    $self->storage->{$attr->name} = defined $value ? $value : return;
}

sub collapse_attribute_value {
    my ($self, $attr, $options)  = @_;
    # Faster, but breaks attributes without readers, do we care?
	#my $value = $attr->get_read_method_ref->($self->object);
	my $value = $attr->get_value($self->object);

	# NOTE:
	# this might not be enough, we might
	# need to make it possible for the
	# cycle checker to return the value
	# Check cycles unless explicitly disabled
    if( ref $value and not(
        $options->{disable_cycle_check} or
        $self->object->does('MooseX::Storage::Traits::DisableCycleDetection')
    )) {        
        $self->check_for_cycle_in_collapse($attr, $value)
    }

    if (defined $value && $attr->has_type_constraint) {
        my $type_converter = $self->find_type_handler($attr->type_constraint);
        (defined $type_converter)
            || confess "Cannot convert " . $attr->type_constraint->name;
        $value = $type_converter->{collapse}->($value, $options);
    }
	return $value;
}

sub expand_attribute_value {
    my ($self, $attr, $value, $options)  = @_;

	# NOTE:
	# (see comment in method above ^^)
    if( ref $value and not(
        $options->{disable_cycle_check} or
        $self->class->does('MooseX::Storage::Traits::DisableCycleDetection')
    )) {        
        $self->check_for_cycle_in_collapse($attr, $value)
    }
    
    if (defined $value && $attr->has_type_constraint) {
        my $type_converter = $self->find_type_handler($attr->type_constraint);
        $value = $type_converter->{expand}->($value, $options);
    }
	return $value;
}

# NOTE:
# possibly these two methods will 
# be used by a cycle supporting 
# engine. However, I am not sure 
# if I can make a cycle one work 
# anyway.

sub check_for_cycle_in_collapse {
    my ($self, $attr, $value) = @_;
    (!exists $self->seen->{refaddr $value})
        || confess "Basic Engine does not support cycles in class(" 
                 . ($attr->associated_class->name) . ").attr("
                 . ($attr->name) . ") with $value";
    $self->seen->{refaddr $value} = undef;
}

sub check_for_cycle_in_expansion {
    my ($self, $attr, $value) = @_;
    (!exists $self->seen->{refaddr $value})
    || confess "Basic Engine does not support cycles in class(" 
             . ($attr->associated_class->name) . ").attr("
             . ($attr->name) . ") with $value";
    $self->seen->{refaddr $value} = undef;
}

# util methods ...

sub map_attributes {
    my ($self, $method_name, @args) = @_;
 
    # The $self->object check is here to differentiate a ->pack from a 
    # ->unpack; ->object is only defined for a ->pack
 
    # no checks needed if this is class based (ie, restore)
    unless( $self->object ) {
        return map { $self->$method_name($_, @args) }
            $self->class->meta->get_all_attributes;
    }
    
    # if it's object based, it's a store -- in that case, 
    # check thoroughly
    my @rv;
    my $o = $self->object;
    for my $attr ( $o->meta->get_all_attributes ) {    
        
        # Skip our special skip attribute :)
        next if $attr->does(
            'MooseX::Storage::Meta::Attribute::Trait::DoNotSerialize');

        # If we're invoked with the 'OnlyWhenBuilt' trait, we should
        # only serialize the attribute if it's already built. So, go ahead
        # and check if the attribute has a predicate. If so, check if it's 
        # set  and then go ahead and look it up.
        if( $o->does('MooseX::Storage::Traits::OnlyWhenBuilt') and 
            my $pred = $attr->predicate 
        ) { 
            next unless $self->object->$pred; 
        }         
        push @rv, $self->$method_name($attr, @args);
    } 

    return @rv;
}

## ------------------------------------------------------------------
## This is all the type handler stuff, it is in a state of flux
## right now, so this may change, or it may just continue to be 
## improved upon. Comments and suggestions are welcomed.
## ------------------------------------------------------------------

# NOTE:
# these are needed by the 
# ArrayRef and HashRef handlers
# below, so I need easy access 
my %OBJECT_HANDLERS = (
    expand => sub {
        my ($data, $options) = @_;   
        (exists $data->{$CLASS_MARKER})
            || confess "Serialized item has no class marker";
        # check the class more thoroughly here ...
        my ($class, $version, $authority) = (split '-' => $data->{$CLASS_MARKER});
        my $meta = eval { $class->meta };
        confess "Class ($class) is not loaded, cannot unpack" if $@;     
        
        if ($options->{check_version}) {
            my $meta_version = $meta->version;
            if (defined $meta_version && $version) {            
                if ($options->{check_version} eq 'allow_less_than') {
                    ($meta_version <= $version)
                        || confess "Class ($class) versions is not less than currently available." 
                                 . " got=($version) available=($meta_version)";                
                }
                elsif ($options->{check_version} eq 'allow_greater_than') {
                    ($meta->version >= $version)
                        || confess "Class ($class) versions is not greater than currently available." 
                                 . " got=($version) available=($meta_version)";                
                }            
                else {
                    ($meta->version == $version)
                        || confess "Class ($class) versions don't match." 
                                 . " got=($version) available=($meta_version)";
                }
            }
        }
        
        if ($options->{check_authority}) {
            my $meta_authority = $meta->authority;
            ($meta->authority eq $authority)
                || confess "Class ($class) authorities don't match." 
                         . " got=($authority) available=($meta_authority)"
                if defined $meta_authority && defined $authority;            
        }
            
        # all is well ...
        $class->unpack($data, %$options);
    },
    collapse => sub {
        my ( $obj, $options ) = @_;
#        ($obj->can('does') && $obj->does('MooseX::Storage::Basic'))
#            || confess "Bad object ($obj) does not do MooseX::Storage::Basic role";
        ($obj->can('pack'))
            || confess "Object ($obj) does not have a &pack method, cannot collapse";
        $obj->pack(%$options);
    },
);


my %TYPES = (
    # NOTE:
    # we need to make sure that we properly numify the numbers 
    # before and after them being futzed with, because some of 
    # the JSON engines are stupid/annoying/frustrating
    'Int'      => { expand => sub { $_[0] + 0 }, collapse => sub { $_[0] + 0 } },
    'Num'      => { expand => sub { $_[0] + 0 }, collapse => sub { $_[0] + 0 } },
    # These are boring ones, so they use the identity function ...    
    'Str'      => { expand => sub { shift }, collapse => sub { shift } },
    'Bool'     => { expand => sub { shift }, collapse => sub { shift } },
    # These are the trickier ones, (see notes)
    # NOTE:
    # Because we are nice guys, we will check 
    # your ArrayRef and/or HashRef one level 
    # down and inflate any objects we find. 
    # But this is where it ends, it is too
    # expensive to try and do this any more  
    # recursively, when it is probably not 
    # nessecary in most of the use cases.
    # However, if you need more then this, subtype 
    # and add a custom handler.    
    'ArrayRef' => { 
        expand => sub {
            my ( $array, @args ) = @_;
            foreach my $i (0 .. $#{$array}) {
                next unless ref($array->[$i]) eq 'HASH' 
                         && exists $array->[$i]->{$CLASS_MARKER};
                $array->[$i] = $OBJECT_HANDLERS{expand}->($array->[$i], @args);
            }
            $array;
        }, 
        collapse => sub {
            my ( $array, @args ) = @_;
            # NOTE:         
            # we need to make a copy cause
            # otherwise it will affect the 
            # other real version.
            [ map {
                blessed($_)
                    ? $OBJECT_HANDLERS{collapse}->($_, @args)
                    : $_
            } @$array ] 
        } 
    },
    'HashRef'  => { 
        expand   => sub {
            my ( $hash, @args ) = @_;
            foreach my $k (keys %$hash) {
                next unless ref($hash->{$k}) eq 'HASH' 
                         && exists $hash->{$k}->{$CLASS_MARKER};
                $hash->{$k} = $OBJECT_HANDLERS{expand}->($hash->{$k}, @args);
            }
            $hash;            
        }, 
        collapse => sub {
            my ( $hash, @args ) = @_;
            # NOTE:         
            # we need to make a copy cause
            # otherwise it will affect the 
            # other real version.
            +{ map {
                blessed($hash->{$_})
                    ? ($_ => $OBJECT_HANDLERS{collapse}->($hash->{$_}, @args))
                    : ($_ => $hash->{$_})
            } keys %$hash }            
        } 
    },
    'Object'   => \%OBJECT_HANDLERS,
    # NOTE:
    # The sanity of enabling this feature by 
    # default is very questionable.
    # - SL
    #'CodeRef' => {
    #    expand   => sub {}, # use eval ...
    #    collapse => sub {}, # use B::Deparse ...        
    #} 
);

sub add_custom_type_handler {
    my ($class, $type_name, %handlers) = @_;
    (exists $handlers{expand} && exists $handlers{collapse})
        || confess "Custom type handlers need an expand *and* a collapse method";
    $TYPES{$type_name} = \%handlers;
}

sub remove_custom_type_handler {
    my ($class, $type_name) = @_;
    delete $TYPES{$type_name} if exists $TYPES{$type_name};
}

sub find_type_handler {
    my ($self, $type_constraint) = @_;
    
    # check if the type is a Maybe and
    # if its parent is not parameterized.
    # If both is true recurse this method
    # using ->type_parameter.
    return $self->find_type_handler($type_constraint->type_parameter)
        if $type_constraint->parent eq 'Maybe'
          and not $type_constraint->parent->can('type_parameter');

    # this should handle most type usages
    # since they they are usually just 
    # the standard set of built-ins
    return $TYPES{$type_constraint->name} 
        if exists $TYPES{$type_constraint->name};
      
    # the next possibility is they are 
    # a subtype of the built-in types, 
    # in which case this will DWIM in 
    # most cases. It is probably not 
    # 100% ideal though, but until I 
    # come up with a decent test case 
    # it will do for now.
    foreach my $type (keys %TYPES) {
        return $TYPES{$type} 
            if $type_constraint->is_subtype_of($type);
    }
    
    # NOTE:
    # the reason the above will work has to 
    # do with the fact that custom subtypes
    # are mostly used for validation of 
    # the guts of a type, and not for some
    # weird structural thing which would 
    # need to be accomidated by the serializer.
    # Of course, mst or phaylon will probably  
    # do something to throw this assumption 
    # totally out the door ;)
    # - SL
    
    # NOTE:
    # if this method hasnt returned by now
    # then we have no been able to find a 
    # type constraint handler to match 
    confess "Cannot handle type constraint (" . $type_constraint->name . ")";    
}

sub find_type_handler_for {
    my ($self, $type_handler_name) = @_;
    $TYPES{$type_handler_name}
}

1;

__END__

=pod

=head1 NAME

MooseX::Storage::Engine - The meta-engine to handle collapsing and expanding objects

=head1 DESCRIPTION

No user serviceable parts inside. If you really want to know, read the source :)

=head1 METHODS

=head2 Accessors

=over 4

=item B<class>

=item B<object>

=item B<storage>

=item B<seen>

=back

=head2 API

=over 4

=item B<expand_object>

=item B<collapse_object>

=back

=head2 ...

=over 4

=item B<collapse_attribute>

=item B<collapse_attribute_value>

=item B<expand_attribute>

=item B<expand_attribute_value>

=item B<check_for_cycle_in_collapse>

=item B<check_for_cycle_in_expansion>

=item B<map_attributes>

=back

=head2 Type Constraint Handlers

=over 4

=item B<find_type_handler ($type)>

=item B<find_type_handler_for ($name)>

=item B<add_custom_type_handler ($name, %handlers)>

=item B<remove_custom_type_handler ($name)>

=back

=head2 Introspection

=over 4

=item B<meta>

=back

=head1 BUGS

All complex software has bugs lurking in it, and this module is no 
exception. If you find a bug please either email me, or add the bug
to cpan-RT.

=head1 AUTHOR

Chris Prather E<lt>chris.prather@iinteractive.comE<gt>

Stevan Little E<lt>stevan.little@iinteractive.comE<gt>

=head1 COPYRIGHT AND LICENSE

Copyright 2007-2008 by Infinity Interactive, Inc.

L<http://www.iinteractive.com>

This library is free software; you can redistribute it and/or modify
it under the same terms as Perl itself.

=cut
Commit	Line	Data
e59193fb	1
	2	package MooseX::Storage::Engine;
	3	use Moose;
ec73712a	4	use Scalar::Util qw(refaddr);
e59193fb	5
5ca52230	6	our $VERSION = '0.18';
69b45b7d	7	our $AUTHORITY = 'cpan:STEVAN';
ba5bba75	8
	9	# the class marker when
	10	# serializing an object.
	11	our $CLASS_MARKER = '__CLASS__';
	12
e59193fb	13	has 'storage' => (
7eb5dc63	14	is => 'ro',
	15	isa => 'HashRef',
	16	default => sub {{}}
	17	);
	18
	19	has 'seen' => (
	20	is => 'ro',
ec73712a	21	isa => 'HashRef[Int]', # int is the refaddr
e59193fb	22	default => sub {{}}
	23	);
	24
e9739624	25	has 'object' => (is => 'rw', isa => 'Object');
e9739624	26	has 'class' => (is => 'rw', isa => 'Str');
e59193fb	27
e9739624	28	## this is the API used by other modules ...
e59193fb	29
e59193fb	30	sub collapse_object {
34dcaa5d	31	my ( $self, %options ) = @_;
7eb5dc63	32
	33	# NOTE:
	34	# mark the root object as seen ...
ec73712a	35	$self->seen->{refaddr $self->object} = undef;
7eb5dc63	36
34dcaa5d	37	$self->map_attributes('collapse_attribute', \%options);
c1830046	38	$self->storage->{$CLASS_MARKER} = $self->object->meta->identifier;
e59193fb	39	return $self->storage;
	40	}
	41
e9739624	42	sub expand_object {
219c1cc5	43	my ($self, $data, %options) = @_;
219c1cc5	44
5b7ea1fd	45	$options{check_version} = 1 unless exists $options{check_version};
	46	$options{check_authority} = 1 unless exists $options{check_authority};
	47
7eb5dc63	48	# NOTE:
7eb5dc63	49	# mark the root object as seen ...
ec73712a	50	$self->seen->{refaddr $data} = undef;
7eb5dc63	51
219c1cc5	52	$self->map_attributes('expand_attribute', $data, \%options);
e9739624	53	return $self->storage;
e59193fb	54	}
e59193fb	55
e9739624	56	## this is the internal API ...
	57
	58	sub collapse_attribute {
f6e1331f	59	my ($self, $attr, $options) = @_;
eea0dfae	60	my $value = $self->collapse_attribute_value($attr, $options);
	61	return if !defined($value);
	62	$self->storage->{$attr->name} = $value;
e9739624	63	}
	64
	65	sub expand_attribute {
219c1cc5	66	my ($self, $attr, $data, $options) = @_;
14b0a4dc	67	my $value = $self->expand_attribute_value($attr, $data->{$attr->name}, $options);
14b0a4dc	68	$self->storage->{$attr->name} = defined $value ? $value : return;
e59193fb	69	}
e59193fb	70
e9739624	71	sub collapse_attribute_value {
f6e1331f	72	my ($self, $attr, $options) = @_;
f4ffa4ef	73	# Faster, but breaks attributes without readers, do we care?
f4ffa4ef	74	#my $value = $attr->get_read_method_ref->($self->object);
e9739624	75	my $value = $attr->get_value($self->object);
f4ffa4ef	76
b430caa3	77	# NOTE:
f4ffa4ef	78	# this might not be enough, we might
f4ffa4ef	79	# need to make it possible for the
b430caa3	80	# cycle checker to return the value
5b7ea1fd	81	# Check cycles unless explicitly disabled
	82	if( ref $value and not(
	83	$options->{disable_cycle_check} or
	84	$self->object->does('MooseX::Storage::Traits::DisableCycleDetection')
	85	)) {
	86	$self->check_for_cycle_in_collapse($attr, $value)
	87	}
f4ffa4ef	88
e9739624	89	if (defined $value && $attr->has_type_constraint) {
3db8f791	90	my $type_converter = $self->find_type_handler($attr->type_constraint);
e9739624	91	(defined $type_converter)
e9739624	92	\|\| confess "Cannot convert " . $attr->type_constraint->name;
f6e1331f	93	$value = $type_converter->{collapse}->($value, $options);
e9739624	94	}
	95	return $value;
	96	}
	97
	98	sub expand_attribute_value {
219c1cc5	99	my ($self, $attr, $value, $options) = @_;
7eb5dc63	100
b430caa3	101	# NOTE:
b430caa3	102	# (see comment in method above ^^)
5b7ea1fd	103	if( ref $value and not(
	104	$options->{disable_cycle_check} or
	105	$self->class->does('MooseX::Storage::Traits::DisableCycleDetection')
	106	)) {
	107	$self->check_for_cycle_in_collapse($attr, $value)
	108	}
7eb5dc63	109
e9739624	110	if (defined $value && $attr->has_type_constraint) {
3db8f791	111	my $type_converter = $self->find_type_handler($attr->type_constraint);
219c1cc5	112	$value = $type_converter->{expand}->($value, $options);
e9739624	113	}
	114	return $value;
	115	}
	116
b430caa3	117	# NOTE:
	118	# possibly these two methods will
	119	# be used by a cycle supporting
	120	# engine. However, I am not sure
	121	# if I can make a cycle one work
	122	# anyway.
e9739624	123
7eb5dc63	124	sub check_for_cycle_in_collapse {
45d9a73c	125	my ($self, $attr, $value) = @_;
ec73712a	126	(!exists $self->seen->{refaddr $value})
45d9a73c	127	\|\| confess "Basic Engine does not support cycles in class("
c1830046	128	. ($attr->associated_class->name) . ").attr("
45d9a73c	129	. ($attr->name) . ") with $value";
ec73712a	130	$self->seen->{refaddr $value} = undef;
7eb5dc63	131	}
	132
	133	sub check_for_cycle_in_expansion {
45d9a73c	134	my ($self, $attr, $value) = @_;
ec73712a	135	(!exists $self->seen->{refaddr $value})
45d9a73c	136	\|\| confess "Basic Engine does not support cycles in class("
c1830046	137	. ($attr->associated_class->name) . ").attr("
45d9a73c	138	. ($attr->name) . ") with $value";
ec73712a	139	$self->seen->{refaddr $value} = undef;
7eb5dc63	140	}
7eb5dc63	141
b430caa3	142	# util methods ...
b430caa3	143
e9739624	144	sub map_attributes {
e9739624	145	my ($self, $method_name, @args) = @_;
186d680b	146
	147	# The $self->object check is here to differentiate a ->pack from a
	148	# ->unpack; ->object is only defined for a ->pack
	149
	150	# no checks needed if this is class based (ie, restore)
	151	unless( $self->object ) {
	152	return map { $self->$method_name($_, @args) }
	153	$self->class->meta->get_all_attributes;
	154	}
	155
	156	# if it's object based, it's a store -- in that case,
	157	# check thoroughly
	158	my @rv;
	159	my $o = $self->object;
	160	for my $attr ( $o->meta->get_all_attributes ) {
	161
b430caa3	162	# Skip our special skip attribute :)
186d680b	163	next if $attr->does(
	164	'MooseX::Storage::Meta::Attribute::Trait::DoNotSerialize');
	165
76218b46	166	# If we're invoked with the 'OnlyWhenBuilt' trait, we should
76218b46	167	# only serialize the attribute if it's already built. So, go ahead
186d680b	168	# and check if the attribute has a predicate. If so, check if it's
	169	# set and then go ahead and look it up.
	170	if( $o->does('MooseX::Storage::Traits::OnlyWhenBuilt') and
	171	my $pred = $attr->predicate
	172	) {
	173	next unless $self->object->$pred;
	174	}
	175	push @rv, $self->$method_name($attr, @args);
	176	}
	177
	178	return @rv;
e59193fb	179	}
e59193fb	180
913d96dd	181	## ------------------------------------------------------------------
3db8f791	182	## This is all the type handler stuff, it is in a state of flux
	183	## right now, so this may change, or it may just continue to be
	184	## improved upon. Comments and suggestions are welcomed.
913d96dd	185	## ------------------------------------------------------------------
	186
	187	# NOTE:
	188	# these are needed by the
	189	# ArrayRef and HashRef handlers
	190	# below, so I need easy access
	191	my %OBJECT_HANDLERS = (
	192	expand => sub {
219c1cc5	193	my ($data, $options) = @_;
ba5bba75	194	(exists $data->{$CLASS_MARKER})
913d96dd	195	\|\| confess "Serialized item has no class marker";
c1830046	196	# check the class more thoroughly here ...
	197	my ($class, $version, $authority) = (split '-' => $data->{$CLASS_MARKER});
	198	my $meta = eval { $class->meta };
219c1cc5	199	confess "Class ($class) is not loaded, cannot unpack" if $@;
	200
	201	if ($options->{check_version}) {
	202	my $meta_version = $meta->version;
	203	if (defined $meta_version && $version) {
	204	if ($options->{check_version} eq 'allow_less_than') {
	205	($meta_version <= $version)
	206	\|\| confess "Class ($class) versions is not less than currently available."
	207	. " got=($version) available=($meta_version)";
	208	}
	209	elsif ($options->{check_version} eq 'allow_greater_than') {
	210	($meta->version >= $version)
	211	\|\| confess "Class ($class) versions is not greater than currently available."
	212	. " got=($version) available=($meta_version)";
	213	}
	214	else {
	215	($meta->version == $version)
	216	\|\| confess "Class ($class) versions don't match."
	217	. " got=($version) available=($meta_version)";
	218	}
	219	}
	220	}
	221
	222	if ($options->{check_authority}) {
	223	my $meta_authority = $meta->authority;
	224	($meta->authority eq $authority)
	225	\|\| confess "Class ($class) authorities don't match."
	226	. " got=($authority) available=($meta_authority)"
	227	if defined $meta_authority && defined $authority;
	228	}
	229
c1830046	230	# all is well ...
34dcaa5d	231	$class->unpack($data, %$options);
913d96dd	232	},
913d96dd	233	collapse => sub {
34dcaa5d	234	my ( $obj, $options ) = @_;
c4a322ec	235	# ($obj->can('does') && $obj->does('MooseX::Storage::Basic'))
c4a322ec	236	# \|\| confess "Bad object ($obj) does not do MooseX::Storage::Basic role";
1c6ac775	237	($obj->can('pack'))
3defafb9	238	\|\| confess "Object ($obj) does not have a &pack method, cannot collapse";
34dcaa5d	239	$obj->pack(%$options);
913d96dd	240	},
	241	);
	242
	243
e59193fb	244	my %TYPES = (
cfee09ad	245	# NOTE:
	246	# we need to make sure that we properly numify the numbers
	247	# before and after them being futzed with, because some of
	248	# the JSON engines are stupid/annoying/frustrating
	249	'Int' => { expand => sub { $_[0] + 0 }, collapse => sub { $_[0] + 0 } },
	250	'Num' => { expand => sub { $_[0] + 0 }, collapse => sub { $_[0] + 0 } },
	251	# These are boring ones, so they use the identity function ...
e9739624	252	'Str' => { expand => sub { shift }, collapse => sub { shift } },
d691721b	253	'Bool' => { expand => sub { shift }, collapse => sub { shift } },
3db8f791	254	# These are the trickier ones, (see notes)
	255	# NOTE:
	256	# Because we are nice guys, we will check
	257	# your ArrayRef and/or HashRef one level
	258	# down and inflate any objects we find.
	259	# But this is where it ends, it is too
	260	# expensive to try and do this any more
	261	# recursively, when it is probably not
	262	# nessecary in most of the use cases.
	263	# However, if you need more then this, subtype
	264	# and add a custom handler.
913d96dd	265	'ArrayRef' => {
e9739624	266	expand => sub {
34dcaa5d	267	my ( $array, @args ) = @_;
913d96dd	268	foreach my $i (0 .. $#{$array}) {
913d96dd	269	next unless ref($array->[$i]) eq 'HASH'
ba5bba75	270	&& exists $array->[$i]->{$CLASS_MARKER};
34dcaa5d	271	$array->[$i] = $OBJECT_HANDLERS{expand}->($array->[$i], @args);
913d96dd	272	}
	273	$array;
	274	},
34dcaa5d	275	collapse => sub {
34dcaa5d	276	my ( $array, @args ) = @_;
913d96dd	277	# NOTE:
	278	# we need to make a copy cause
	279	# otherwise it will affect the
	280	# other real version.
	281	[ map {
	282	blessed($_)
34dcaa5d	283	? $OBJECT_HANDLERS{collapse}->($_, @args)
913d96dd	284	: $_
	285	} @$array ]
	286	}
	287	},
	288	'HashRef' => {
3db8f791	289	expand => sub {
34dcaa5d	290	my ( $hash, @args ) = @_;
3db8f791	291	foreach my $k (keys %$hash) {
3db8f791	292	next unless ref($hash->{$k}) eq 'HASH'
ba5bba75	293	&& exists $hash->{$k}->{$CLASS_MARKER};
34dcaa5d	294	$hash->{$k} = $OBJECT_HANDLERS{expand}->($hash->{$k}, @args);
3db8f791	295	}
	296	$hash;
	297	},
	298	collapse => sub {
34dcaa5d	299	my ( $hash, @args ) = @_;
3db8f791	300	# NOTE:
	301	# we need to make a copy cause
	302	# otherwise it will affect the
	303	# other real version.
	304	+{ map {
95f31c36	305	blessed($hash->{$_})
f6e1331f	306	? ($_ => $OBJECT_HANDLERS{collapse}->($hash->{$_}, @args))
3db8f791	307	: ($_ => $hash->{$_})
	308	} keys %$hash }
	309	}
e1bb45ff	310	},
913d96dd	311	'Object' => \%OBJECT_HANDLERS,
e1bb45ff	312	# NOTE:
	313	# The sanity of enabling this feature by
	314	# default is very questionable.
	315	# - SL
	316	#'CodeRef' => {
	317	# expand => sub {}, # use eval ...
	318	# collapse => sub {}, # use B::Deparse ...
7eb5dc63	319	#}
e59193fb	320	);
e59193fb	321
3db8f791	322	sub add_custom_type_handler {
	323	my ($class, $type_name, %handlers) = @_;
	324	(exists $handlers{expand} && exists $handlers{collapse})
	325	\|\| confess "Custom type handlers need an expand and a collapse method";
	326	$TYPES{$type_name} = \%handlers;
	327	}
	328
	329	sub remove_custom_type_handler {
	330	my ($class, $type_name) = @_;
	331	delete $TYPES{$type_name} if exists $TYPES{$type_name};
	332	}
	333
	334	sub find_type_handler {
e59193fb	335	my ($self, $type_constraint) = @_;
e1bb45ff	336
ef87e4a6	337	# check if the type is a Maybe and
	338	# if its parent is not parameterized.
	339	# If both is true recurse this method
	340	# using ->type_parameter.
	341	return $self->find_type_handler($type_constraint->type_parameter)
	342	if $type_constraint->parent eq 'Maybe'
	343	and not $type_constraint->parent->can('type_parameter');
	344
e1bb45ff	345	# this should handle most type usages
	346	# since they they are usually just
	347	# the standard set of built-ins
	348	return $TYPES{$type_constraint->name}
	349	if exists $TYPES{$type_constraint->name};
	350
	351	# the next possibility is they are
	352	# a subtype of the built-in types,
	353	# in which case this will DWIM in
	354	# most cases. It is probably not
	355	# 100% ideal though, but until I
	356	# come up with a decent test case
	357	# it will do for now.
e59193fb	358	foreach my $type (keys %TYPES) {
	359	return $TYPES{$type}
	360	if $type_constraint->is_subtype_of($type);
	361	}
e1bb45ff	362
	363	# NOTE:
	364	# the reason the above will work has to
	365	# do with the fact that custom subtypes
	366	# are mostly used for validation of
	367	# the guts of a type, and not for some
	368	# weird structural thing which would
	369	# need to be accomidated by the serializer.
	370	# Of course, mst or phaylon will probably
	371	# do something to throw this assumption
	372	# totally out the door ;)
	373	# - SL
	374
e9739624	375	# NOTE:
	376	# if this method hasnt returned by now
	377	# then we have no been able to find a
	378	# type constraint handler to match
	379	confess "Cannot handle type constraint (" . $type_constraint->name . ")";
e59193fb	380	}
e59193fb	381
3defafb9	382	sub find_type_handler_for {
	383	my ($self, $type_handler_name) = @_;
	384	$TYPES{$type_handler_name}
	385	}
	386
e59193fb	387	1;
e9739624	388
	389	__END__
	390
	391	=pod
	392
ec9c1923	393	=head1 NAME
ec9c1923	394
1390c23d	395	MooseX::Storage::Engine - The meta-engine to handle collapsing and expanding objects
ec9c1923	396
	397	=head1 DESCRIPTION
	398
1390c23d	399	No user serviceable parts inside. If you really want to know, read the source :)
1390c23d	400
ec9c1923	401	=head1 METHODS
	402
	403	=head2 Accessors
	404
	405	=over 4
	406
	407	=item B<class>
	408
	409	=item B<object>
	410
	411	=item B<storage>
	412
b430caa3	413	=item B<seen>
b430caa3	414
ec9c1923	415	=back
	416
	417	=head2 API
	418
	419	=over 4
	420
	421	=item B<expand_object>
	422
	423	=item B<collapse_object>
	424
	425	=back
	426
	427	=head2 ...
	428
	429	=over 4
	430
	431	=item B<collapse_attribute>
	432
	433	=item B<collapse_attribute_value>
	434
	435	=item B<expand_attribute>
	436
	437	=item B<expand_attribute_value>
	438
b430caa3	439	=item B<check_for_cycle_in_collapse>
	440
	441	=item B<check_for_cycle_in_expansion>
	442
ec9c1923	443	=item B<map_attributes>
ec9c1923	444
3db8f791	445	=back
	446
	447	=head2 Type Constraint Handlers
	448
	449	=over 4
	450
3defafb9	451	=item B<find_type_handler ($type)>
	452
	453	=item B<find_type_handler_for ($name)>
3db8f791	454
3defafb9	455	=item B<add_custom_type_handler ($name, %handlers)>
3db8f791	456
3defafb9	457	=item B<remove_custom_type_handler ($name)>
ec9c1923	458
	459	=back
	460
	461	=head2 Introspection
	462
	463	=over 4
	464
	465	=item B<meta>
	466
	467	=back
	468
	469	=head1 BUGS
	470
	471	All complex software has bugs lurking in it, and this module is no
	472	exception. If you find a bug please either email me, or add the bug
	473	to cpan-RT.
	474
	475	=head1 AUTHOR
	476
	477	Chris Prather E<lt>chris.prather@iinteractive.comE<gt>
	478
	479	Stevan Little E<lt>stevan.little@iinteractive.comE<gt>
	480
	481	=head1 COPYRIGHT AND LICENSE
	482
1f3074ea	483	Copyright 2007-2008 by Infinity Interactive, Inc.
ec9c1923	484
	485	L<http://www.iinteractive.com>
	486
	487	This library is free software; you can redistribute it and/or modify
	488	it under the same terms as Perl itself.
	489
e9739624	490	=cut
	491
	492
ec9c1923	493