lib/MooseX/Singleton/Role/Meta/Class.pm

   1 package MooseX::Singleton::Role::Meta::Class;
   2 use Moose::Role;
   3 use MooseX::Singleton::Role::Meta::Instance;
   4 use MooseX::Singleton::Role::Meta::Method::Constructor;
   5
   6
   7 sub existing_singleton {
   8     my ($class) = @_;
   9     my $pkg = $class->name;
  10
  11     no strict 'refs';
  12
  13     # create exactly one instance
  14     if ( defined ${"$pkg\::singleton"} ) {
  15         return ${"$pkg\::singleton"};
  16     }
  17
  18     return;
  19 }
  20
  21 sub clear_singleton {
  22     my ($class) = @_;
  23     my $pkg = $class->name;
  24     no strict 'refs';
  25     undef ${"$pkg\::singleton"};
  26 }
  27
  28 override _construct_instance => sub {
  29     my ($class) = @_;
  30
  31     # create exactly one instance
  32     my $existing = $class->existing_singleton;
  33     return $existing if $existing;
  34
  35     my $pkg = $class->name;
  36     no strict 'refs';
  37     no warnings 'once';
  38     return ${"$pkg\::singleton"} = super;
  39 };
  40
  41 if ( $Moose::VERSION >= 1.9900 ) {
  42     override _inline_params => sub {
  43         my $self = shift;
  44
  45         return
  46             'my $existing = do {',
  47                 'no strict "refs";',
  48                 'no warnings "once";',
  49                 '\${"$class\::singleton"};',
  50             '};',
  51             'return ${$existing} if ${$existing};',
  52             super();
  53     };
  54
  55     override _inline_extra_init => sub {
  56         my $self = shift;
  57
  58         return '${$existing} = $instance;';
  59     };
  60 }
  61
  62 no Moose::Role;
  63
  64 1;
  65
  66 # ABSTRACT: Metaclass role for MooseX::Singleton
  67
  68 __END__
  69
  70 =pod
  71
  72 =head1 DESCRIPTION
  73
  74 This metaclass role makes sure that there is only ever one instance of an
  75 object for a singleton class. The first call to C<construct_instance> is run
  76 normally (and then cached). Subsequent calls will return the cached version.
  77
  78 =cut
  79