t/000_recipes/004_recipe.t

   1 #!/usr/bin/perl
   2
   3 use strict;
   4 use warnings;
   5
   6 use Test::More;
   7
   8 BEGIN {
   9     eval "use Regexp::Common; use Locale::US;";
  10     plan skip_all => "Regexp::Common & Locale::US required for this test" if $@;
  11     plan tests => 81;
  12 }
  13
  14 use Test::Exception;
  15 use Scalar::Util 'isweak';
  16
  17 BEGIN {
  18     use_ok('Moose');
  19 }
  20
  21 {
  22     package Address;
  23     use Moose;
  24     use Moose::Util::TypeConstraints;
  25
  26     use Locale::US;
  27     use Regexp::Common 'zip';
  28
  29     my $STATES = Locale::US->new;
  30
  31     subtype USState
  32         => as Str
  33         => where {
  34             (exists $STATES->{code2state}{uc($_)} || exists $STATES->{state2code}{uc($_)})
  35         };
  36
  37     subtype USZipCode
  38         => as Value
  39         => where {
  40             /^$RE{zip}{US}{-extended => 'allow'}$/
  41         };
  42
  43     has 'street'   => (is => 'rw', isa => 'Str');
  44     has 'city'     => (is => 'rw', isa => 'Str');
  45     has 'state'    => (is => 'rw', isa => 'USState');
  46     has 'zip_code' => (is => 'rw', isa => 'USZipCode');
  47
  48     metaclass->make_immutable(debug => 0);
  49 }{
  50
  51     package Company;
  52     use Moose;
  53     use Moose::Util::TypeConstraints;
  54
  55     has 'name'      => (is => 'rw', isa => 'Str', required => 1);
  56     has 'address'   => (is => 'rw', isa => 'Address');
  57     has 'employees' => (is => 'rw', isa => 'ArrayRef[Employee]');
  58
  59     sub BUILD {
  60         my ($self, $params) = @_;
  61         if ($params->{employees}) {
  62             foreach my $employee (@{$params->{employees}}) {
  63                 $employee->company($self);
  64             }
  65         }
  66     }
  67
  68     sub get_employee_count { scalar @{(shift)->employees} }
  69
  70     after 'employees' => sub {
  71         my ($self, $employees) = @_;
  72         # if employees is defined, it
  73         # has already been type checked
  74         if (defined $employees) {
  75             # make sure each gets the
  76             # weak ref to the company
  77             foreach my $employee (@{$employees}) {
  78                 $employee->company($self);
  79             }
  80         }
  81     };
  82
  83     metaclass->make_immutable(debug => 0);
  84 }{
  85
  86     package Person;
  87     use Moose;
  88
  89     has 'first_name'     => (is => 'rw', isa => 'Str', required => 1);
  90     has 'last_name'      => (is => 'rw', isa => 'Str', required => 1);
  91     has 'middle_initial' => (is => 'rw', isa => 'Str', predicate => 'has_middle_initial');
  92     has 'address'        => (is => 'rw', isa => 'Address');
  93
  94     sub full_name {
  95         my $self = shift;
  96         return $self->first_name .
  97               ($self->has_middle_initial ? ' ' . $self->middle_initial . '. ' : ' ') .
  98                $self->last_name;
  99     }
 100
 101     metaclass->make_immutable(debug => 0);
 102 }{
 103
 104     package Employee;
 105     use Moose;
 106
 107     extends 'Person';
 108
 109     has 'title'   => (is => 'rw', isa => 'Str', required => 1);
 110     has 'company' => (is => 'rw', isa => 'Company', weak_ref => 1);
 111
 112     override 'full_name' => sub {
 113         my $self = shift;
 114         super() . ', ' . $self->title
 115     };
 116
 117     metaclass->make_immutable(debug => 0);
 118 }
 119
 120 my $ii;
 121 lives_ok {
 122     $ii = Company->new({
 123         name    => 'Infinity Interactive',
 124         address => Address->new(
 125             street   => '565 Plandome Rd., Suite 307',
 126             city     => 'Manhasset',
 127             state    => 'NY',
 128             zip_code => '11030'
 129         ),
 130         employees => [
 131             Employee->new(
 132                 first_name     => 'Jeremy',
 133                 last_name      => 'Shao',
 134                 title          => 'President / Senior Consultant',
 135                 address        => Address->new(city => 'Manhasset', state => 'NY')
 136             ),
 137             Employee->new(
 138                 first_name     => 'Tommy',
 139                 last_name      => 'Lee',
 140                 title          => 'Vice President / Senior Developer',
 141                 address        => Address->new(city => 'New York', state => 'NY')
 142             ),
 143             Employee->new(
 144                 first_name     => 'Stevan',
 145                 middle_initial => 'C',
 146                 last_name      => 'Little',
 147                 title          => 'Senior Developer',
 148                 address        => Address->new(city => 'Madison', state => 'CT')
 149             ),
 150             Employee->new(
 151                 first_name     => 'Rob',
 152                 last_name      => 'Kinyon',
 153                 title          => 'Developer',
 154                 address        => Address->new(city => 'Marysville', state => 'OH')
 155             ),
 156         ]
 157     });
 158 } '... created the entire company successfully';
 159 isa_ok($ii, 'Company');
 160
 161 is($ii->name, 'Infinity Interactive', '... got the right name for the company');
 162
 163 isa_ok($ii->address, 'Address');
 164 is($ii->address->street, '565 Plandome Rd., Suite 307', '... got the right street address');
 165 is($ii->address->city, 'Manhasset', '... got the right city');
 166 is($ii->address->state, 'NY', '... got the right state');
 167 is($ii->address->zip_code, 11030, '... got the zip code');
 168
 169 is($ii->get_employee_count, 4, '... got the right employee count');
 170
 171 # employee #1
 172
 173 isa_ok($ii->employees->[0], 'Employee');
 174 isa_ok($ii->employees->[0], 'Person');
 175
 176 is($ii->employees->[0]->first_name, 'Jeremy', '... got the right first name');
 177 is($ii->employees->[0]->last_name, 'Shao', '... got the right last name');
 178 ok(!$ii->employees->[0]->has_middle_initial, '... no middle initial');
 179 is($ii->employees->[0]->middle_initial, undef, '... got the right middle initial value');
 180 is($ii->employees->[0]->full_name, 'Jeremy Shao, President / Senior Consultant', '... got the right full name');
 181 is($ii->employees->[0]->title, 'President / Senior Consultant', '... got the right title');
 182 is($ii->employees->[0]->company, $ii, '... got the right company');
 183 ok(isweak($ii->employees->[0]->{company}), '... the company is a weak-ref');
 184
 185 isa_ok($ii->employees->[0]->address, 'Address');
 186 is($ii->employees->[0]->address->city, 'Manhasset', '... got the right city');
 187 is($ii->employees->[0]->address->state, 'NY', '... got the right state');
 188
 189 # employee #2
 190
 191 isa_ok($ii->employees->[1], 'Employee');
 192 isa_ok($ii->employees->[1], 'Person');
 193
 194 is($ii->employees->[1]->first_name, 'Tommy', '... got the right first name');
 195 is($ii->employees->[1]->last_name, 'Lee', '... got the right last name');
 196 ok(!$ii->employees->[1]->has_middle_initial, '... no middle initial');
 197 is($ii->employees->[1]->middle_initial, undef, '... got the right middle initial value');
 198 is($ii->employees->[1]->full_name, 'Tommy Lee, Vice President / Senior Developer', '... got the right full name');
 199 is($ii->employees->[1]->title, 'Vice President / Senior Developer', '... got the right title');
 200 is($ii->employees->[1]->company, $ii, '... got the right company');
 201 ok(isweak($ii->employees->[1]->{company}), '... the company is a weak-ref');
 202
 203 isa_ok($ii->employees->[1]->address, 'Address');
 204 is($ii->employees->[1]->address->city, 'New York', '... got the right city');
 205 is($ii->employees->[1]->address->state, 'NY', '... got the right state');
 206
 207 # employee #3
 208
 209 isa_ok($ii->employees->[2], 'Employee');
 210 isa_ok($ii->employees->[2], 'Person');
 211
 212 is($ii->employees->[2]->first_name, 'Stevan', '... got the right first name');
 213 is($ii->employees->[2]->last_name, 'Little', '... got the right last name');
 214 ok($ii->employees->[2]->has_middle_initial, '... got middle initial');
 215 is($ii->employees->[2]->middle_initial, 'C', '... got the right middle initial value');
 216 is($ii->employees->[2]->full_name, 'Stevan C. Little, Senior Developer', '... got the right full name');
 217 is($ii->employees->[2]->title, 'Senior Developer', '... got the right title');
 218 is($ii->employees->[2]->company, $ii, '... got the right company');
 219 ok(isweak($ii->employees->[2]->{company}), '... the company is a weak-ref');
 220
 221 isa_ok($ii->employees->[2]->address, 'Address');
 222 is($ii->employees->[2]->address->city, 'Madison', '... got the right city');
 223 is($ii->employees->[2]->address->state, 'CT', '... got the right state');
 224
 225 # employee #4
 226
 227 isa_ok($ii->employees->[3], 'Employee');
 228 isa_ok($ii->employees->[3], 'Person');
 229
 230 is($ii->employees->[3]->first_name, 'Rob', '... got the right first name');
 231 is($ii->employees->[3]->last_name, 'Kinyon', '... got the right last name');
 232 ok(!$ii->employees->[3]->has_middle_initial, '... got middle initial');
 233 is($ii->employees->[3]->middle_initial, undef, '... got the right middle initial value');
 234 is($ii->employees->[3]->full_name, 'Rob Kinyon, Developer', '... got the right full name');
 235 is($ii->employees->[3]->title, 'Developer', '... got the right title');
 236 is($ii->employees->[3]->company, $ii, '... got the right company');
 237 ok(isweak($ii->employees->[3]->{company}), '... the company is a weak-ref');
 238
 239 isa_ok($ii->employees->[3]->address, 'Address');
 240 is($ii->employees->[3]->address->city, 'Marysville', '... got the right city');
 241 is($ii->employees->[3]->address->state, 'OH', '... got the right state');
 242
 243 # create new company
 244
 245 my $new_company = Company->new(name => 'Infinity Interactive International');
 246 isa_ok($new_company, 'Company');
 247
 248 my $ii_employees = $ii->employees;
 249 foreach my $employee (@$ii_employees) {
 250     is($employee->company, $ii, '... has the ii company');
 251 }
 252
 253 $new_company->employees($ii_employees);
 254
 255 foreach my $employee (@{$new_company->employees}) {
 256     is($employee->company, $new_company, '... has the different company now');
 257 }
 258
 259 ## check some error conditions for the subtypes
 260
 261 dies_ok {
 262     Address->new(street => {}),
 263 } '... we die correctly with bad args';
 264
 265 dies_ok {
 266     Address->new(city => {}),
 267 } '... we die correctly with bad args';
 268
 269 dies_ok {
 270     Address->new(state => 'British Columbia'),
 271 } '... we die correctly with bad args';
 272
 273 lives_ok {
 274     Address->new(state => 'Connecticut'),
 275 } '... we live correctly with good args';
 276
 277 dies_ok {
 278     Address->new(zip_code => 'AF5J6$'),
 279 } '... we die correctly with bad args';
 280
 281 lives_ok {
 282     Address->new(zip_code => '06443'),
 283 } '... we live correctly with good args';
 284
 285 dies_ok {
 286     Company->new(),
 287 } '... we die correctly without good args';
 288
 289 lives_ok {
 290     Company->new(name => 'Foo'),
 291 } '... we live correctly without good args';
 292
 293 dies_ok {
 294     Company->new(name => 'Foo', employees => [ Person->new ]),
 295 } '... we die correctly with good args';
 296
 297 lives_ok {
 298     Company->new(name => 'Foo', employees => []),
 299 } '... we live correctly with good args';
 300