lib/Sub/Quote.pm

   1 package Sub::Quote;
   2
   3 use strictures 1;
   4
   5 sub _clean_eval { eval $_[0] }
   6
   7 use Sub::Defer;
   8 use B 'perlstring';
   9 use Scalar::Util qw(weaken);
  10 use base qw(Exporter);
  11
  12 our @EXPORT = qw(quote_sub unquote_sub quoted_from_sub);
  13
  14 our %QUOTE_OUTSTANDING;
  15
  16 our %QUOTED;
  17
  18 our %WEAK_REFS;
  19
  20 sub capture_unroll {
  21   my ($from, $captures, $indent) = @_;
  22   join(
  23     '',
  24     map {
  25       /^([\@\%\$])/
  26         or die "capture key should start with \@, \% or \$: $_";
  27       (' ' x $indent).qq{my ${_} = ${1}{${from}->{${\perlstring $_}}};\n};
  28     } keys %$captures
  29   );
  30 }
  31
  32 sub inlinify {
  33   my ($code, $args, $extra, $local) = @_;
  34   my $do = 'do { '.($extra||'');
  35   if (my ($code_args, $body) = $code =~ / +my \(([^)]+)\) = \@_;(.*)$/s) {
  36     if ($code_args eq $args) {
  37       $do.$body.' }'
  38     } else {
  39       $do.'my ('.$code_args.') = ('.$args.'); '.$body.' }';
  40     }
  41   } else {
  42     $do.($local ? 'local ' : '').'@_ = ('.$args.'); '.$code.' }';
  43   }
  44 }
  45
  46 sub _unquote_all_outstanding {
  47   return unless %QUOTE_OUTSTANDING;
  48   my ($assembled_code, @assembled_captures, @localize_these) = '';
  49   # we sort the keys in order to make debugging more predictable
  50   foreach my $outstanding (sort keys %QUOTE_OUTSTANDING) {
  51     my ($name, $code, $captures) = @{$QUOTE_OUTSTANDING{$outstanding}};
  52
  53     push @localize_these, $name if $name;
  54
  55     my $make_sub = "{\n";
  56
  57     if (keys %$captures) {
  58       my $ass_cap_count = @assembled_captures;
  59       $make_sub .= capture_unroll("\$_[1][${ass_cap_count}]", $captures, 2);
  60       push @assembled_captures, $captures;
  61     }
  62
  63     my $o_quoted = perlstring $outstanding;
  64     $make_sub .= (
  65       $name
  66           # disable the 'variable $x will not stay shared' warning since
  67           # we're not letting it escape from this scope anyway so there's
  68           # nothing trying to share it
  69         ? "  no warnings 'closure';\n  sub ${name} {\n"
  70         : "  \$Sub::Quote::QUOTED{${o_quoted}}[3] = sub {\n"
  71     );
  72     $make_sub .= $code;
  73     $make_sub .= "  }".($name ? '' : ';')."\n";
  74     if ($name) {
  75       $make_sub .= "  \$Sub::Quote::QUOTED{${o_quoted}}[3] = \\&${name}\n";
  76     }
  77     $make_sub .= "}\n";
  78     $assembled_code .= $make_sub;
  79   }
  80   my $debug_code = $assembled_code;
  81   if (@localize_these) {
  82     $debug_code =
  83       "# localizing: ".join(', ', @localize_these)."\n"
  84       .$assembled_code;
  85     $assembled_code = join("\n",
  86       (map { "local *${_};" } @localize_these),
  87       'eval '.perlstring($assembled_code).'; die $@ if $@;'
  88     );
  89   } else {
  90     $ENV{SUB_QUOTE_DEBUG} && warn $assembled_code;
  91   }
  92   $assembled_code .= "\n1;";
  93   unless (_clean_eval $assembled_code, \@assembled_captures) {
  94     die "Eval went very, very wrong:\n\n${debug_code}\n\n$@";
  95   }
  96   $ENV{SUB_QUOTE_DEBUG} && warn $debug_code;
  97   %QUOTE_OUTSTANDING = ();
  98 }
  99
 100 sub quote_sub {
 101   # HOLY DWIMMERY, BATMAN!
 102   # $name => $code => \%captures => \%options
 103   # $name => $code => \%captures
 104   # $name => $code
 105   # $code => \%captures => \%options
 106   # $code
 107   my $options =
 108     (ref($_[-1]) eq 'HASH' and ref($_[-2]) eq 'HASH')
 109       ? pop
 110       : {};
 111   my $captures = pop if ref($_[-1]) eq 'HASH';
 112   undef($captures) if $captures && !keys %$captures;
 113   my $code = pop;
 114   my $name = $_[0];
 115   my $outstanding;
 116   my $deferred = defer_sub +($options->{no_install} ? undef : $name) => sub {
 117     unquote_sub($outstanding);
 118   };
 119   $outstanding = "$deferred";
 120   $QUOTE_OUTSTANDING{$outstanding} = $QUOTED{$outstanding} = [
 121     $name, $code, $captures
 122   ];
 123   weaken($WEAK_REFS{$outstanding} = $deferred);
 124   return $deferred;
 125 }
 126
 127 sub quoted_from_sub {
 128   my ($sub) = @_;
 129   $WEAK_REFS{$sub||''} and $QUOTED{$sub||''};
 130 }
 131
 132 sub unquote_sub {
 133   my ($sub) = @_;
 134   _unquote_all_outstanding;
 135   $QUOTED{$sub}[3];
 136 }
 137
 138 1;
 139
 140 =head1 NAME
 141
 142 Sub::Quote - efficient generation of subroutines via string eval
 143
 144 =head1 SYNOPSIS
 145
 146  package Silly;
 147
 148  use Sub::Quote qw(quote_sub unquote_sub quoted_from_sub);
 149
 150  quote_sub 'Silly::kitty', q{ print "meow" };
 151
 152  quote_sub 'Silly::doggy', q{ print "woof" };
 153
 154  my $sound; $$sound = 0;
 155
 156  quote_sub 'Silly::dagron',
 157    q{ print ++$$sound % 2 ? 'burninate' : 'roar' },
 158    { '$sound' => \$sound };
 159
 160 And elsewhere:
 161
 162  Silly->kitty;  # meow
 163  Silly->doggy;  # woof
 164  Silly->dagron; # burninate
 165  Silly->dagron; # roar
 166  Silly->dagron; # burninate
 167
 168 =head1 DESCRIPTION
 169
 170 This package provides performant ways to generate subroutines from strings.
 171
 172 =head1 SUBROUTINES
 173
 174 =head2 quote_sub
 175
 176  my $coderef = quote_sub 'Foo:bar', q{ print $x++ . "\n" }, { '$x' => \0 };
 177
 178 Arguments: ?$name, $code, ?\%captures, ?\%options
 179
 180 C<$name> is the subroutine where the coderef will be installed.
 181
 182 C<$code> is a string that will be turned into code.
 183
 184 C<\%captures> is a hashref of variables that will be made available to the
 185 code.  See the L</SYNOPSIS>'s C<Silly::dagron> for an example using captures.
 186
 187 =head3 options
 188
 189 =over 2
 190
 191 =item * no_install
 192
 193 B<Boolean>.  Set this option to not install the generated coderef into the
 194 passed subroutine name on undefer.
 195
 196 =back
 197
 198 =head2 unquote_sub
 199
 200  my $coderef = unquote_sub $sub;
 201
 202 Forcibly replace subroutine with actual code.  Note that for performance
 203 reasons all quoted subs declared so far will be globally unquoted/parsed in
 204 a single eval. This means that if you have a syntax error in one of your
 205 quoted subs you may find out when some other sub is unquoted.
 206
 207 If $sub is not a quoted sub, this is a no-op.
 208
 209 =head2 quoted_from_sub
 210
 211  my $data = quoted_from_sub $sub;
 212
 213  my ($name, $code, $captures, $compiled_sub) = @$data;
 214
 215 Returns original arguments to quote_sub, plus the compiled version if this
 216 sub has already been unquoted.
 217
 218 Note that $sub can be either the original quoted version or the compiled
 219 version for convenience.
 220
 221 =head2 inlinify
 222
 223  my $prelude = capture_unroll {
 224    '$x' => 1,
 225    '$y' => 2,
 226  };
 227
 228  my $inlined_code = inlinify q{
 229    my ($x, $y) = @_;
 230
 231    print $x + $y . "\n";
 232  }, '$x, $y', $prelude;
 233
 234 Takes a string of code, a string of arguments, a string of code which acts as a
 235 "prelude", and a B<Boolean> representing whether or not to localize the
 236 arguments.
 237
 238 =head2 capture_unroll
 239
 240  my $prelude = capture_unroll {
 241    '$x' => 1,
 242    '$y' => 2,
 243  };
 244
 245 Generates a snippet of code which is suitable to be used as a prelude for
 246 L</inlinify>.  The keys are the names of the variables and the values are (duh)
 247 the values.  Note that references work as values.