lib/MooseX/Role/Parameterized/Meta/Role/Parameterizable.pm

   1 package MooseX::Role::Parameterized::Meta::Role::Parameterizable;
   2 use Moose;
   3 extends 'Moose::Meta::Role';
   4
   5 use MooseX::Role::Parameterized::Meta::Role::Parameterized;
   6 use MooseX::Role::Parameterized::Parameters;
   7
   8 use constant parameterized_role_metaclass => 'MooseX::Role::Parameterized::Meta::Role::Parameterized';
   9
  10 has parameter_metaclass => (
  11     is      => 'rw',
  12     isa     => 'Moose::Meta::Class',
  13     lazy    => 1,
  14     default => sub {
  15         Moose::Meta::Class->create_anon_class(
  16             superclasses => ['MooseX::Role::Parameterized::Parameters'],
  17         );
  18     },
  19 );
  20
  21 has role_generator => (
  22     is        => 'rw',
  23     isa       => 'CodeRef',
  24     predicate => 'has_role_generator',
  25 );
  26
  27 sub add_parameter {
  28     my $self = shift;
  29     my $name = shift;
  30
  31     # need to figure out a plan for these guys..
  32     confess "The parameter name ($name) is currently forbidden."
  33         if $name eq 'alias'
  34         || $name eq 'excludes';
  35
  36     $self->parameter_metaclass->add_attribute($name => @_);
  37 }
  38
  39 sub construct_parameters {
  40     my $self = shift;
  41     my %args = @_;
  42
  43     # need to figure out a plan for these guys..
  44     for my $name ('alias', 'excludes') {
  45         confess "The parameter name ($name) is currently forbidden."
  46             if exists $args{$name};
  47     }
  48
  49     $self->parameter_metaclass->new_object(\%args);
  50 }
  51
  52 sub generate_role {
  53     my $self = shift;
  54
  55     my $parameters = @_ == 1 ? shift
  56                              : $self->construct_parameters(@_);
  57
  58     confess "A role generator is required to generate roles"
  59         unless $self->has_role_generator;
  60
  61     my $role = $self->parameterized_role_metaclass->create_anon_role(parameters => $parameters);
  62
  63     local $MooseX::Role::Parameterized::CURRENT_METACLASS = $role;
  64
  65     $self->apply_parameterized_role($role);
  66
  67     $self->role_generator->($parameters,
  68         operating_on => $role,
  69     );
  70
  71     return $role;
  72 }
  73
  74 sub apply {
  75     my $self  = shift;
  76     my $class = shift;
  77     my %args  = @_;
  78
  79     my $role = $self->generate_role(%args);
  80     $role->apply($class, %args);
  81 }
  82
  83 sub apply_parameterized_role {
  84     my $self = shift;
  85
  86     $self->SUPER::apply(@_);
  87 }
  88
  89 __PACKAGE__->meta->make_immutable;
  90 no Moose;
  91
  92 1;
  93
  94 __END__
  95
  96 =head1 NAME
  97
  98 MooseX::Role::Parameterized::Meta::Role::Parameterizable - metaclass for parameterizable roles
  99
 100 =head1 DESCRIPTION
 101
 102 This is the metaclass for parameteriz-able roles, roles that have their
 103 parameters currently unbound. These are the roles that you use L<Moose/with>,
 104 but instead of composing the parameteriz-able role, we construct a new
 105 parameteriz-ed role
 106 (L<MooseX::Role::Parameterized::Meta::Role::Parameterized>).
 107
 108 =cut
 109