lib/Moo/Role.pm

   1 package Moo::Role;
   2
   3 use strictures 1;
   4 use Moo::_Utils;
   5 use base qw(Role::Tiny);
   6
   7 require Moo::sification;
   8
   9 BEGIN { *INFO = \%Role::Tiny::INFO }
  10
  11 our %INFO;
  12
  13 sub import {
  14   my $target = caller;
  15   my ($me) = @_;
  16   strictures->import;
  17   return if $INFO{$target}; # already exported into this package
  18   # get symbol table reference
  19   my $stash = do { no strict 'refs'; \%{"${target}::"} };
  20   _install_coderef "${target}::has" => "Moo::Role::has" => sub {
  21     my ($name, %spec) = @_;
  22     ($INFO{$target}{accessor_maker} ||= do {
  23       require Method::Generate::Accessor;
  24       Method::Generate::Accessor->new
  25     })->generate_method($target, $name, \%spec);
  26     push @{$INFO{$target}{attributes}||=[]}, $name, \%spec;
  27     $me->_maybe_reset_handlemoose($target);
  28   };
  29   # install before/after/around subs
  30   foreach my $type (qw(before after around)) {
  31     *{_getglob "${target}::${type}"} = sub {
  32       require Class::Method::Modifiers;
  33       push @{$INFO{$target}{modifiers}||=[]}, [ $type => @_ ];
  34       $me->_maybe_reset_handlemoose($target);
  35     };
  36   }
  37   *{_getglob "${target}::requires"} = sub {
  38     push @{$INFO{$target}{requires}||=[]}, @_;
  39     $me->_maybe_reset_handlemoose($target);
  40   };
  41   *{_getglob "${target}::with"} = sub {
  42     $me->apply_roles_to_package($target, @_);
  43     $me->_maybe_reset_handlemoose($target);
  44   };
  45   # grab all *non-constant* (stash slot is not a scalarref) subs present
  46   # in the symbol table and store their refaddrs (no need to forcibly
  47   # inflate constant subs into real subs) - also add '' to here (this
  48   # is used later) with a map to the coderefs in case of copying or re-use
  49   my @not_methods = ('', map { *$_{CODE}||() } grep !ref($_), values %$stash);
  50   @{$INFO{$target}{not_methods}={}}{@not_methods} = @not_methods;
  51   # a role does itself
  52   $Role::Tiny::APPLIED_TO{$target} = { $target => undef };
  53
  54   if ($INC{'Moo/HandleMoose.pm'}) {
  55     Moo::HandleMoose::inject_fake_metaclass_for($target);
  56   }
  57 }
  58
  59 sub _maybe_reset_handlemoose {
  60   my ($class, $target) = @_;
  61   if ($INC{"Moo/HandleMoose.pm"}) {
  62     Moo::HandleMoose::maybe_reinject_fake_metaclass_for($target);
  63   }
  64 }
  65
  66 sub _inhale_if_moose {
  67   my ($self, $role) = @_;
  68   _load_module($role);
  69   if (!$INFO{$role} and $INC{"Moose.pm"}) {
  70     if (my $meta = Class::MOP::class_of($role)) {
  71       $INFO{$role}{methods} = {
  72         map +($_ => $role->can($_)),
  73           grep !$meta->get_method($_)->isa('Class::MOP::Method::Meta'),
  74             $meta->get_method_list
  75       };
  76       $Role::Tiny::APPLIED_TO{$role} = {
  77         map +($_->name => 1), $meta->calculate_all_roles
  78       };
  79       $INFO{$role}{requires} = [ $meta->get_required_method_list ];
  80       $INFO{$role}{attributes} = [
  81         map +($_ => $meta->get_attribute($_)), $meta->get_attribute_list
  82       ];
  83       my $mods = $INFO{$role}{modifiers} = [];
  84       foreach my $type (qw(before after around)) {
  85         my $map = $meta->${\"get_${type}_method_modifiers_map"};
  86         foreach my $method (keys %$map) {
  87           foreach my $mod (@{$map->{$method}}) {
  88             push @$mods, [ $type => $method => $mod ];
  89           }
  90         }
  91       }
  92       require Class::Method::Modifiers if @$mods;
  93       $INFO{$role}{inhaled_from_moose} = 1;
  94     }
  95   }
  96 }
  97
  98 sub _maybe_make_accessors {
  99   my ($self, $role, $target) = @_;
 100   my $m;
 101   if ($INFO{$role}{inhaled_from_moose}
 102       or $INC{"Moo.pm"}
 103       and $m = Moo->_accessor_maker_for($target)
 104       and ref($m) ne 'Method::Generate::Accessor') {
 105     $self->_make_accessors($role, $target);
 106   }
 107 }
 108
 109 sub _make_accessors_if_moose {
 110   my ($self, $role, $target) = @_;
 111   if ($INFO{$role}{inhaled_from_moose}) {
 112     $self->_make_accessors($role, $target);
 113   }
 114 }
 115
 116 sub _make_accessors {
 117   my ($self, $role, $target) = @_;
 118   my $acc_gen = ($Moo::MAKERS{$target}{accessor} ||= do {
 119     require Method::Generate::Accessor;
 120     Method::Generate::Accessor->new
 121   });
 122   my $con_gen = $Moo::MAKERS{$target}{constructor};
 123   my @attrs = @{$INFO{$role}{attributes}||[]};
 124   while (my ($name, $spec) = splice @attrs, 0, 2) {
 125     # needed to ensure we got an index for an arrayref based generator
 126     if ($con_gen) {
 127       $spec = $con_gen->all_attribute_specs->{$name};
 128     }
 129     $acc_gen->generate_method($target, $name, $spec);
 130   }
 131 }
 132
 133 sub apply_roles_to_package {
 134   my ($me, $to, @roles) = @_;
 135   $me->_inhale_if_moose($_) for @roles;
 136   $me->SUPER::apply_roles_to_package($to, @roles);
 137 }
 138
 139 sub apply_single_role_to_package {
 140   my ($me, $to, $role) = @_;
 141   $me->_inhale_if_moose($role);
 142   $me->_handle_constructor($to, $INFO{$role}{attributes});
 143   $me->_maybe_make_accessors($role, $to);
 144   $me->SUPER::apply_single_role_to_package($to, $role);
 145 }
 146
 147 sub create_class_with_roles {
 148   my ($me, $superclass, @roles) = @_;
 149
 150   my $new_name = join(
 151     '__WITH__', $superclass, my $compose_name = join '__AND__', @roles
 152   );
 153
 154   return $new_name if $Role::Tiny::COMPOSED{class}{$new_name};
 155
 156   $me->_inhale_if_moose($_) for @roles;
 157
 158   my $m;
 159   if ($INC{"Moo.pm"}
 160       and $m = Moo->_accessor_maker_for($superclass)
 161       and ref($m) ne 'Method::Generate::Accessor') {
 162     # old fashioned way time.
 163     *{_getglob("${new_name}::ISA")} = [ $superclass ];
 164     $me->apply_roles_to_package($new_name, @roles);
 165     return $new_name;
 166   }
 167
 168   require Sub::Quote;
 169
 170   $me->SUPER::create_class_with_roles($superclass, @roles);
 171
 172   foreach my $role (@roles) {
 173     die "${role} is not a Role::Tiny" unless my $info = $INFO{$role};
 174   }
 175
 176   $Moo::MAKERS{$new_name} = {};
 177
 178   $me->_handle_constructor(
 179     $new_name, [ map @{$INFO{$_}{attributes}||[]}, @roles ], $superclass
 180   );
 181
 182   return $new_name;
 183 }
 184
 185 sub _composable_package_for {
 186   my ($self, $role) = @_;
 187   my $composed_name = 'Role::Tiny::_COMPOSABLE::'.$role;
 188   return $composed_name if $Role::Tiny::COMPOSED{role}{$composed_name};
 189   $self->_make_accessors_if_moose($role, $composed_name);
 190   $self->SUPER::_composable_package_for($role);
 191 }
 192
 193 sub _install_single_modifier {
 194   my ($me, @args) = @_;
 195   _install_modifier(@args);
 196 }
 197
 198 sub _handle_constructor {
 199   my ($me, $to, $attr_info, $superclass) = @_;
 200   return unless $attr_info && @$attr_info;
 201   if ($INFO{$to}) {
 202     push @{$INFO{$to}{attributes}||=[]}, @$attr_info;
 203   } else {
 204     # only fiddle with the constructor if the target is a Moo class
 205     if ($INC{"Moo.pm"}
 206         and my $con = Moo->_constructor_maker_for($to, $superclass)) {
 207       # shallow copy of the specs since the constructor will assign an index
 208       $con->register_attribute_specs(map ref() ? { %$_ } : $_, @$attr_info);
 209     }
 210   }
 211 }
 212
 213 1;
 214
 215 =head1 NAME
 216
 217 Moo::Role - Minimal Object Orientation support for Roles
 218
 219 =head1 SYNOPSIS
 220
 221  package My::Role;
 222
 223  use Moo::Role;
 224
 225  sub foo { ... }
 226
 227  sub bar { ... }
 228
 229  has baz => (
 230    is => 'ro',
 231  );
 232
 233  1;
 234
 235 else where
 236
 237  package Some::Class;
 238
 239  use Moo;
 240
 241  # bar gets imported, but not foo
 242  with('My::Role');
 243
 244  sub foo { ... }
 245
 246  1;
 247
 248 =head1 DESCRIPTION
 249
 250 C<Moo::Role> builds upon L<Role::Tiny>, so look there for most of the
 251 documentation on how this works.  The main addition here is extra bits to make
 252 the roles more "Moosey;" which is to say, it adds L</has>.
 253
 254 =head1 IMPORTED SUBROUTINES
 255
 256 See L<Role::Tiny/IMPORTED SUBROUTINES> for all the other subroutines that are
 257 imported by this module.
 258
 259 =head2 has
 260
 261  has attr => (
 262    is => 'ro',
 263  );
 264
 265 Declares an attribute for the class to be composed into.  See
 266 L<Moo/has> for all options.
 267
 268 =head1 AUTHORS
 269
 270 See L<Moo> for authors.
 271
 272 =head1 COPYRIGHT AND LICENSE
 273
 274 See L<Moo> for the copyright and license.
 275
 276 =cut