t/21.core-back-compat.t

   1 #!/usr/bin/perl
   2
   3 use strict;
   4 use warnings;
   5
   6 use Test::More 'no_plan';
   7 use Test::Exception;
   8 use Test::Moose;
   9 use File::Temp qw(tempdir);
  10 use File::Spec::Functions;
  11
  12 my $dir = tempdir( CLEANUP => 1 );
  13
  14 BEGIN {
  15     use_ok('MooseX::Daemonize::Core');
  16     use_ok('MooseX::Daemonize::Pid');
  17 }
  18
  19 use constant DEBUG => 0;
  20
  21 $ENV{MX_DAEMON_STDOUT} = catfile($dir, 'Out.txt');
  22 $ENV{MX_DAEMON_STDERR} = catfile($dir, 'Err.txt');
  23
  24 {
  25     package MyFooDaemon;
  26     use Moose;
  27
  28     with 'MooseX::Daemonize::Core';
  29
  30     has 'daemon_pid' => (is => 'rw', isa => 'MooseX::Daemonize::Pid');
  31
  32     # capture the PID from the fork
  33     around 'daemon_fork' => sub {
  34         my $next = shift;
  35         my $self = shift;
  36         if (my $pid = $self->$next(@_)) {
  37             $self->daemon_pid(
  38                 MooseX::Daemonize::Pid->new(pid => $pid)
  39             );
  40         }
  41     };
  42
  43     sub start {
  44         my $self = shift;
  45         # tell it to ignore zombies ...
  46         $self->daemonize(
  47             ignore_zombies => 1,
  48             no_double_fork => 1,
  49         );
  50         return unless $self->is_daemon;
  51         # change to our local dir
  52         # so that we can debug easier
  53         chdir $dir;
  54         # make it easy to find with ps
  55         $0 = 'test-app';
  56         $SIG{INT} = sub {
  57             print "Got INT! Oh Noes!";
  58             exit;
  59         };
  60         while (1) {
  61             print "Hello from $$\n";
  62             sleep(10);
  63         }
  64         exit;
  65     }
  66 }
  67
  68 my $d = MyFooDaemon->new;
  69 isa_ok($d, 'MyFooDaemon');
  70 does_ok($d, 'MooseX::Daemonize::Core');
  71
  72 lives_ok {
  73     $d->start;
  74 } '... successfully daemonized from (' . $$ . ')';
  75
  76 my $p = $d->daemon_pid;
  77 isa_ok($p, 'MooseX::Daemonize::Pid');
  78
  79 ok($p->is_running, '... the daemon process is running (' . $p->pid . ')');
  80
  81 my $pid = $p->pid;
  82 if (DEBUG) {
  83     diag `ps $pid`;
  84     diag "-------";
  85     diag `ps -x | grep test-app`;
  86     diag "-------";
  87     diag "killing $pid";
  88 }
  89 kill INT => $p->pid;
  90 diag "killed $pid" if DEBUG;
  91 sleep(2);
  92 if (DEBUG) {
  93     diag `ps $pid`;
  94     diag "-------";
  95     diag `ps -x | grep test-app`;
  96 }
  97
  98 ok(!$p->is_running, '... the daemon process is no longer running (' . $p->pid . ')');
  99
 100 unlink $ENV{MX_DAEMON_STDOUT};
 101 unlink $ENV{MX_DAEMON_STDERR};
 102
 103