lib/Moo/Role.pm

   1 package Moo::Role;
   2
   3 use strictures 1;
   4 use Moo::_Utils;
   5 use Role::Tiny ();
   6 use base qw(Role::Tiny);
   7
   8 require Moo::sification;
   9
  10 BEGIN { *INFO = \%Role::Tiny::INFO }
  11
  12 our %INFO;
  13 our %APPLY_DEFAULTS;
  14
  15 sub _install_tracked {
  16   my ($target, $name, $code) = @_;
  17   $INFO{$target}{exports}{$name} = $code;
  18   _install_coderef "${target}::${name}" => "Moo::Role::${name}" => $code;
  19 }
  20
  21 sub import {
  22   my $target = caller;
  23   my ($me) = @_;
  24   strictures->import;
  25   if ($Moo::MAKERS{$target} and $Moo::MAKERS{$target}{is_class}) {
  26     die "Cannot import Moo::Role into a Moo class";
  27   }
  28   $INFO{$target} ||= {};
  29   # get symbol table reference
  30   my $stash = do { no strict 'refs'; \%{"${target}::"} };
  31   _install_tracked $target => has => sub {
  32     my ($name_proto, %spec) = @_;
  33     my $name_isref = ref $name_proto eq 'ARRAY';
  34     foreach my $name ($name_isref ? @$name_proto : $name_proto) {
  35       my $spec_ref = $name_isref ? +{%spec} : \%spec;
  36       ($INFO{$target}{accessor_maker} ||= do {
  37         require Method::Generate::Accessor;
  38         Method::Generate::Accessor->new
  39       })->generate_method($target, $name, $spec_ref);
  40       push @{$INFO{$target}{attributes}||=[]}, $name, $spec_ref;
  41       $me->_maybe_reset_handlemoose($target);
  42     }
  43   };
  44   # install before/after/around subs
  45   foreach my $type (qw(before after around)) {
  46     _install_tracked $target => $type => sub {
  47       require Class::Method::Modifiers;
  48       push @{$INFO{$target}{modifiers}||=[]}, [ $type => @_ ];
  49       $me->_maybe_reset_handlemoose($target);
  50     };
  51   }
  52   _install_tracked $target => requires => sub {
  53     push @{$INFO{$target}{requires}||=[]}, @_;
  54     $me->_maybe_reset_handlemoose($target);
  55   };
  56   _install_tracked $target => with => sub {
  57     $me->apply_roles_to_package($target, @_);
  58     $me->_maybe_reset_handlemoose($target);
  59   };
  60   return if $INFO{$target}{is_role}; # already exported into this package
  61   $INFO{$target}{is_role} = 1;
  62   *{_getglob("${target}::meta")} = $me->can('meta');
  63   # grab all *non-constant* (stash slot is not a scalarref) subs present
  64   # in the symbol table and store their refaddrs (no need to forcibly
  65   # inflate constant subs into real subs) - also add '' to here (this
  66   # is used later) with a map to the coderefs in case of copying or re-use
  67   my @not_methods = ('', map { *$_{CODE}||() } grep !ref($_), values %$stash);
  68   @{$INFO{$target}{not_methods}={}}{@not_methods} = @not_methods;
  69   # a role does itself
  70   $Role::Tiny::APPLIED_TO{$target} = { $target => undef };
  71
  72   if ($INC{'Moo/HandleMoose.pm'}) {
  73     Moo::HandleMoose::inject_fake_metaclass_for($target);
  74   }
  75 }
  76
  77 # duplicate from Moo::Object
  78 sub meta {
  79   require Moo::HandleMoose::FakeMetaClass;
  80   my $class = ref($_[0])||$_[0];
  81   bless({ name => $class }, 'Moo::HandleMoose::FakeMetaClass');
  82 }
  83
  84 sub unimport {
  85   my $target = caller;
  86   _unimport_coderefs($target, $INFO{$target});
  87 }
  88
  89 sub _maybe_reset_handlemoose {
  90   my ($class, $target) = @_;
  91   if ($INC{"Moo/HandleMoose.pm"}) {
  92     Moo::HandleMoose::maybe_reinject_fake_metaclass_for($target);
  93   }
  94 }
  95
  96 sub _inhale_if_moose {
  97   my ($self, $role) = @_;
  98   _load_module($role);
  99   my $meta;
 100   if (!$INFO{$role}
 101       and (
 102         $INC{"Moose.pm"}
 103         and $meta = Class::MOP::class_of($role)
 104         and $meta->isa('Moose::Meta::Role')
 105       )
 106       or (
 107         Mouse::Util->can('find_meta')
 108         and $meta = Mouse::Util::find_meta($role)
 109         and $meta->isa('Mouse::Meta::Role')
 110      )
 111   ) {
 112     $INFO{$role}{methods} = {
 113       map +($_ => $role->can($_)),
 114         grep !$meta->get_method($_)->isa('Class::MOP::Method::Meta'),
 115           $meta->get_method_list
 116     };
 117     $Role::Tiny::APPLIED_TO{$role} = {
 118       map +($_->name => 1), $meta->calculate_all_roles
 119     };
 120     $INFO{$role}{requires} = [ $meta->get_required_method_list ];
 121     $INFO{$role}{attributes} = [
 122       map +($_ => do {
 123         my $attr = $meta->get_attribute($_);
 124         my $is_mouse = $meta->isa('Mouse::Meta::Role');
 125         my $spec = { %{ $is_mouse ? $attr : $attr->original_options } };
 126
 127         if ($spec->{isa}) {
 128
 129           my $get_constraint = do {
 130             my $pkg = $is_mouse
 131                         ? 'Mouse::Util::TypeConstraints'
 132                         : 'Moose::Util::TypeConstraints';
 133             _load_module($pkg);
 134             $pkg->can('find_or_create_isa_type_constraint');
 135           };
 136
 137           my $tc = $get_constraint->($spec->{isa});
 138           my $check = $tc->_compiled_type_constraint;
 139
 140           $spec->{isa} = sub {
 141             &$check or die "Type constraint failed for $_[0]"
 142           };
 143
 144           if ($spec->{coerce}) {
 145
 146              # Mouse has _compiled_type_coercion straight on the TC object
 147              $spec->{coerce} = $tc->${\(
 148                $tc->can('coercion')||sub { $_[0] }
 149              )}->_compiled_type_coercion;
 150           }
 151         }
 152         $spec;
 153       }), $meta->get_attribute_list
 154     ];
 155     my $mods = $INFO{$role}{modifiers} = [];
 156     foreach my $type (qw(before after around)) {
 157       # Mouse pokes its own internals so we have to fall back to doing
 158       # the same thing in the absence of the Moose API method
 159       my $map = $meta->${\(
 160         $meta->can("get_${type}_method_modifiers_map")
 161         or sub { shift->{"${type}_method_modifiers"} }
 162       )};
 163       foreach my $method (keys %$map) {
 164         foreach my $mod (@{$map->{$method}}) {
 165           push @$mods, [ $type => $method => $mod ];
 166         }
 167       }
 168     }
 169     require Class::Method::Modifiers if @$mods;
 170     $INFO{$role}{inhaled_from_moose} = 1;
 171   }
 172 }
 173
 174 sub _maybe_make_accessors {
 175   my ($self, $role, $target) = @_;
 176   my $m;
 177   if ($INFO{$role}{inhaled_from_moose}
 178       or $INC{"Moo.pm"}
 179       and $m = Moo->_accessor_maker_for($target)
 180       and ref($m) ne 'Method::Generate::Accessor') {
 181     $self->_make_accessors($role, $target);
 182   }
 183 }
 184
 185 sub _make_accessors_if_moose {
 186   my ($self, $role, $target) = @_;
 187   if ($INFO{$role}{inhaled_from_moose}) {
 188     $self->_make_accessors($role, $target);
 189   }
 190 }
 191
 192 sub _make_accessors {
 193   my ($self, $role, $target) = @_;
 194   my $acc_gen = ($Moo::MAKERS{$target}{accessor} ||= do {
 195     require Method::Generate::Accessor;
 196     Method::Generate::Accessor->new
 197   });
 198   my $con_gen = $Moo::MAKERS{$target}{constructor};
 199   my @attrs = @{$INFO{$role}{attributes}||[]};
 200   while (my ($name, $spec) = splice @attrs, 0, 2) {
 201     # needed to ensure we got an index for an arrayref based generator
 202     if ($con_gen) {
 203       $spec = $con_gen->all_attribute_specs->{$name};
 204     }
 205     $acc_gen->generate_method($target, $name, $spec);
 206   }
 207 }
 208
 209 sub apply_roles_to_package {
 210   my ($me, $to, @roles) = @_;
 211   foreach my $role (@roles) {
 212       $me->_inhale_if_moose($role);
 213   }
 214   $me->SUPER::apply_roles_to_package($to, @roles);
 215 }
 216
 217 sub apply_single_role_to_package {
 218   my ($me, $to, $role) = @_;
 219   $me->_inhale_if_moose($role);
 220   die "${role} is not a Moo::Role" unless my $info = $INFO{$role};
 221   $me->_handle_constructor($to, $INFO{$role}{attributes});
 222   $me->_maybe_make_accessors($role, $to);
 223   $me->SUPER::apply_single_role_to_package($to, $role);
 224 }
 225
 226 sub create_class_with_roles {
 227   my ($me, $superclass, @roles) = @_;
 228
 229   my $new_name = join(
 230     '__WITH__', $superclass, my $compose_name = join '__AND__', @roles
 231   );
 232
 233   return $new_name if $Role::Tiny::COMPOSED{class}{$new_name};
 234
 235   foreach my $role (@roles) {
 236       $me->_inhale_if_moose($role);
 237   }
 238
 239   my $m;
 240   if ($INC{"Moo.pm"}
 241       and $m = Moo->_accessor_maker_for($superclass)
 242       and ref($m) ne 'Method::Generate::Accessor') {
 243     # old fashioned way time.
 244     *{_getglob("${new_name}::ISA")} = [ $superclass ];
 245     $me->apply_roles_to_package($new_name, @roles);
 246     return $new_name;
 247   }
 248
 249   require Sub::Quote;
 250
 251   $me->SUPER::create_class_with_roles($superclass, @roles);
 252
 253   foreach my $role (@roles) {
 254     die "${role} is not a Role::Tiny" unless my $info = $INFO{$role};
 255   }
 256
 257   $Moo::MAKERS{$new_name} = {};
 258
 259   $me->_handle_constructor(
 260     $new_name, [ map @{$INFO{$_}{attributes}||[]}, @roles ]
 261   );
 262
 263   return $new_name;
 264 }
 265
 266 sub apply_roles_to_object {
 267   my ($me, $object, @roles) = @_;
 268   my $new = $me->SUPER::apply_roles_to_object($object, @roles);
 269
 270   my $apply_defaults = $APPLY_DEFAULTS{ref $new} ||= do {
 271     my %attrs = map { @{$INFO{$_}{attributes}||[]} } @roles;
 272
 273     if ($INC{'Moo.pm'}
 274         and keys %attrs
 275         and my $con_gen = Moo->_constructor_maker_for(ref $new)
 276         and my $m = Moo->_accessor_maker_for(ref $new)) {
 277       require Sub::Quote;
 278
 279       my $specs = $con_gen->all_attribute_specs;
 280
 281       my $assign = '';
 282       my %captures;
 283       foreach my $name ( keys %attrs ) {
 284         my $spec = $specs->{$name};
 285         if ($m->has_eager_default($name, $spec)) {
 286           my ($has, $has_cap)
 287             = $m->generate_simple_has('$_[0]', $name, $spec);
 288           my ($code, $pop_cap)
 289             = $m->generate_use_default('$_[0]', $name, $spec, $has);
 290
 291           $assign .= $code;
 292           @captures{keys %$has_cap, keys %$pop_cap}
 293             = (values %$has_cap, values %$pop_cap);
 294         }
 295       }
 296       Sub::Quote::quote_sub($assign, \%captures);
 297     }
 298     else {
 299       sub {};
 300     }
 301   };
 302   $new->$apply_defaults;
 303   return $new;
 304 }
 305
 306 sub _composable_package_for {
 307   my ($self, $role) = @_;
 308   my $composed_name = 'Role::Tiny::_COMPOSABLE::'.$role;
 309   return $composed_name if $Role::Tiny::COMPOSED{role}{$composed_name};
 310   $self->_make_accessors_if_moose($role, $composed_name);
 311   $self->SUPER::_composable_package_for($role);
 312 }
 313
 314 sub _install_single_modifier {
 315   my ($me, @args) = @_;
 316   _install_modifier(@args);
 317 }
 318
 319 sub _handle_constructor {
 320   my ($me, $to, $attr_info) = @_;
 321   return unless $attr_info && @$attr_info;
 322   if ($INFO{$to}) {
 323     push @{$INFO{$to}{attributes}||=[]}, @$attr_info;
 324   } else {
 325     # only fiddle with the constructor if the target is a Moo class
 326     if ($INC{"Moo.pm"}
 327         and my $con = Moo->_constructor_maker_for($to)) {
 328       # shallow copy of the specs since the constructor will assign an index
 329       $con->register_attribute_specs(map ref() ? { %$_ } : $_, @$attr_info);
 330     }
 331   }
 332 }
 333
 334 1;
 335
 336 =head1 NAME
 337
 338 Moo::Role - Minimal Object Orientation support for Roles
 339
 340 =head1 SYNOPSIS
 341
 342  package My::Role;
 343
 344  use Moo::Role;
 345
 346  sub foo { ... }
 347
 348  sub bar { ... }
 349
 350  has baz => (
 351    is => 'ro',
 352  );
 353
 354  1;
 355
 356 And elsewhere:
 357
 358  package Some::Class;
 359
 360  use Moo;
 361
 362  # bar gets imported, but not foo
 363  with('My::Role');
 364
 365  sub foo { ... }
 366
 367  1;
 368
 369 =head1 DESCRIPTION
 370
 371 C<Moo::Role> builds upon L<Role::Tiny>, so look there for most of the
 372 documentation on how this works.  The main addition here is extra bits to make
 373 the roles more "Moosey;" which is to say, it adds L</has>.
 374
 375 =head1 IMPORTED SUBROUTINES
 376
 377 See L<Role::Tiny/IMPORTED SUBROUTINES> for all the other subroutines that are
 378 imported by this module.
 379
 380 =head2 has
 381
 382  has attr => (
 383    is => 'ro',
 384  );
 385
 386 Declares an attribute for the class to be composed into.  See
 387 L<Moo/has> for all options.
 388
 389 =head1 SUPPORT
 390
 391 See L<Moo> for support and contact information.
 392
 393 =head1 AUTHORS
 394
 395 See L<Moo> for authors.
 396
 397 =head1 COPYRIGHT AND LICENSE
 398
 399 See L<Moo> for the copyright and license.