lib/Moo/Role.pm

   1 package Moo::Role;
   2
   3 use strictures 1;
   4 use Moo::_Utils;
   5 use base qw(Role::Tiny);
   6
   7 require Moo::sification;
   8
   9 BEGIN { *INFO = \%Role::Tiny::INFO }
  10
  11 our %INFO;
  12
  13 sub import {
  14   my $target = caller;
  15   strictures->import;
  16   return if $INFO{$target}; # already exported into this package
  17   # get symbol table reference
  18   my $stash = do { no strict 'refs'; \%{"${target}::"} };
  19   _install_coderef "${target}::has" => sub {
  20     my ($name, %spec) = @_;
  21     ($INFO{$target}{accessor_maker} ||= do {
  22       require Method::Generate::Accessor;
  23       Method::Generate::Accessor->new
  24     })->generate_method($target, $name, \%spec);
  25     push @{$INFO{$target}{attributes}||=[]}, $name, \%spec;
  26   };
  27   if ($INC{'Moo/HandleMoose.pm'}) {
  28     Moo::HandleMoose::inject_fake_metaclass_for($target);
  29   }
  30   goto &Role::Tiny::import;
  31 }
  32
  33 sub _inhale_if_moose {
  34   my ($self, $role) = @_;
  35   _load_module($role);
  36   if (!$INFO{$role} and $INC{"Moose.pm"}) {
  37     if (my $meta = Class::MOP::class_of($role)) {
  38       $INFO{$role}{methods} = {
  39         map +($_ => $role->can($_)), $meta->get_method_list
  40       };
  41       $Role::Tiny::APPLIED_TO{$role} = {
  42         map +($_->name => 1), $meta->calculate_all_roles
  43       };
  44       $INFO{$role}{requires} = [ $meta->get_required_method_list ];
  45       $INFO{$role}{attributes} = [
  46         map +($_ => $meta->get_attribute($_)), $meta->get_attribute_list
  47       ];
  48       my $mods = $INFO{$role}{modifiers} = [];
  49       foreach my $type (qw(before after around)) {
  50         my $map = $meta->${\"get_${type}_method_modifiers_map"};
  51         foreach my $method (keys %$map) {
  52           foreach my $mod (@{$map->{$method}}) {
  53             push @$mods, [ $type => $method => $mod ];
  54           }
  55         }
  56       }
  57       require Class::Method::Modifiers if @$mods;
  58       $INFO{$role}{inhaled_from_moose} = 1;
  59     }
  60   }
  61 }
  62
  63 sub _maybe_make_accessors {
  64   my ($self, $role, $target) = @_;
  65   my $m;
  66   if ($INFO{$role}{inhaled_from_moose}
  67       or $m = Moo->_accessor_maker_for($target)
  68       and ref($m) ne 'Method::Generate::Accessor') {
  69     $self->_make_accessors($role, $target);
  70   }
  71 }
  72
  73 sub _make_accessors_if_moose {
  74   my ($self, $role, $target) = @_;
  75   if ($INFO{$role}{inhaled_from_moose}) {
  76     $self->_make_accessors($role, $target);
  77   }
  78 }
  79
  80 sub _make_accessors {
  81   my ($self, $role, $target) = @_;
  82   my $acc_gen = ($Moo::MAKERS{$target}{accessor} ||= do {
  83     require Method::Generate::Accessor;
  84     Method::Generate::Accessor->new
  85   });
  86   my @attrs = @{$INFO{$role}{attributes}||[]};
  87   while (my ($name, $spec) = splice @attrs, 0, 2) {
  88     $acc_gen->generate_method($target, $name, $spec);
  89   }
  90 }
  91
  92 sub apply_single_role_to_package {
  93   my ($me, $to, $role) = @_;
  94   $me->_inhale_if_moose($role);
  95   $me->_handle_constructor($to, $INFO{$role}{attributes});
  96   $me->_maybe_make_accessors($role, $to);
  97   $me->SUPER::apply_single_role_to_package($to, $role);
  98 }
  99
 100 sub create_class_with_roles {
 101   my ($me, $superclass, @roles) = @_;
 102
 103   my $new_name = join(
 104     '__WITH__', $superclass, my $compose_name = join '__AND__', @roles
 105   );
 106
 107   return $new_name if $Role::Tiny::COMPOSED{class}{$new_name};
 108
 109   $me->_inhale_if_moose($_) for @roles;
 110
 111   my $m;
 112   if ($m = Moo->_accessor_maker_for($superclass)
 113       and ref($m) ne 'Method::Generate::Accessor') {
 114     # old fashioned way time.
 115     *{_getglob("${new_name}::ISA")} = [ $superclass ];
 116     $me->apply_roles_to_package($new_name, @roles);
 117     return $new_name;
 118   }
 119
 120   require Sub::Quote;
 121
 122   $me->SUPER::create_class_with_roles($superclass, @roles);
 123
 124   foreach my $role (@roles) {
 125     die "${role} is not a Role::Tiny" unless my $info = $INFO{$role};
 126   }
 127
 128   $Moo::MAKERS{$new_name} = {};
 129
 130   $me->_handle_constructor(
 131     $new_name, [ map @{$INFO{$_}{attributes}||[]}, @roles ], $superclass
 132   );
 133
 134   return $new_name;
 135 }
 136
 137 sub _composable_package_for {
 138   my ($self, $role) = @_;
 139   my $composed_name = 'Role::Tiny::_COMPOSABLE::'.$role;
 140   return $composed_name if $Role::Tiny::COMPOSED{role}{$composed_name};
 141   $self->_make_accessors_if_moose($role, $composed_name);
 142   $self->SUPER::_composable_package_for($role);
 143 }
 144
 145 sub _install_single_modifier {
 146   my ($me, @args) = @_;
 147   _install_modifier(@args);
 148 }
 149
 150 sub _handle_constructor {
 151   my ($me, $to, $attr_info, $superclass) = @_;
 152   return unless $attr_info && @$attr_info;
 153   if ($INFO{$to}) {
 154     push @{$INFO{$to}{attributes}||=[]}, @$attr_info;
 155   } else {
 156     # only fiddle with the constructor if the target is a Moo class
 157     if ($INC{"Moo.pm"}
 158         and my $con = Moo->_constructor_maker_for($to, $superclass)) {
 159       # shallow copy of the specs since the constructor will assign an index
 160       $con->register_attribute_specs(map ref() ? { %$_ } : $_, @$attr_info);
 161     }
 162   }
 163 }
 164
 165 1;
 166
 167 =head1 NAME
 168
 169 Moo::Role - Minimal Object Orientation support for Roles
 170
 171 =head1 SYNOPSIS
 172
 173  package My::Role;
 174
 175  use Moo::Role;
 176
 177  sub foo { ... }
 178
 179  sub bar { ... }
 180
 181  has baz => (
 182    is => 'ro',
 183  );
 184
 185  1;
 186
 187 else where
 188
 189  package Some::Class;
 190
 191  use Moo;
 192
 193  # bar gets imported, but not foo
 194  with('My::Role');
 195
 196  sub foo { ... }
 197
 198  1;
 199
 200 =head1 DESCRIPTION
 201
 202 C<Moo::Role> builds upon L<Role::Tiny>, so look there for most of the
 203 documentation on how this works.  The main addition here is extra bits to make
 204 the roles more "Moosey;" which is to say, it adds L</has>.
 205
 206 =head1 IMPORTED SUBROUTINES
 207
 208 See L<Role::Tiny/IMPORTED SUBROUTINES> for all the other subroutines that are
 209 imported by this module.
 210
 211 =head2 has
 212
 213  has attr => (
 214    is => 'ro',
 215  );
 216
 217 Declares an attribute for the class to be composed into.  See
 218 L<Moo/has> for all options.
 219
 220 =head1 AUTHORS
 221
 222 See L<Moo> for authors.
 223
 224 =head1 COPYRIGHT AND LICENSE
 225
 226 See L<Moo> for the copyright and license.
 227
 228 =cut