t/30.with_pid_file.t

   1 #!/usr/bin/perl
   2
   3 use strict;
   4 use warnings;
   5
   6 use File::Spec::Functions;
   7
   8 use Test::More 'no_plan';
   9 use Test::Fatal;
  10 use Test::Moose;
  11 use File::Temp qw(tempdir);
  12
  13 my $dir = tempdir( CLEANUP => 1 );
  14
  15
  16 BEGIN {
  17     use_ok('MooseX::Daemonize::Core');
  18 }
  19
  20 use constant DEBUG => 0;
  21
  22 my $PIDFILE            = catfile($dir, 'test-app.pid');
  23 $ENV{MX_DAEMON_STDOUT} = catfile($dir, 'Out.txt');
  24 $ENV{MX_DAEMON_STDERR} = catfile($dir, 'Err.txt');
  25
  26 {
  27     package MyFooDaemon;
  28     use Moose;
  29
  30     with 'MooseX::Daemonize::WithPidFile';
  31
  32     sub init_pidfile {
  33         MooseX::Daemonize::Pid::File->new( file => $PIDFILE )
  34     }
  35
  36     sub start {
  37         my $self = shift;
  38
  39         # this tests our bad PID
  40         # cleanup functionality.
  41         print "Our parent PID is " . $self->pidfile->pid . "\n" if ::DEBUG;
  42
  43         $self->daemonize;
  44         return unless $self->is_daemon;
  45
  46         # make it easy to find with ps
  47         $0 = 'test-app-2';
  48         $SIG{INT} = sub {
  49             print "Got INT! Oh Noes!";
  50             $self->pidfile->remove;
  51             exit;
  52         };
  53         while (1) {
  54             print "Hello from $$\n";
  55             sleep(10);
  56         }
  57         exit;
  58     }
  59 }
  60
  61 my $d = MyFooDaemon->new( pidfile => $PIDFILE );
  62 isa_ok($d, 'MyFooDaemon');
  63 does_ok($d, 'MooseX::Daemonize::Core');
  64 does_ok($d, 'MooseX::Daemonize::WithPidFile');
  65
  66 ok($d->has_pidfile, '... we have a pidfile value');
  67
  68 {
  69     my $p = $d->pidfile;
  70     isa_ok($p, 'MooseX::Daemonize::Pid::File');
  71     #diag $p->dump;
  72 }
  73
  74 ok(!(-e $PIDFILE), '... the PID file does not exist yet');
  75
  76 is(
  77     exception { $d->start },
  78     undef,
  79     '... successfully daemonized from (' . $$ . ')',
  80 );
  81
  82 my $p = $d->pidfile;
  83 isa_ok($p, 'MooseX::Daemonize::Pid::File');
  84 #diag $p->dump;
  85
  86 sleep(2);
  87
  88 ok($p->does_file_exist, '... the PID file exists');
  89 ok($p->is_running, '... the daemon process is running (' . $p->pid . ')');
  90
  91 my $pid = $p->pid;
  92 if (DEBUG) {
  93     diag `ps $pid`;
  94     diag "-------";
  95     diag `ps -x | grep test-app`;
  96     diag "-------";
  97     diag "killing $pid";
  98 }
  99 kill INT => $p->pid;
 100 diag "killed $pid" if DEBUG;
 101 sleep(2);
 102 if (DEBUG) {
 103     diag `ps $pid`;
 104     diag "-------";
 105     diag `ps -x | grep test-app`;
 106 }
 107
 108 ok(!$p->is_running, '... the daemon process is no longer running (' . $p->pid . ')');
 109 ok(!(-e $PIDFILE), '... the PID file has been removed');
 110
 111 unlink $ENV{MX_DAEMON_STDOUT};
 112 unlink $ENV{MX_DAEMON_STDERR};