lib/Sub/Quote.pm

   1 package Sub::Quote;
   2
   3 use strictures 1;
   4
   5 sub _clean_eval { eval $_[0] }
   6
   7 use Sub::Defer;
   8 use B 'perlstring';
   9 use base qw(Exporter);
  10
  11 our @EXPORT = qw(quote_sub unquote_sub);
  12
  13 our %QUOTE_OUTSTANDING;
  14
  15 our %QUOTED;
  16
  17 sub _unquote_all_outstanding {
  18   return unless %QUOTE_OUTSTANDING;
  19   my ($assembled_code, @assembled_captures, @localize_these) = '';
  20   foreach my $outstanding (keys %QUOTE_OUTSTANDING) {
  21     my ($name, $code, $captures) = @{$QUOTE_OUTSTANDING{$outstanding}};
  22
  23     push @localize_these, $name if $name;
  24
  25     my $make_sub = "{\n";
  26
  27     if (keys %$captures) {
  28       my $ass_cap_count = @assembled_captures;
  29       $make_sub .= join(
  30         "\n",
  31         map {
  32           /^([\@\%\$])/
  33             or die "capture key should start with \@, \% or \$: $_";
  34           qq{  my ${_} = ${1}{\$_[1][${ass_cap_count}]{${\perlstring $_}}};\n};
  35         } keys %$captures
  36       );
  37       push @assembled_captures, $captures;
  38     }
  39
  40     my $o_quoted = perlstring $outstanding;
  41     $make_sub .= (
  42       $name
  43         ? "  no warnings 'closure';\n  sub ${name} {\n"
  44         : "  \$Sub::Quote::QUOTED{${o_quoted}}[3] = sub {\n"
  45     );
  46     $make_sub .= $code;
  47     $make_sub .= "  }".($name ? '' : ';')."\n";
  48     if ($name) {
  49       $make_sub .= "  \$Sub::Quote::QUOTED{${o_quoted}}[3] = \\&${name}\n";
  50     }
  51     $make_sub .= "}\n";
  52     $assembled_code .= $make_sub;
  53   }
  54   if (@localize_these) {
  55     $assembled_code = join("\n",
  56       (map { "local *${_};" } @localize_these),
  57       'eval '.perlstring $assembled_code
  58     );
  59   }
  60   $ENV{SUB_QUOTE_DEBUG} && warn $assembled_code;
  61   _clean_eval $assembled_code, \@assembled_captures;
  62   if ($@) {
  63     die "Eval went very, very wrong:\n\n${assembled_code}\n\n$@";
  64   }
  65   %QUOTE_OUTSTANDING = ();
  66 }
  67
  68 sub quote_sub {
  69   # HOLY DWIMMERY, BATMAN!
  70   # $name => $code => \%captures
  71   # $name => $code
  72   # $code => \%captures
  73   # $code
  74   my $captures = pop if ref($_[-1]) eq 'HASH';
  75   my $code = pop;
  76   my $name = $_[0];
  77   my $outstanding;
  78   my $deferred = defer_sub $name => sub {
  79     unquote_sub($outstanding);
  80   };
  81   $outstanding = "$deferred";
  82   $QUOTE_OUTSTANDING{$outstanding} = $QUOTED{$outstanding} = [
  83     $name, $code, $captures
  84   ];
  85   return $deferred;
  86 }
  87
  88 sub quoted_from_sub {
  89   my ($sub) = @_;
  90   $QUOTED{$sub};
  91 }
  92
  93 sub unquote_sub {
  94   my ($sub) = @_;
  95   _unquote_all_outstanding;
  96   $QUOTED{$sub}[3];
  97 }
  98
  99 1;