lib/MooseX/Daemonize/Pid/File.pm

   1 use strict;
   2 use warnings;
   3 package MooseX::Daemonize::Pid::File;
   4
   5 use Moose;
   6 use Moose::Util::TypeConstraints;
   7
   8 use MooseX::Types::Path::Class;
   9 use MooseX::Getopt::OptionTypeMap;
  10
  11 # NOTE:
  12 # set up some basic coercions
  13 # that will come in handy
  14 # - SL
  15 coerce 'MooseX::Daemonize::Pid::File'
  16     => from 'Str'
  17         => via { MooseX::Daemonize::Pid::File->new( file => $_ ) }
  18     => from 'ArrayRef'
  19         => via { MooseX::Daemonize::Pid::File->new( file => $_ ) }
  20     => from 'Path::Class::File'
  21         => via { MooseX::Daemonize::Pid::File->new( file => $_ ) };
  22
  23 # NOTE:
  24 # make sure this class plays
  25 # well with MooseX::Getopt
  26 # - SL
  27 MooseX::Getopt::OptionTypeMap->add_option_type_to_map(
  28     'MooseX::Daemonize::Pid::File' => '=s',
  29 );
  30
  31 extends 'MooseX::Daemonize::Pid';
  32
  33 has '+pid' => (
  34     default => sub {
  35         my $self = shift;
  36         $self->does_file_exist
  37             ? $self->file->slurp(chomp => 1)
  38             : $$
  39     }
  40 );
  41
  42 has 'file' => (
  43     is       => 'ro',
  44     isa      => 'Path::Class::File',
  45     coerce   => 1,
  46     required => 1,
  47     handles  => [ 'remove' ]
  48 );
  49
  50 sub does_file_exist { -s (shift)->file }
  51
  52 sub write {
  53     my $self = shift;
  54     my $fh = $self->file->openw;
  55     $fh->print($self->pid . "\n");
  56     $fh->close;
  57 }
  58
  59 override 'is_running' => sub {
  60     return 0 unless (shift)->does_file_exist;
  61     super();
  62 };
  63
  64 1;
  65
  66 __END__
  67
  68 =pod
  69
  70 =head1 NAME
  71
  72 MooseX::Daemonize::Pid::File - PID file management for MooseX::Daemonize
  73
  74 =head1 DESCRIPTION
  75
  76 This object extends L<MooseX::Daemonize::Pid> to add persistence in a Pidfile.
  77
  78 This class sets up some basic coercion routines for itself so that it can
  79 be created from a I<Str> (a file name), I<ArrayRef> (an array of path components
  80 for a filename) or a I<Path::Class::File> object.
  81
  82 This class registers it's type with L<MooseX::Getopt> as well, and is expected
  83 to be passed on the command line as a string (which will then go through the
  84 coercion routines mentioned above).
  85
  86 =head1 ATTRIBUTES
  87
  88 =over
  89
  90 =item I<pid Int>
  91
  92 This is inherited from L<MooseX:Daemonize::Pid> and extended here to
  93 get it's default value from the Pidfile (if available).
  94
  95 =item I<file Path::Class::File | Str>
  96
  97 =back
  98
  99 =head1 METHODS
 100
 101 =over
 102
 103 =item B<clear_pid>
 104
 105 =item B<has_pid>
 106
 107 Both of these methods are inherited from L<MooseX:Daemonize::Pid> see that
 108 module for more information.
 109
 110 =item B<remove>
 111
 112 This removes the Pidfile.
 113
 114 =item B<write>
 115
 116 This writes the Pidfile.
 117
 118 =item B<does_file_exist>
 119
 120 This checks if the Pidfile exists.
 121
 122 =item B<is_running>
 123
 124 This checks if the Pidfile exists, if it does it checks to see if the process
 125 is running, if the Pidfile doesn't exist, it returns false.
 126
 127 =item meta()
 128
 129 The C<meta()> method from L<Class::MOP::Class>
 130
 131 =back
 132
 133 =head1 DEPENDENCIES
 134
 135 Obviously L<Moose>
 136
 137 =head1 INCOMPATIBILITIES
 138
 139 None reported.
 140
 141 =head1 BUGS AND LIMITATIONS
 142
 143 No bugs have been reported.
 144
 145 Please report any bugs or feature requests to
 146 C<bug-acme-dahut-call@rt.cpan.org>, or through the web interface at
 147 L<http://rt.cpan.org>.
 148
 149 =head1 AUTHOR
 150
 151 Stevan Little  C<< <stevan.little@iinteractive.com> >>
 152
 153 =head1 LICENCE AND COPYRIGHT
 154
 155 Copyright (c) 2007-2011, Chris Prather C<< <perigrin@cpan.org> >>. All rights
 156 reserved.
 157
 158 This module is free software; you can redistribute it and/or
 159 modify it under the same terms as Perl itself. See L<perlartistic>.
 160
 161
 162 =head1 DISCLAIMER OF WARRANTY
 163
 164 BECAUSE THIS SOFTWARE IS LICENSED FREE OF CHARGE, THERE IS NO WARRANTY
 165 FOR THE SOFTWARE, TO THE EXTENT PERMITTED BY APPLICABLE LAW. EXCEPT WHEN
 166 OTHERWISE STATED IN WRITING THE COPYRIGHT HOLDERS AND/OR OTHER PARTIES
 167 PROVIDE THE SOFTWARE "AS IS" WITHOUT WARRANTY OF ANY KIND, EITHER
 168 EXPRESSED OR IMPLIED, INCLUDING, BUT NOT LIMITED TO, THE IMPLIED
 169 WARRANTIES OF MERCHANTABILITY AND FITNESS FOR A PARTICULAR PURPOSE. THE
 170 ENTIRE RISK AS TO THE QUALITY AND PERFORMANCE OF THE SOFTWARE IS WITH
 171 YOU. SHOULD THE SOFTWARE PROVE DEFECTIVE, YOU ASSUME THE COST OF ALL
 172 NECESSARY SERVICING, REPAIR, OR CORRECTION.
 173
 174 IN NO EVENT UNLESS REQUIRED BY APPLICABLE LAW OR AGREED TO IN WRITING
 175 WILL ANY COPYRIGHT HOLDER, OR ANY OTHER PARTY WHO MAY MODIFY AND/OR
 176 REDISTRIBUTE THE SOFTWARE AS PERMITTED BY THE ABOVE LICENCE, BE
 177 LIABLE TO YOU FOR DAMAGES, INCLUDING ANY GENERAL, SPECIAL, INCIDENTAL,
 178 OR CONSEQUENTIAL DAMAGES ARISING OUT OF THE USE OR INABILITY TO USE
 179 THE SOFTWARE (INCLUDING BUT NOT LIMITED TO LOSS OF DATA OR DATA BEING
 180 RENDERED INACCURATE OR LOSSES SUSTAINED BY YOU OR THIRD PARTIES OR A
 181 FAILURE OF THE SOFTWARE TO OPERATE WITH ANY OTHER SOFTWARE), EVEN IF
 182 SUCH HOLDER OR OTHER PARTY HAS BEEN ADVISED OF THE POSSIBILITY OF
 183 SUCH DAMAGES.
 184
 185 =cut