t/accessor-default.t

   1 use strictures 1;
   2 use Test::More;
   3
   4 my $c_ran;
   5 {
   6   package Foo;
   7
   8   use Sub::Quote;
   9   use Moo;
  10
  11   has one => (is => 'ro', lazy => 1, default => quote_sub q{ {} });
  12   has two => (is => 'ro', lazy => 1, builder => '_build_two');
  13   sub _build_two { {} }
  14   has three => (is => 'ro', default => quote_sub q{ {} });
  15   has four => (is => 'ro', builder => '_build_four');
  16   sub _build_four { {} }
  17   has five => (is => 'ro', init_arg => undef, default => sub { {} });
  18   has six => (is => 'ro', builder => 1);
  19   sub _build_six { {} }
  20   has seven => (is => 'ro', required => 1, default => quote_sub q{ {} });
  21   has eight => (is => 'ro', builder => '_build_eight', coerce => sub { $c_ran = 1; $_[0] });
  22   sub _build_eight { {} }
  23   has nine => (is => 'lazy', coerce => sub { $c_ran = 1; $_[0] });
  24   sub _build_nine { {} }
  25 }
  26
  27 sub check {
  28   my ($attr, @h) = @_;
  29
  30   is_deeply($h[$_], {}, "${attr}: empty hashref \$h[$_]") for 0..1;
  31
  32   isnt($h[0],$h[1], "${attr}: not the same hashref");
  33 }
  34
  35 check one => map Foo->new->one, 1..2;
  36
  37 check two => map Foo->new->two, 1..2;
  38
  39 check three => map Foo->new->{three}, 1..2;
  40
  41 check four => map Foo->new->{four}, 1..2;
  42
  43 check five => map Foo->new->{five}, 1..2;
  44
  45 check six => map Foo->new->{six}, 1..2;
  46
  47 check seven => map Foo->new->{seven}, 1..2;
  48
  49 check eight => map Foo->new->{eight}, 1..2;
  50 ok($c_ran, 'coerce defaults');
  51
  52 $c_ran = 0;
  53
  54 check nine => map Foo->new->nine, 1..2;
  55 ok($c_ran, 'coerce lazy default');
  56
  57 done_testing;