lib/Moose/Autobox/Array.pm

   1 package Moose::Autobox::Array;
   2 use Moose::Role 'with';
   3 use Perl6::Junction;
   4 use autobox;
   5
   6 our $VERSION = '0.02';
   7
   8 with 'Moose::Autobox::Ref',
   9      'Moose::Autobox::List',
  10      'Moose::Autobox::Indexed';
  11
  12 ## Array Interface
  13
  14 sub pop {
  15     my ($array) = @_;
  16     CORE::pop @$array;
  17 }
  18
  19 sub push {
  20     my ($array, @rest) = @_;
  21     CORE::push @$array, @rest;
  22     $array;
  23 }
  24
  25 sub unshift {
  26     my ($array, @rest) = @_;
  27     CORE::unshift @$array, @rest;
  28     $array;
  29 }
  30
  31 sub delete {
  32     my ($array, $index) = @_;
  33     CORE::delete $array->[$index];
  34 }
  35
  36 sub shift {
  37     my ($array) = @_;
  38     CORE::shift @$array;
  39 }
  40
  41 sub slice {
  42     my ($array, $indicies) = @_;
  43     [ @{$array}[ @{$indicies} ] ];
  44 }
  45
  46 # NOTE:
  47 # sprintf args need to be reversed,
  48 # because the invocant is the array
  49 sub sprintf { CORE::sprintf $_[1], @{$_[0]} }
  50
  51 ## ::List interface implementation
  52
  53 sub head { $_[0]->[0] }
  54 sub tail { [ @{$_[0]}[ 1 .. $#{$_[0]} ] ] }
  55
  56 sub length {
  57     my ($array) = @_;
  58     CORE::scalar @$array;
  59 }
  60
  61 sub grep {
  62     my ($array, $sub) = @_;
  63     [ CORE::grep { $sub->($_) } @$array ];
  64 }
  65
  66 sub map {
  67     my ($array, $sub) = @_;
  68     [ CORE::map { $sub->($_) } @$array ];
  69 }
  70
  71 sub join {
  72     my ($array, $sep) = @_;
  73     $sep ||= '';
  74     CORE::join $sep, @$array;
  75 }
  76
  77 sub reverse {
  78     my ($array) = @_;
  79     [ CORE::reverse @$array ];
  80 }
  81
  82 sub sort {
  83     my ($array, $sub) = @_;
  84     $sub ||= sub { $a cmp $b };
  85     [ CORE::sort { $sub->($a, $b) } @$array ];
  86 }
  87
  88 ## ::Indexed implementation
  89
  90 sub at {
  91     my ($array, $index) = @_;
  92     $array->[$index];
  93 }
  94
  95 sub put {
  96     my ($array, $index, $value) = @_;
  97     $array->[$index] = $value;
  98 }
  99
 100 sub exists {
 101     my ($array, $index) = @_;
 102     CORE::exists $array->[$index];
 103 }
 104
 105 sub keys {
 106     my ($array) = @_;
 107     [ 0 .. $#{$array} ];
 108 }
 109
 110 sub values {
 111     my ($array) = @_;
 112     [ @$array ];
 113 }
 114
 115 sub kv {
 116     my ($array) = @_;
 117     $array->keys->map(sub { [ $_, $array->[$_] ] });
 118 }
 119
 120 ## Junctions
 121
 122 sub all {
 123     my ($array) = @_;
 124     return Perl6::Junction::All->all(@$array);
 125 }
 126
 127 sub any {
 128     my ($array) = @_;
 129     return Perl6::Junction::Any->any(@$array);
 130 }
 131
 132 sub none {
 133     my ($array) = @_;
 134     return Perl6::Junction::None->none(@$array);
 135 }
 136
 137 sub one {
 138     my ($array) = @_;
 139     return Perl6::Junction::One->one(@$array);
 140 }
 141
 142 1;
 143
 144 __END__
 145
 146 =pod
 147
 148 =head1 NAME
 149
 150 Moose::Autobox::Array - the Array role
 151
 152 =head1 SYNOPOSIS
 153
 154   use Moose::Autobox;
 155   use autobox;
 156
 157   [ 1..5 ]->isa('ARRAY'); # true
 158   [ a..z ]->does('Moose::Autobox::Array'); # true
 159   [ 0..2 ]->does('Moose::Autobox::List'); # true
 160
 161   print "Squares: " . [ 1 .. 10 ]->map(sub { $_ * $_ })->join(', ');
 162
 163   print [ 1, 'number' ]->sprintf('%d is the loneliest %s');
 164
 165   print ([ 1 .. 5 ]->any == 3) ? 'true' : 'false'; # prints 'true'
 166
 167 =head1 DESCRIPTION
 168
 169 This is a role to describe operations on the Array type.
 170
 171 =head1 METHODS
 172
 173 =over 4
 174
 175 =item B<pop>
 176
 177 =item B<push ($value)>
 178
 179 =item B<shift>
 180
 181 =item B<unshift ($value)>
 182
 183 =item B<delete ($index)>
 184
 185 =item B<sprintf ($format_string)>
 186
 187 =item B<slice (@indices)>
 188
 189 =back
 190
 191 =head2 Indexed implementation
 192
 193 =over 4
 194
 195 =item B<at ($index)>
 196
 197 =item B<put ($index, $value)>
 198
 199 =item B<exists ($index)>
 200
 201 =item B<keys>
 202
 203 =item B<values>
 204
 205 =item B<kv>
 206
 207 =back
 208
 209 =head2 List implementation
 210
 211 =over 4
 212
 213 =item B<head>
 214
 215 =item B<tail>
 216
 217 =item B<join (?$seperator)>
 218
 219 =item B<length>
 220
 221 =item B<map (\&block)>
 222
 223 =item B<grep (\&block)>
 224
 225 =item B<reverse>
 226
 227 =item B<sort (?\&block)>
 228
 229 =back
 230
 231 =head2 Junctions
 232
 233 =over 4
 234
 235 =item B<all>
 236
 237 =item B<any>
 238
 239 =item B<none>
 240
 241 =item B<one>
 242
 243 =back
 244
 245 =over 4
 246
 247 =item B<meta>
 248
 249 =back
 250
 251 =head1 BUGS
 252
 253 All complex software has bugs lurking in it, and this module is no
 254 exception. If you find a bug please either email me, or add the bug
 255 to cpan-RT.
 256
 257 =head1 AUTHOR
 258
 259 Stevan Little E<lt>stevan@iinteractive.comE<gt>
 260
 261 =head1 COPYRIGHT AND LICENSE
 262
 263 Copyright 2006 by Infinity Interactive, Inc.
 264
 265 L<http://www.iinteractive.com>
 266
 267 This library is free software; you can redistribute it and/or modify
 268 it under the same terms as Perl itself.
 269
 270 =cut