lib/MooseX/ConfigFromFile.pm

   1 package MooseX::ConfigFromFile;
   2
   3 use Moose::Role;
   4 use MooseX::Types::Path::Class qw( File );
   5
   6 our $VERSION   = '0.02';
   7
   8 requires 'get_config_from_file';
   9
  10 has configfile => (
  11     is => 'ro',
  12     isa => File,
  13     coerce => 1,
  14     predicate => 'has_configfile',
  15 );
  16
  17 sub new_with_config {
  18     my ($class, %opts) = @_;
  19
  20     my $configfile;
  21
  22     if(defined $opts{configfile}) {
  23         $configfile = $opts{configfile}
  24     }
  25     else {
  26         my $cfmeta = $class->meta->get_attribute('configfile');
  27         $configfile = $cfmeta->default if $cfmeta->has_default;
  28     }
  29
  30     if(defined $configfile) {
  31         %opts = (%{$class->get_config_from_file($configfile)}, %opts);
  32     }
  33
  34     $class->new(%opts);
  35 }
  36
  37 no Moose::Role; 1;
  38
  39 __END__
  40
  41 =pod
  42
  43 =head1 NAME
  44
  45 MooseX::ConfigFromFile - An abstract Moose role for setting attributes from a configfile
  46
  47 =head1 SYNOPSIS
  48
  49   ########
  50   ## A real role based on this abstract role:
  51   ########
  52
  53   package MooseX::SomeSpecificConfigRole;
  54   use Moose::Role;
  55
  56   with 'MooseX::ConfigFromFile';
  57
  58   use Some::ConfigFile::Loader ();
  59
  60   sub get_config_from_file {
  61     my ($class, $file) = @_;
  62
  63     my $options_hashref = Some::ConfigFile::Loader->load($file);
  64
  65     return $options_hashref;
  66   }
  67
  68
  69   ########
  70   ## A class that uses it:
  71   ########
  72   package Foo;
  73   use Moose;
  74   with 'MooseX::SomeSpecificConfigRole';
  75
  76   # optionally, default the configfile:
  77   has +configfile ( default => '/tmp/foo.yaml' );
  78
  79   # ... insert your stuff here ...
  80
  81   ########
  82   ## A script that uses the class with a configfile
  83   ########
  84
  85   my $obj = Foo->new_with_config(configfile => '/etc/foo.yaml', other_opt => 'foo');
  86
  87 =head1 DESCRIPTION
  88
  89 This is an abstract role which provides an alternate constructor for creating
  90 objects using parameters passed in from a configuration file.  The
  91 actual implementation of reading the configuration file is left to
  92 concrete subroles.
  93
  94 It declares an attribute C<configfile> and a class method C<new_with_config>,
  95 and requires that concrete roles derived from it implement the class method
  96 C<get_config_from_file>.
  97
  98 Attributes specified directly as arguments to C<new_with_config> supercede those
  99 in the configfile.
 100
 101 L<MooseX::Getopt> knows about this abstract role, and will use it if available
 102 to load attributes from the file specified by the commandline flag C<--configfile>
 103 during its normal C<new_with_options>.
 104
 105 =head1 Attributes
 106
 107 =head2 configfile
 108
 109 This is a L<Path::Class::File> object which can be coerced from a regular pathname
 110 string.  This is the file your attributes are loaded from.  You can add a default
 111 configfile in the class using the role and it will be honored at the appropriate time:
 112
 113   has +configfile ( default => '/etc/myapp.yaml' );
 114
 115 =head1 Class Methods
 116
 117 =head2 new_with_config
 118
 119 This is an alternate constructor, which knows to look for the C<configfile> option
 120 in its arguments and use that to set attributes.  It is much like L<MooseX::Getopts>'s
 121 C<new_with_options>.  Example:
 122
 123   my $foo = SomeClass->new_with_config(configfile => '/etc/foo.yaml');
 124
 125 Explicit arguments will overide anything set by the configfile.
 126
 127 =head2 get_config_from_file
 128
 129 This class method is not implemented in this role, but it is required of all subroles.
 130 Its two arguments are the classname and the configfile, and it is expected to return
 131 a hashref of arguments to pass to C<new()> which are sourced from the configfile.
 132
 133 =head2 meta
 134
 135 The Moose meta stuff, included here because otherwise pod tests fail sometimes
 136
 137 =head1 BUGS
 138
 139 =head1 AUTHOR
 140
 141 Brandon L. Black, E<lt>blblack@gmail.comE<gt>
 142
 143 =head1 LICENSE
 144
 145 This library is free software; you can redistribute it and/or modify
 146 it under the same terms as Perl itself.
 147
 148 =cut