lib/Sub/Quote.pm

   1 package Sub::Quote;
   2
   3 use strictures 1;
   4
   5 sub _clean_eval { eval $_[0] }
   6
   7 use Sub::Defer;
   8 use B 'perlstring';
   9 use base qw(Exporter);
  10
  11 our @EXPORT = qw(quote_sub unquote_sub);
  12
  13 our %QUOTE_OUTSTANDING;
  14
  15 our %QUOTED;
  16
  17 sub _unquote_all_outstanding {
  18   return unless %QUOTE_OUTSTANDING;
  19   my ($assembled_code, @assembled_captures, @localize_these) = '';
  20   foreach my $outstanding (keys %QUOTE_OUTSTANDING) {
  21     my ($name, $code, $captures) = @{$QUOTE_OUTSTANDING{$outstanding}};
  22
  23     push @localize_these, $name if $name;
  24
  25     my $make_sub = "{\n";
  26
  27     if (keys %$captures) {
  28       my $ass_cap_count = @assembled_captures;
  29       $make_sub .= join(
  30         "\n",
  31         map {
  32           /^([\@\%\$])/
  33             or die "capture key should start with \@, \% or \$: $_";
  34           qq{  my ${_} = ${1}{\$_[1][${ass_cap_count}]{${\perlstring $_}}};\n};
  35         } keys %$captures
  36       );
  37       push @assembled_captures, $captures;
  38     }
  39
  40     my $o_quoted = perlstring $outstanding;
  41     $make_sub .= (
  42       $name
  43           # disable the 'variable $x will not stay shared' warning since
  44           # we're not letting it escape from this scope anyway so there's
  45           # nothing trying to share it
  46         ? "  no warnings 'closure';\n  sub ${name} {\n"
  47         : "  \$Sub::Quote::QUOTED{${o_quoted}}[3] = sub {\n"
  48     );
  49     $make_sub .= $code;
  50     $make_sub .= "  }".($name ? '' : ';')."\n";
  51     if ($name) {
  52       $make_sub .= "  \$Sub::Quote::QUOTED{${o_quoted}}[3] = \\&${name}\n";
  53     }
  54     $make_sub .= "}\n";
  55     $assembled_code .= $make_sub;
  56   }
  57   my $debug_code = $assembled_code;
  58   if (@localize_these) {
  59     $debug_code =
  60       "# localizing: ".join(', ', @localize_these)."\n"
  61       .$assembled_code;
  62     $assembled_code = join("\n",
  63       (map { "local *${_};" } @localize_these),
  64       'eval '.perlstring($assembled_code).'; die $@ if $@;'
  65     );
  66   } else {
  67     $ENV{SUB_QUOTE_DEBUG} && warn $assembled_code;
  68   }
  69   $assembled_code .= "\n1;";
  70   unless (_clean_eval $assembled_code, \@assembled_captures) {
  71     die "Eval went very, very wrong:\n\n${debug_code}\n\n$@";
  72   }
  73   $ENV{SUB_QUOTE_DEBUG} && warn $debug_code;
  74   %QUOTE_OUTSTANDING = ();
  75 }
  76
  77 sub quote_sub {
  78   # HOLY DWIMMERY, BATMAN!
  79   # $name => $code => \%captures => \%options
  80   # $name => $code => \%captures
  81   # $name => $code
  82   # $code => \%captures => \%options
  83   # $code
  84   my $options =
  85     (ref($_[-1]) eq 'HASH' and ref($_[-2]) eq 'HASH')
  86       ? pop
  87       : {};
  88   my $captures = pop if ref($_[-1]) eq 'HASH';
  89   my $code = pop;
  90   my $name = $_[0];
  91   my $outstanding;
  92   my $deferred = defer_sub +($options->{no_install} ? undef : $name) => sub {
  93     unquote_sub($outstanding);
  94   };
  95   $outstanding = "$deferred";
  96   $QUOTE_OUTSTANDING{$outstanding} = $QUOTED{$outstanding} = [
  97     $name, $code, $captures
  98   ];
  99   return $deferred;
 100 }
 101
 102 sub quoted_from_sub {
 103   my ($sub) = @_;
 104   $QUOTED{$sub};
 105 }
 106
 107 sub unquote_sub {
 108   my ($sub) = @_;
 109   _unquote_all_outstanding;
 110   $QUOTED{$sub}[3];
 111 }
 112
 113 1;