lib/Moose/Autobox/Array.pm

   1 package Moose::Autobox::Array;
   2 use Moose::Role 'with';
   3 use Perl6::Junction;
   4 use Moose::Autobox;
   5
   6 our $VERSION = '0.03';
   7
   8 with 'Moose::Autobox::Ref',
   9      'Moose::Autobox::List',
  10      'Moose::Autobox::Indexed';
  11
  12 ## Array Interface
  13
  14 sub pop {
  15     my ($array) = @_;
  16     CORE::pop @$array;
  17 }
  18
  19 sub push {
  20     my ($array, @rest) = @_;
  21     CORE::push @$array, @rest;
  22     $array;
  23 }
  24
  25 sub unshift {
  26     my ($array, @rest) = @_;
  27     CORE::unshift @$array, @rest;
  28     $array;
  29 }
  30
  31 sub delete {
  32     my ($array, $index) = @_;
  33     CORE::delete $array->[$index];
  34 }
  35
  36 sub shift {
  37     my ($array) = @_;
  38     CORE::shift @$array;
  39 }
  40
  41 sub slice {
  42     my ($array, $indicies) = @_;
  43     [ @{$array}[ @{$indicies} ] ];
  44 }
  45
  46 # NOTE:
  47 # sprintf args need to be reversed,
  48 # because the invocant is the array
  49 sub sprintf { CORE::sprintf $_[1], @{$_[0]} }
  50
  51 ## ::List interface implementation
  52
  53 sub head { $_[0]->[0] }
  54 sub tail { [ @{$_[0]}[ 1 .. $#{$_[0]} ] ] }
  55
  56 sub length {
  57     my ($array) = @_;
  58     CORE::scalar @$array;
  59 }
  60
  61 sub grep {
  62     my ($array, $sub) = @_;
  63     [ CORE::grep { $sub->($_) } @$array ];
  64 }
  65
  66 sub map {
  67     my ($array, $sub) = @_;
  68     [ CORE::map { $sub->($_) } @$array ];
  69 }
  70
  71 sub join {
  72     my ($array, $sep) = @_;
  73     $sep ||= '';
  74     CORE::join $sep, @$array;
  75 }
  76
  77 sub reverse {
  78     my ($array) = @_;
  79     [ CORE::reverse @$array ];
  80 }
  81
  82 sub sort {
  83     my ($array, $sub) = @_;
  84     $sub ||= sub { $a cmp $b };
  85     [ CORE::sort { $sub->($a, $b) } @$array ];
  86 }
  87
  88 ## ::Indexed implementation
  89
  90 sub at {
  91     my ($array, $index) = @_;
  92     $array->[$index];
  93 }
  94
  95 sub put {
  96     my ($array, $index, $value) = @_;
  97     $array->[$index] = $value;
  98 }
  99
 100 sub exists {
 101     my ($array, $index) = @_;
 102     CORE::exists $array->[$index];
 103 }
 104
 105 sub keys {
 106     my ($array) = @_;
 107     [ 0 .. $#{$array} ];
 108 }
 109
 110 sub values {
 111     my ($array) = @_;
 112     [ @$array ];
 113 }
 114
 115 sub kv {
 116     my ($array) = @_;
 117     $array->keys->map(sub { [ $_, $array->[$_] ] });
 118 }
 119
 120 sub flatten {
 121     @{$_[0]}
 122 }
 123
 124 sub _flatten_deep {
 125         my @array = @_;
 126         my $depth = CORE::pop @array;
 127         --$depth if (defined($depth));
 128
 129         CORE::map {
 130                 (ref eq 'ARRAY')
 131                         ? (defined($depth) && $depth == -1) ? $_ : _flatten_deep( @$_, $depth )
 132                         : $_
 133         } @array;
 134
 135 }
 136
 137 sub flatten_deep {
 138         my ($array, $depth) = @_;
 139         [ _flatten_deep(@$array, $depth) ];
 140 }
 141
 142 ## Junctions
 143
 144 sub all {
 145     my ($array) = @_;
 146     return Perl6::Junction::all(@$array);
 147 }
 148
 149 sub any {
 150     my ($array) = @_;
 151     return Perl6::Junction::any(@$array);
 152 }
 153
 154 sub none {
 155     my ($array) = @_;
 156     return Perl6::Junction::none(@$array);
 157 }
 158
 159 sub one {
 160     my ($array) = @_;
 161     return Perl6::Junction::one(@$array);
 162 }
 163
 164 ## Print
 165
 166 sub print { CORE::print @{$_[0]} }
 167 sub say   { CORE::print @{$_[0]}, "\n" }
 168
 169 1;
 170
 171 __END__
 172
 173 =pod
 174
 175 =head1 NAME
 176
 177 Moose::Autobox::Array - the Array role
 178
 179 =head1 SYNOPOSIS
 180
 181   use Moose::Autobox;
 182
 183   [ 1..5 ]->isa('ARRAY'); # true
 184   [ a..z ]->does('Moose::Autobox::Array'); # true
 185   [ 0..2 ]->does('Moose::Autobox::List'); # true
 186
 187   print "Squares: " . [ 1 .. 10 ]->map(sub { $_ * $_ })->join(', ');
 188
 189   print [ 1, 'number' ]->sprintf('%d is the loneliest %s');
 190
 191   print ([ 1 .. 5 ]->any == 3) ? 'true' : 'false'; # prints 'true'
 192
 193 =head1 DESCRIPTION
 194
 195 This is a role to describe operations on the Array type.
 196
 197 =head1 METHODS
 198
 199 =over 4
 200
 201 =item B<pop>
 202
 203 =item B<push ($value)>
 204
 205 =item B<shift>
 206
 207 =item B<unshift ($value)>
 208
 209 =item B<delete ($index)>
 210
 211 =item B<sprintf ($format_string)>
 212
 213 =item B<slice (@indices)>
 214
 215 =item B<flatten>
 216
 217 =item B<flatten_deep ($depth)>
 218
 219 =back
 220
 221 =head2 Indexed implementation
 222
 223 =over 4
 224
 225 =item B<at ($index)>
 226
 227 =item B<put ($index, $value)>
 228
 229 =item B<exists ($index)>
 230
 231 =item B<keys>
 232
 233 =item B<values>
 234
 235 =item B<kv>
 236
 237 =back
 238
 239 =head2 List implementation
 240
 241 =over 4
 242
 243 =item B<head>
 244
 245 =item B<tail>
 246
 247 =item B<join (?$seperator)>
 248
 249 =item B<length>
 250
 251 =item B<map (\&block)>
 252
 253 =item B<grep (\&block)>
 254
 255 Note that, in both the above, $_ is in scope within the code block, as well as
 256 being passed as $_[0]. As per CORE::map and CORE::grep, $_ is an alias to
 257 the list value, so can be used to to modify the list, viz:
 258
 259     use Moose::Autobox;
 260
 261     my $foo = [1, 2, 3];
 262     $foo->map( sub {$_++} );
 263     print $foo->dump;
 264
 265 yields
 266
 267    $VAR1 = [
 268              2,
 269              3,
 270              4
 271            ];
 272
 273 =item B<reverse>
 274
 275 =item B<sort (?\&block)>
 276
 277 =back
 278
 279 =head2 Junctions
 280
 281 =over 4
 282
 283 =item B<all>
 284
 285 =item B<any>
 286
 287 =item B<none>
 288
 289 =item B<one>
 290
 291 =back
 292
 293 =over 4
 294
 295 =item B<meta>
 296
 297 =item B<print>
 298
 299 =item B<say>
 300
 301 =back
 302
 303 =head1 BUGS
 304
 305 All complex software has bugs lurking in it, and this module is no
 306 exception. If you find a bug please either email me, or add the bug
 307 to cpan-RT.
 308
 309 =head1 AUTHOR
 310
 311 Stevan Little E<lt>stevan@iinteractive.comE<gt>
 312
 313 =head1 COPYRIGHT AND LICENSE
 314
 315 Copyright 2006-2008 by Infinity Interactive, Inc.
 316
 317 L<http://www.iinteractive.com>
 318
 319 This library is free software; you can redistribute it and/or modify
 320 it under the same terms as Perl itself.
 321
 322 =cut