lib/MooseX/Antlers/Compiler.pm

   1 package MooseX::Antlers::Compiler;
   2
   3 use Moose;
   4 use IO::All qw(io);
   5 use String::TT qw(strip tt);
   6 use B qw(perlstring);
   7 use Data::Dumper::Concise;
   8 use Scalar::Util qw(refaddr);
   9 use aliased 'MooseX::Antlers::RefTracker';
  10 use aliased 'MooseX::Antlers::EvalTracker';
  11 use aliased 'MooseX::Antlers::RefFilter';
  12
  13 has [ qw(_target _attr_refs _attr_et _im_et _raw_source) ] => (is => 'rw');
  14
  15 sub load_with_compiler {
  16   my ($class, $target) = @_;
  17   $class->new->load($target);
  18 }
  19
  20 sub load {
  21   my ($self, $target) = @_;
  22   my %attr_refs;
  23   my %attr_et;
  24   my $im_et;
  25   my $orig_import = Moose->can('import');
  26   no warnings 'redefine';
  27   local *Moose::import = sub {
  28     my $targ = caller;
  29     Moose->$orig_import({ into => $targ });
  30     my $has = $targ->can('has');
  31     {
  32       no strict 'refs';
  33       *{"${targ}::has"} = sub {
  34         $attr_refs{$_[0]} = [
  35           map RefTracker->trace_refs( $_ => \@_ ),
  36             '(\@_)', '$has_args{'.perlstring($_[0]).'}'
  37         ];
  38         my $et = EvalTracker->new->enable;
  39         $has->(@_);
  40         $attr_et{$_[0]} = $et->disable;
  41         return;
  42       };
  43     }
  44   };
  45   my $orig_immutable = Moose::Meta::Class->can('make_immutable');
  46   local *Moose::Meta::Class::make_immutable = sub {
  47     my $et = EvalTracker->new->enable;
  48     $orig_immutable->(@_);
  49     $im_et = $et->disable;
  50     return;
  51   };
  52   Class::MOP::load_class($target);
  53   $self->_attr_refs(\%attr_refs);
  54   $self->_attr_et(\%attr_et);
  55   $self->_im_et($im_et);
  56   $self->_target($target);
  57   (my $pm_file = $target) =~ s/::/\//g;
  58   $self->_raw_source(scalar io($INC{"${pm_file}.pm"})->slurp);
  59   return $self;
  60 }
  61
  62 sub compiled_source {
  63   my ($self) = @_;
  64   my %attr_et = %{$self->_attr_et};
  65   my %attr_refs = %{$self->_attr_refs};
  66   my $im_et = $self->_im_et;
  67   my $target = $self->_target;
  68   my %attr_construct;
  69   my $all_refs = { map %{$_->[1]}, values %attr_refs };
  70   foreach my $attr_name (keys %attr_refs) {
  71     $attr_construct{$attr_name}
  72       = $attr_et{$attr_name}->serialized_construction(
  73           $attr_refs{$attr_name}[0]
  74         );
  75   }
  76   my $im_construct = $im_et->serialized_construction($all_refs);
  77   my $preamble = tt strip q{
  78     my %replay_has;
  79     my %has_args;
  80     BEGIN {
  81       %replay_has = (
  82   [% FOREACH a IN attr_construct_h %]
  83         [% a.key %] => sub {
  84           [% a.value %]
  85         }
  86   [% END %]
  87       );
  88     }
  89     sub MooseX::Antlers::ImmutableHackFor::[% target %]::make_immutable {
  90       [% im_construct %]
  91       no warnings 'redefine';
  92       *[% target %]::meta = sub {
  93         my $meta_code = do { local $/; <[% target %]::DATA> };
  94         local $@;
  95         my $meta = eval $meta_code;
  96         die $@ if $@;
  97         $meta;
  98       };
  99     }
 100     use MooseX::Antlers::StealImport
 101       Moose => {
 102         -do => sub {
 103           strict->import;
 104           warnings->import;
 105         },
 106         has => sub {
 107           $has_args{$_[0]} = \@_;
 108           ($replay_has{$_[0]}||die "Can't find replay for $_[0]")
 109             ->(@_);
 110         },
 111         meta => sub { 'MooseX::Antlers::ImmutableHackFor::[% target %]' }
 112       };
 113   };
 114
 115   my $meta_construct = $self->_meta_construction_code($all_refs);
 116
 117   my $postamble = tt strip q{
 118     no MooseX::Antlers::StealImport qw(Moose);
 119     __DATA__
 120     [% meta_construct %]
 121   };
 122
 123   my $compiled = join("\n", $preamble, $self->_raw_source, $postamble);
 124
 125   return $compiled;
 126 }
 127
 128 sub _meta_construction_code {
 129   my ($self, $all_refs) = @_;
 130   my $target = $self->_target;
 131   my $meta_obj = $target->meta;
 132   my $mappings = {
 133     %$all_refs,
 134     map +(refaddr($target->can($_)) => '\&'.$target.'::'.$_),
 135       $meta_obj->get_method_list, 'meta'
 136   };
 137   my $filter = RefFilter->new(
 138     external_mappings => $mappings,
 139     root_name => '$meta'
 140   );
 141   my $filtered_meta = Dumper($filter->visit($meta_obj));
 142   my $meta_fixup = $filter->fixup_code;
 143   my $target_string = perlstring($target);
 144   return tt strip q{
 145     require Moose;
 146     my $meta = [% filtered_meta %];
 147     [% meta_fixup %]
 148     Class::MOP::store_metaclass_by_name([% target_string %] => $meta);
 149     no warnings 'redefine';
 150     *[% target %]::meta = sub {
 151       Moose::Meta::Class->initialize( ref($_[0]) || $_[0] );
 152     };
 153     $meta;
 154   };
 155 }
 156
 157 1;