lib/Moose/Autobox/Array.pm

   1 package Moose::Autobox::Array;
   2 use Moose::Role 'with';
   3 use Perl6::Junction;
   4 use Moose::Autobox;
   5
   6 our $VERSION = '0.03';
   7
   8 with 'Moose::Autobox::Ref',
   9      'Moose::Autobox::List',
  10      'Moose::Autobox::Indexed';
  11
  12 ## Array Interface
  13
  14 sub pop {
  15     my ($array) = @_;
  16     CORE::pop @$array;
  17 }
  18
  19 sub push {
  20     my ($array, @rest) = @_;
  21     CORE::push @$array, @rest;
  22     $array;
  23 }
  24
  25 sub unshift {
  26     my ($array, @rest) = @_;
  27     CORE::unshift @$array, @rest;
  28     $array;
  29 }
  30
  31 sub delete {
  32     my ($array, $index) = @_;
  33     CORE::delete $array->[$index];
  34 }
  35
  36 sub shift {
  37     my ($array) = @_;
  38     CORE::shift @$array;
  39 }
  40
  41 sub slice {
  42     my ($array, $indicies) = @_;
  43     [ @{$array}[ @{$indicies} ] ];
  44 }
  45
  46 # NOTE:
  47 # sprintf args need to be reversed,
  48 # because the invocant is the array
  49 sub sprintf { CORE::sprintf $_[1], @{$_[0]} }
  50
  51 ## ::List interface implementation
  52
  53 sub head { $_[0]->[0] }
  54 sub tail { [ @{$_[0]}[ 1 .. $#{$_[0]} ] ] }
  55
  56 sub length {
  57     my ($array) = @_;
  58     CORE::scalar @$array;
  59 }
  60
  61 sub grep {
  62     my ($array, $sub) = @_;
  63     [ CORE::grep { $sub->($_) } @$array ];
  64 }
  65
  66 sub map {
  67     my ($array, $sub) = @_;
  68     [ CORE::map { $sub->($_) } @$array ];
  69 }
  70
  71 sub join {
  72     my ($array, $sep) = @_;
  73     $sep ||= '';
  74     CORE::join $sep, @$array;
  75 }
  76
  77 sub reverse {
  78     my ($array) = @_;
  79     [ CORE::reverse @$array ];
  80 }
  81
  82 sub sort {
  83     my ($array, $sub) = @_;
  84     $sub ||= sub { $a cmp $b };
  85     [ CORE::sort { $sub->($a, $b) } @$array ];
  86 }
  87
  88 ## ::Indexed implementation
  89
  90 sub at {
  91     my ($array, $index) = @_;
  92     $array->[$index];
  93 }
  94
  95 sub put {
  96     my ($array, $index, $value) = @_;
  97     $array->[$index] = $value;
  98 }
  99
 100 sub exists {
 101     my ($array, $index) = @_;
 102     CORE::exists $array->[$index];
 103 }
 104
 105 sub keys {
 106     my ($array) = @_;
 107     [ 0 .. $#{$array} ];
 108 }
 109
 110 sub values {
 111     my ($array) = @_;
 112     [ @$array ];
 113 }
 114
 115 sub kv {
 116     my ($array) = @_;
 117     $array->keys->map(sub { [ $_, $array->[$_] ] });
 118 }
 119
 120 ## Junctions
 121
 122 sub all {
 123     my ($array) = @_;
 124     return Perl6::Junction::All->all(@$array);
 125 }
 126
 127 sub any {
 128     my ($array) = @_;
 129     return Perl6::Junction::Any->any(@$array);
 130 }
 131
 132 sub none {
 133     my ($array) = @_;
 134     return Perl6::Junction::None->none(@$array);
 135 }
 136
 137 sub one {
 138     my ($array) = @_;
 139     return Perl6::Junction::One->one(@$array);
 140 }
 141
 142 1;
 143
 144 __END__
 145
 146 =pod
 147
 148 =head1 NAME
 149
 150 Moose::Autobox::Array - the Array role
 151
 152 =head1 SYNOPOSIS
 153
 154   use Moose::Autobox;
 155
 156   [ 1..5 ]->isa('ARRAY'); # true
 157   [ a..z ]->does('Moose::Autobox::Array'); # true
 158   [ 0..2 ]->does('Moose::Autobox::List'); # true
 159
 160   print "Squares: " . [ 1 .. 10 ]->map(sub { $_ * $_ })->join(', ');
 161
 162   print [ 1, 'number' ]->sprintf('%d is the loneliest %s');
 163
 164   print ([ 1 .. 5 ]->any == 3) ? 'true' : 'false'; # prints 'true'
 165
 166 =head1 DESCRIPTION
 167
 168 This is a role to describe operations on the Array type.
 169
 170 =head1 METHODS
 171
 172 =over 4
 173
 174 =item B<pop>
 175
 176 =item B<push ($value)>
 177
 178 =item B<shift>
 179
 180 =item B<unshift ($value)>
 181
 182 =item B<delete ($index)>
 183
 184 =item B<sprintf ($format_string)>
 185
 186 =item B<slice (@indices)>
 187
 188 =back
 189
 190 =head2 Indexed implementation
 191
 192 =over 4
 193
 194 =item B<at ($index)>
 195
 196 =item B<put ($index, $value)>
 197
 198 =item B<exists ($index)>
 199
 200 =item B<keys>
 201
 202 =item B<values>
 203
 204 =item B<kv>
 205
 206 =back
 207
 208 =head2 List implementation
 209
 210 =over 4
 211
 212 =item B<head>
 213
 214 =item B<tail>
 215
 216 =item B<join (?$seperator)>
 217
 218 =item B<length>
 219
 220 =item B<map (\&block)>
 221
 222 =item B<grep (\&block)>
 223
 224 =item B<reverse>
 225
 226 =item B<sort (?\&block)>
 227
 228 =back
 229
 230 =head2 Junctions
 231
 232 =over 4
 233
 234 =item B<all>
 235
 236 =item B<any>
 237
 238 =item B<none>
 239
 240 =item B<one>
 241
 242 =back
 243
 244 =over 4
 245
 246 =item B<meta>
 247
 248 =back
 249
 250 =head1 BUGS
 251
 252 All complex software has bugs lurking in it, and this module is no
 253 exception. If you find a bug please either email me, or add the bug
 254 to cpan-RT.
 255
 256 =head1 AUTHOR
 257
 258 Stevan Little E<lt>stevan@iinteractive.comE<gt>
 259
 260 =head1 COPYRIGHT AND LICENSE
 261
 262 Copyright 2006 by Infinity Interactive, Inc.
 263
 264 L<http://www.iinteractive.com>
 265
 266 This library is free software; you can redistribute it and/or modify
 267 it under the same terms as Perl itself.
 268
 269 =cut