make all warnings fatal in tests

[gitmo/MooseX-Getopt.git] / t / 105_uc_bug_more.t

use strict;
use warnings FATAL => 'all';

use Test::More tests => 13;
use Test::NoWarnings 1.04 ':early';
use Moose ();
use Moose::Meta::Class;

foreach my $role (qw/
    MooseX::Getopt
    MooseX::Getopt::GLD
    MooseX::Getopt::Basic
/) {
    Class::MOP::load_class($role);

    my $meta = Moose::Meta::Class->create_anon_class(
        superclasses => ['Moose::Object'],
    );
    $meta->add_attribute('Debug', traits => ['Getopt'], isa => 'Bool',
        cmd_aliases => ['d'], is => 'ro');
    $role->meta->apply($meta);

    ok($meta->name->new_with_options({ argv => ['-d'] })->Debug,
        "Debug was set for argv -d on $role");
    {
        local @ARGV = ('-d');
        ok($meta->name->new_with_options()->Debug,
            "Debug was set for ARGV on $role");
    }

    ok($meta->name->new_with_options({ argv => ['--Debug'] })->Debug,
        "Debug was set for argv --Debug on $role");

    ok($meta->name->new_with_options({ argv => ['--debug'] })->Debug,
        "Debug was set for argv --debug on $role");
}