lib/Sub/Quote.pm

   1 package Sub::Quote;
   2
   3 use strictures 1;
   4
   5 sub _clean_eval { eval $_[0] }
   6
   7 use Sub::Defer;
   8 use B 'perlstring';
   9 use base qw(Exporter);
  10
  11 our @EXPORT = qw(quote_sub unquote_sub quoted_from_sub);
  12
  13 our %QUOTE_OUTSTANDING;
  14
  15 our %QUOTED;
  16
  17 sub capture_unroll {
  18   my ($from, $captures, $indent) = @_;
  19   join(
  20     '',
  21     map {
  22       /^([\@\%\$])/
  23         or die "capture key should start with \@, \% or \$: $_";
  24       (' ' x $indent).qq{my ${_} = ${1}{${from}->{${\perlstring $_}}};\n};
  25     } keys %$captures
  26   );
  27 }
  28
  29 sub _unquote_all_outstanding {
  30   return unless %QUOTE_OUTSTANDING;
  31   my ($assembled_code, @assembled_captures, @localize_these) = '';
  32   foreach my $outstanding (keys %QUOTE_OUTSTANDING) {
  33     my ($name, $code, $captures) = @{$QUOTE_OUTSTANDING{$outstanding}};
  34
  35     push @localize_these, $name if $name;
  36
  37     my $make_sub = "{\n";
  38
  39     if (keys %$captures) {
  40       my $ass_cap_count = @assembled_captures;
  41       $make_sub .= capture_unroll("\$_[1][${ass_cap_count}]", $captures, 2);
  42       push @assembled_captures, $captures;
  43     }
  44
  45     my $o_quoted = perlstring $outstanding;
  46     $make_sub .= (
  47       $name
  48           # disable the 'variable $x will not stay shared' warning since
  49           # we're not letting it escape from this scope anyway so there's
  50           # nothing trying to share it
  51         ? "  no warnings 'closure';\n  sub ${name} {\n"
  52         : "  \$Sub::Quote::QUOTED{${o_quoted}}[3] = sub {\n"
  53     );
  54     $make_sub .= $code;
  55     $make_sub .= "  }".($name ? '' : ';')."\n";
  56     if ($name) {
  57       $make_sub .= "  \$Sub::Quote::QUOTED{${o_quoted}}[3] = \\&${name}\n";
  58     }
  59     $make_sub .= "}\n";
  60     $assembled_code .= $make_sub;
  61   }
  62   my $debug_code = $assembled_code;
  63   if (@localize_these) {
  64     $debug_code =
  65       "# localizing: ".join(', ', @localize_these)."\n"
  66       .$assembled_code;
  67     $assembled_code = join("\n",
  68       (map { "local *${_};" } @localize_these),
  69       'eval '.perlstring($assembled_code).'; die $@ if $@;'
  70     );
  71   } else {
  72     $ENV{SUB_QUOTE_DEBUG} && warn $assembled_code;
  73   }
  74   $assembled_code .= "\n1;";
  75   unless (_clean_eval $assembled_code, \@assembled_captures) {
  76     die "Eval went very, very wrong:\n\n${debug_code}\n\n$@";
  77   }
  78   $ENV{SUB_QUOTE_DEBUG} && warn $debug_code;
  79   %QUOTE_OUTSTANDING = ();
  80 }
  81
  82 sub quote_sub {
  83   # HOLY DWIMMERY, BATMAN!
  84   # $name => $code => \%captures => \%options
  85   # $name => $code => \%captures
  86   # $name => $code
  87   # $code => \%captures => \%options
  88   # $code
  89   my $options =
  90     (ref($_[-1]) eq 'HASH' and ref($_[-2]) eq 'HASH')
  91       ? pop
  92       : {};
  93   my $captures = pop if ref($_[-1]) eq 'HASH';
  94   undef($captures) if $captures && !keys %$captures;
  95   my $code = pop;
  96   my $name = $_[0];
  97   my $outstanding;
  98   my $deferred = defer_sub +($options->{no_install} ? undef : $name) => sub {
  99     unquote_sub($outstanding);
 100   };
 101   $outstanding = "$deferred";
 102   $QUOTE_OUTSTANDING{$outstanding} = $QUOTED{$outstanding} = [
 103     $name, $code, $captures
 104   ];
 105   return $deferred;
 106 }
 107
 108 sub quoted_from_sub {
 109   my ($sub) = @_;
 110   $QUOTED{$sub};
 111 }
 112
 113 sub unquote_sub {
 114   my ($sub) = @_;
 115   _unquote_all_outstanding;
 116   $QUOTED{$sub}[3];
 117 }
 118
 119 1;