t/accessor-weaken.t

   1 use strictures 1;
   2 use Test::More;
   3
   4 {
   5   package Foo;
   6
   7   use Moo;
   8
   9   has one => (is => 'ro', weak_ref => 1);
  10
  11   package Foo2;
  12
  13   use Moo;
  14
  15   has one => (is => 'lazy', weak_ref => 1, default => sub { {} });
  16 }
  17
  18 my $ref = {};
  19 my $foo = Foo->new(one => $ref);
  20 is($foo->one, $ref, 'value present');
  21 ok(Scalar::Util::isweak($foo->{one}), 'value weakened');
  22 undef $ref;
  23 ok(!defined $foo->{one}, 'weak value gone');
  24
  25 my $foo2 = Foo2->new;
  26 ok(my $ref2 = $foo2->one, 'value returned');
  27 ok(Scalar::Util::isweak($foo2->{one}), 'value weakened');
  28 undef $ref2;
  29 ok(!defined $foo->{one}, 'weak value gone');
  30
  31 # test readonly SVs
  32 sub mk_ref { \ 'yay' };
  33 my $foo_ro = eval { Foo->new(one => mk_ref()) };
  34 if ($] < 5.008003) {
  35   like(
  36     $@,
  37     qr/\QReference to readonly value in "one" can not be weakened on Perl < 5.8.3/,
  38     'Expected exception thrown on old perls'
  39   );
  40 }
  41 elsif ($^O eq 'cygwin' and $] < 5.012000) {
  42   SKIP: { skip 'Static coderef reaping seems nonfunctional on cygwin < 5.12', 1 }
  43 }
  44 else {
  45   is(${$foo_ro->one},'yay', 'value present');
  46   ok(Scalar::Util::isweak($foo_ro->{one}), 'value weakened');
  47
  48   { no warnings 'redefine'; *mk_ref = sub {} }
  49   ok (!defined $foo_ro->{one}, 'optree reaped, ro static value gone');
  50 }
  51
  52 done_testing;