lib/Role/Tiny.pm

   1 package Role::Tiny;
   2
   3 sub _getglob { \*{$_[0]} }
   4 sub _getstash { \%{"$_[0]::"} }
   5
   6 use strict;
   7 use warnings FATAL => 'all';
   8
   9 our %INFO;
  10 our %APPLIED_TO;
  11 our %COMPOSED;
  12
  13 # inlined from Moo::_Utils - update that first.
  14
  15 sub _load_module {
  16   (my $proto = $_[0]) =~ s/::/\//g;
  17   return 1 if $INC{"${proto}.pm"};
  18   # can't just ->can('can') because a sub-package Foo::Bar::Baz
  19   # creates a 'Baz::' key in Foo::Bar's symbol table
  20   return 1 if grep !/::$/, keys %{_getstash($_[0])||{}};
  21   { local $@; require "${proto}.pm"; }
  22   return 1;
  23 }
  24
  25 { # \[] is REF, not SCALAR. \v1 is VSTRING (thanks to doy for that one)
  26   my %reftypes = map +($_ => 1), qw(SCALAR REF VSTRING);
  27   sub _is_scalar_ref { $reftypes{ref($_[0])} }
  28 }
  29
  30 sub import {
  31   my $target = caller;
  32   my $me = shift;
  33   strictures->import;
  34   return if $INFO{$target}; # already exported into this package
  35   # get symbol table reference
  36   my $stash = do { no strict 'refs'; \%{"${target}::"} };
  37   # install before/after/around subs
  38   foreach my $type (qw(before after around)) {
  39     *{_getglob "${target}::${type}"} = sub {
  40       { local $@; require Class::Method::Modifiers; }
  41       push @{$INFO{$target}{modifiers}||=[]}, [ $type => @_ ];
  42     };
  43   }
  44   *{_getglob "${target}::requires"} = sub {
  45     push @{$INFO{$target}{requires}||=[]}, @_;
  46   };
  47   *{_getglob "${target}::with"} = sub {
  48     die "Only one role supported at a time by with" if @_ > 1;
  49     $me->apply_role_to_package($target, $_[0]);
  50   };
  51   # grab all *non-constant* (stash slot is not a scalarref) subs present
  52   # in the symbol table and store their refaddrs (no need to forcibly
  53   # inflate constant subs into real subs) - also add '' to here (this
  54   # is used later)
  55   @{$INFO{$target}{not_methods}={}}{
  56     '', map { *$_{CODE}||() } grep !ref($_), values %$stash
  57   } = ();
  58   # a role does itself
  59   $APPLIED_TO{$target} = { $target => undef };
  60 }
  61
  62 sub apply_role_to_package {
  63   my ($me, $to, $role) = @_;
  64
  65   _load_module($role);
  66
  67   die "This is apply_role_to_package" if ref($to);
  68   die "${role} is not a Role::Tiny" unless my $info = $INFO{$role};
  69
  70   $me->_check_requires($to, $role, @{$info->{requires}||[]});
  71
  72   $me->_install_methods($to, $role);
  73
  74   $me->_install_modifiers($to, $info->{modifiers});
  75
  76   # only add does() method to classes and only if they don't have one
  77   if (not $INFO{$to} and not $to->can('does')) {
  78     *{_getglob "${to}::does"} = \&does_role;
  79   }
  80
  81   # copy our role list into the target's
  82   @{$APPLIED_TO{$to}||={}}{keys %{$APPLIED_TO{$role}}} = ();
  83 }
  84
  85 sub apply_roles_to_object {
  86   my ($me, $object, @roles) = @_;
  87   die "No roles supplied!" unless @roles;
  88   my $class = ref($object);
  89   bless($object, $me->create_class_with_roles($class, @roles));
  90   $object;
  91 }
  92
  93 sub create_class_with_roles {
  94   my ($me, $superclass, @roles) = @_;
  95
  96   die "No roles supplied!" unless @roles;
  97
  98   my $new_name = join(
  99     '__WITH__', $superclass, my $compose_name = join '__AND__', @roles
 100   );
 101
 102   return $new_name if $COMPOSED{class}{$new_name};
 103
 104   foreach my $role (@roles) {
 105     _load_module($role);
 106     die "${role} is not a Role::Tiny" unless my $info = $INFO{$role};
 107   }
 108
 109   if ($] >= 5.010) {
 110     { local $@; require mro; }
 111   } else {
 112     { local $@; require MRO::Compat; }
 113   }
 114
 115   my @composable = map $me->_composable_package_for($_), reverse @roles;
 116
 117   *{_getglob("${new_name}::ISA")} = [ @composable, $superclass ];
 118
 119   my @info = map +($INFO{$_} ? $INFO{$_} : ()), @roles;
 120
 121   $me->_check_requires(
 122     $new_name, $compose_name,
 123     do { my %h; @h{map @{$_->{requires}||[]}, @info} = (); keys %h }
 124   );
 125
 126   *{_getglob "${new_name}::does"} = \&does_role unless $new_name->can('does');
 127
 128   @{$APPLIED_TO{$new_name}||={}}{
 129     map keys %{$APPLIED_TO{$_}}, @roles
 130   } = ();
 131
 132   $COMPOSED{class}{$new_name} = 1;
 133   return $new_name;
 134 }
 135
 136 sub _composable_package_for {
 137   my ($me, $role) = @_;
 138   my $composed_name = 'Role::Tiny::_COMPOSABLE::'.$role;
 139   return $composed_name if $COMPOSED{role}{$composed_name};
 140   $me->_install_methods($composed_name, $role);
 141   my $base_name = $composed_name.'::_BASE';
 142   *{_getglob("${composed_name}::ISA")} = [ $base_name ];
 143   my $modifiers = $INFO{$role}{modifiers}||[];
 144   my @mod_base;
 145   foreach my $modified (
 146     do { my %h; @h{map $_->[1], @$modifiers} = (); keys %h }
 147   ) {
 148     push @mod_base, "sub ${modified} { shift->next::method(\@_) }";
 149   }
 150   {
 151     local $@;
 152     eval(my $code = join "\n", "package ${base_name};", @mod_base);
 153     die "Evaling failed: $@\nTrying to eval:\n${code}" if $@;
 154   }
 155   $me->_install_modifiers($composed_name, $modifiers);
 156   $COMPOSED{role}{$composed_name} = 1;
 157   return $composed_name;
 158 }
 159
 160 sub _check_requires {
 161   my ($me, $to, $name, @requires) = @_;
 162   if (my @requires_fail = grep !$to->can($_), @requires) {
 163     # role -> role, add to requires, role -> class, error out
 164     if (my $to_info = $INFO{$to}) {
 165       push @{$to_info->{requires}||=[]}, @requires_fail;
 166     } else {
 167       die "Can't apply ${name} to ${to} - missing ".join(', ', @requires_fail);
 168     }
 169   }
 170 }
 171
 172 sub _concrete_methods_of {
 173   my ($me, $role) = @_;
 174   my $info = $INFO{$role};
 175   $info->{methods} ||= do {
 176     # grab role symbol table
 177     my $stash = do { no strict 'refs'; \%{"${role}::"}};
 178     my $not_methods = $info->{not_methods};
 179     +{
 180       # grab all code entries that aren't in the not_methods list
 181       map {
 182         my $code = *{$stash->{$_}}{CODE};
 183         # rely on the '' key we added in import for "no code here"
 184         exists $not_methods->{$code||''} ? () : ($_ => $code)
 185       } grep !ref($stash->{$_}), keys %$stash
 186     };
 187   };
 188 }
 189
 190 sub methods_provided_by {
 191   my ($me, $role) = @_;
 192   die "${role} is not a Role::Tiny" unless my $info = $INFO{$role};
 193   (keys %{$me->_concrete_methods_of($role)}, @{$info->{requires}||[]});
 194 }
 195
 196 sub _install_methods {
 197   my ($me, $to, $role) = @_;
 198
 199   my $info = $INFO{$role};
 200
 201   my $methods = $me->_concrete_methods_of($role);
 202
 203   # grab target symbol table
 204   my $stash = do { no strict 'refs'; \%{"${to}::"}};
 205
 206   # determine already extant methods of target
 207   my %has_methods;
 208   @has_methods{grep
 209     +(ref($stash->{$_}) || *{$stash->{$_}}{CODE}),
 210     keys %$stash
 211   } = ();
 212
 213   foreach my $i (grep !exists $has_methods{$_}, keys %$methods) {
 214     no warnings 'once';
 215     *{_getglob "${to}::${i}"} = $methods->{$i};
 216   }
 217 }
 218
 219 sub _install_modifiers {
 220   my ($me, $to, $modifiers) = @_;
 221   if (my $info = $INFO{$to}) {
 222     push @{$info->{modifiers}}, @{$modifiers||[]};
 223   } else {
 224     foreach my $modifier (@{$modifiers||[]}) {
 225       $me->_install_single_modifier($to, @$modifier);
 226     }
 227   }
 228 }
 229
 230 sub _install_single_modifier {
 231   my ($me, @args) = @_;
 232   Class::Method::Modifiers::install_modifier(@args);
 233 }
 234
 235 sub does_role {
 236   my ($proto, $role) = @_;
 237   return exists $APPLIED_TO{ref($proto)||$proto}{$role};
 238 }
 239
 240 1;
 241
 242 =head1 NAME
 243
 244 Role::Tiny - Roles. Like a nouvelle cusine portion size slice of Moose.
 245
 246 =head1 SYNOPSIS
 247
 248  package Some::Role;
 249
 250  use Role::Tiny;
 251
 252  sub foo { ... }
 253
 254  sub bar { ... }
 255
 256  1;
 257
 258 else where
 259
 260  package Some::Class;
 261
 262  use Role::Tiny::With;
 263
 264  # bar gets imported, but not foo
 265  with 'Some::Role';
 266
 267  sub foo { ... }
 268
 269  1;
 270
 271 =head1 DESCRIPTION
 272
 273 C<Role::Tiny> is a minimalist role composition tool.
 274
 275 =head1 ROLE COMPOSITION
 276
 277 Role composition can be thought of as much more clever and meaningful multiple
 278 inheritance.  The basics of this implementation of roles is:
 279
 280 =over 2
 281
 282 =item *
 283
 284 If a method is already defined on a class, that method will not be composed in
 285 from the role.
 286
 287 =item *
 288
 289 If a method that the role L</requires> to be implemented is not implemented,
 290 role application will fail loudly.
 291
 292 =back
 293
 294 Unlike L<Class::C3>, where the B<last> class inherited from "wins," role
 295 composition is the other way around, where first wins.  In a more complete
 296 system (see L<Moose>) roles are checked to see if they clash.  The goal of this
 297 is to be much simpler, hence disallowing composition of multiple roles at once.
 298
 299 =head1 METHODS
 300
 301 =head2 apply_role_to_package
 302
 303  Role::Tiny->apply_role_to_package('Some::Package', 'Some::Role');
 304
 305 Composes role with package.  See also L<Role::Tiny::With>.
 306
 307 =head2 apply_roles_to_object
 308
 309  Role::Tiny->apply_roles_to_object($foo, qw(Some::Role1 Some::Role2));
 310
 311 Composes roles in order into object directly.  Object is reblessed into the
 312 resulting class.
 313
 314 =head2 create_class_with_roles
 315
 316  Role::Tiny->create_class_with_roles('Some::Base', qw(Some::Role1 Some::Role2));
 317
 318 Creates a new class based on base, with the roles composed into it in order.
 319 New class is returned.
 320
 321 =head1 SUBROUTINES
 322
 323 =head2 does_role
 324
 325  if (Role::Tiny::does_role($foo, 'Some::Role')) {
 326    ...
 327  }
 328
 329 Returns true if class has been composed with role.
 330
 331 This subroutine is also installed as ->does on any class a Role::Tiny is
 332 composed into unless that class already has an ->does method, so
 333
 334   if ($foo->does_role('Some::Role')) {
 335     ...
 336   }
 337
 338 will work for classes but to test a role, one must use ::does_role directly
 339
 340 =head1 IMPORTED SUBROUTINES
 341
 342 =head2 requires
 343
 344  requires qw(foo bar);
 345
 346 Declares a list of methods that must be defined to compose role.
 347
 348 =head2 with
 349
 350  with 'Some::Role1';
 351  with 'Some::Role2';
 352
 353 Composes another role into the current role.  Only one role may be composed in
 354 at a time to allow the code to remain as simple as possible.
 355
 356 =head2 before
 357
 358  before foo => sub { ... };
 359
 360 See L<< Class::Method::Modifiers/before method(s) => sub { ... } >> for full
 361 documentation.
 362
 363 =head2 around
 364
 365  around foo => sub { ... };
 366
 367 See L<< Class::Method::Modifiers/around method(s) => sub { ... } >> for full
 368 documentation.
 369
 370 =head2 after
 371
 372  after foo => sub { ... };
 373
 374 See L<< Class::Method::Modifiers/after method(s) => sub { ... } >> for full
 375 documentation.
 376
 377 =head1 AUTHORS
 378
 379 See L<Moo> for authors.
 380
 381 =head1 COPYRIGHT AND LICENSE
 382
 383 See L<Moo> for the copyright and license.
 384
 385 =cut