lib/Moo/Role.pm

   1 package Moo::Role;
   2
   3 use strictures 1;
   4 use Moo::_Utils;
   5 use base qw(Role::Tiny);
   6
   7 require Moo::sification;
   8
   9 BEGIN { *INFO = \%Role::Tiny::INFO }
  10
  11 our %INFO;
  12
  13 sub _install_tracked {
  14   my ($target, $name, $code) = @_;
  15   $INFO{$target}{exports}{$name} = $code;
  16   _install_coderef "${target}::${name}" => "Moo::Role::${name}" => $code;
  17 }
  18
  19 sub import {
  20   my $target = caller;
  21   my ($me) = @_;
  22   strictures->import;
  23   return if $INFO{$target}; # already exported into this package
  24   $INFO{$target} = {};
  25   # get symbol table reference
  26   my $stash = do { no strict 'refs'; \%{"${target}::"} };
  27   _install_tracked $target => has => sub {
  28     my ($name_proto, %spec) = @_;
  29     my $name_isref = ref $name_proto eq 'ARRAY';
  30     foreach my $name ($name_isref ? @$name_proto : $name_proto) {
  31       my $spec_ref = $name_isref ? +{%spec} : \%spec;
  32       ($INFO{$target}{accessor_maker} ||= do {
  33         require Method::Generate::Accessor;
  34         Method::Generate::Accessor->new
  35       })->generate_method($target, $name, $spec_ref);
  36       push @{$INFO{$target}{attributes}||=[]}, $name, $spec_ref;
  37       $me->_maybe_reset_handlemoose($target);
  38     }
  39   };
  40   # install before/after/around subs
  41   foreach my $type (qw(before after around)) {
  42     _install_tracked $target => $type => sub {
  43       require Class::Method::Modifiers;
  44       push @{$INFO{$target}{modifiers}||=[]}, [ $type => @_ ];
  45       $me->_maybe_reset_handlemoose($target);
  46     };
  47   }
  48   _install_tracked $target => requires => sub {
  49     push @{$INFO{$target}{requires}||=[]}, @_;
  50     $me->_maybe_reset_handlemoose($target);
  51   };
  52   _install_tracked $target => with => sub {
  53     $me->apply_roles_to_package($target, @_);
  54     $me->_maybe_reset_handlemoose($target);
  55   };
  56   # grab all *non-constant* (stash slot is not a scalarref) subs present
  57   # in the symbol table and store their refaddrs (no need to forcibly
  58   # inflate constant subs into real subs) - also add '' to here (this
  59   # is used later) with a map to the coderefs in case of copying or re-use
  60   my @not_methods = ('', map { *$_{CODE}||() } grep !ref($_), values %$stash);
  61   @{$INFO{$target}{not_methods}={}}{@not_methods} = @not_methods;
  62   # a role does itself
  63   $Role::Tiny::APPLIED_TO{$target} = { $target => undef };
  64
  65   if ($INC{'Moo/HandleMoose.pm'}) {
  66     Moo::HandleMoose::inject_fake_metaclass_for($target);
  67   }
  68 }
  69
  70 sub unimport {
  71   my $target = caller;
  72   _unimport_coderefs($target, $INFO{$target});
  73 }
  74
  75 sub _maybe_reset_handlemoose {
  76   my ($class, $target) = @_;
  77   if ($INC{"Moo/HandleMoose.pm"}) {
  78     Moo::HandleMoose::maybe_reinject_fake_metaclass_for($target);
  79   }
  80 }
  81
  82 sub _inhale_if_moose {
  83   my ($self, $role) = @_;
  84   _load_module($role);
  85   my $meta;
  86   if (!$INFO{$role}
  87       and (
  88         $INC{"Moose.pm"}
  89         and $meta = Class::MOP::class_of($role)
  90       )
  91       or (
  92         $INC{"Mouse.pm"}
  93         and $meta = Mouse::Util::find_meta($role)
  94      )
  95   ) {
  96     $INFO{$role}{methods} = {
  97       map +($_ => $role->can($_)),
  98         grep !$meta->get_method($_)->isa('Class::MOP::Method::Meta'),
  99           $meta->get_method_list
 100     };
 101     $Role::Tiny::APPLIED_TO{$role} = {
 102       map +($_->name => 1), $meta->calculate_all_roles
 103     };
 104     $INFO{$role}{requires} = [ $meta->get_required_method_list ];
 105     $INFO{$role}{attributes} = [
 106       map +($_ => do {
 107         my $spec = { %{$meta->get_attribute($_)} };
 108
 109         if ($spec->{isa}) {
 110
 111           my $get_constraint = do {
 112             my $pkg = $meta->isa('Mouse::Meta::Role')
 113                         ? 'Mouse::Util::TypeConstraints'
 114                         : 'Moose::Util::TypeConstraints';
 115             _load_module($pkg);
 116             $pkg->can('find_or_create_isa_type_constraint');
 117           };
 118
 119           my $tc = $get_constraint->($spec->{isa});
 120           my $check = $tc->_compiled_type_constraint;
 121
 122           $spec->{isa} = sub {
 123             &$check or die "Type constraint failed for $_[0]"
 124           };
 125
 126           if ($spec->{coerce}) {
 127
 128              # Mouse has _compiled_type_coercion straight on the TC object
 129              $spec->{coerce} = $tc->${\(
 130                $tc->can('coercion')||sub { $_[0] }
 131              )}->_compiled_type_coercion;
 132           }
 133         }
 134         $spec;
 135       }), $meta->get_attribute_list
 136     ];
 137     my $mods = $INFO{$role}{modifiers} = [];
 138     foreach my $type (qw(before after around)) {
 139       # Mouse pokes its own internals so we have to fall back to doing
 140       # the same thing in the absence of the Moose API method
 141       my $map = $meta->${\(
 142         $meta->can("get_${type}_method_modifiers_map")
 143         or sub { shift->{"${type}_method_modifiers"} }
 144       )};
 145       foreach my $method (keys %$map) {
 146         foreach my $mod (@{$map->{$method}}) {
 147           push @$mods, [ $type => $method => $mod ];
 148         }
 149       }
 150     }
 151     require Class::Method::Modifiers if @$mods;
 152     $INFO{$role}{inhaled_from_moose} = 1;
 153   }
 154 }
 155
 156 sub _maybe_make_accessors {
 157   my ($self, $role, $target) = @_;
 158   my $m;
 159   if ($INFO{$role}{inhaled_from_moose}
 160       or $INC{"Moo.pm"}
 161       and $m = Moo->_accessor_maker_for($target)
 162       and ref($m) ne 'Method::Generate::Accessor') {
 163     $self->_make_accessors($role, $target);
 164   }
 165 }
 166
 167 sub _make_accessors_if_moose {
 168   my ($self, $role, $target) = @_;
 169   if ($INFO{$role}{inhaled_from_moose}) {
 170     $self->_make_accessors($role, $target);
 171   }
 172 }
 173
 174 sub _make_accessors {
 175   my ($self, $role, $target) = @_;
 176   my $acc_gen = ($Moo::MAKERS{$target}{accessor} ||= do {
 177     require Method::Generate::Accessor;
 178     Method::Generate::Accessor->new
 179   });
 180   my $con_gen = $Moo::MAKERS{$target}{constructor};
 181   my @attrs = @{$INFO{$role}{attributes}||[]};
 182   while (my ($name, $spec) = splice @attrs, 0, 2) {
 183     # needed to ensure we got an index for an arrayref based generator
 184     if ($con_gen) {
 185       $spec = $con_gen->all_attribute_specs->{$name};
 186     }
 187     $acc_gen->generate_method($target, $name, $spec);
 188   }
 189 }
 190
 191 sub apply_roles_to_package {
 192   my ($me, $to, @roles) = @_;
 193   foreach my $role (@roles) {
 194       $me->_inhale_if_moose($role);
 195   }
 196   $me->SUPER::apply_roles_to_package($to, @roles);
 197 }
 198
 199 sub apply_single_role_to_package {
 200   my ($me, $to, $role) = @_;
 201   $me->_inhale_if_moose($role);
 202   $me->_handle_constructor($to, $INFO{$role}{attributes});
 203   $me->_maybe_make_accessors($role, $to);
 204   $me->SUPER::apply_single_role_to_package($to, $role);
 205 }
 206
 207 sub create_class_with_roles {
 208   my ($me, $superclass, @roles) = @_;
 209
 210   my $new_name = join(
 211     '__WITH__', $superclass, my $compose_name = join '__AND__', @roles
 212   );
 213
 214   return $new_name if $Role::Tiny::COMPOSED{class}{$new_name};
 215
 216   foreach my $role (@roles) {
 217       $me->_inhale_if_moose($role);
 218   }
 219
 220   my $m;
 221   if ($INC{"Moo.pm"}
 222       and $m = Moo->_accessor_maker_for($superclass)
 223       and ref($m) ne 'Method::Generate::Accessor') {
 224     # old fashioned way time.
 225     *{_getglob("${new_name}::ISA")} = [ $superclass ];
 226     $me->apply_roles_to_package($new_name, @roles);
 227     return $new_name;
 228   }
 229
 230   require Sub::Quote;
 231
 232   $me->SUPER::create_class_with_roles($superclass, @roles);
 233
 234   foreach my $role (@roles) {
 235     die "${role} is not a Role::Tiny" unless my $info = $INFO{$role};
 236   }
 237
 238   $Moo::MAKERS{$new_name} = {};
 239
 240   $me->_handle_constructor(
 241     $new_name, [ map @{$INFO{$_}{attributes}||[]}, @roles ], $superclass
 242   );
 243
 244   return $new_name;
 245 }
 246
 247 sub _composable_package_for {
 248   my ($self, $role) = @_;
 249   my $composed_name = 'Role::Tiny::_COMPOSABLE::'.$role;
 250   return $composed_name if $Role::Tiny::COMPOSED{role}{$composed_name};
 251   $self->_make_accessors_if_moose($role, $composed_name);
 252   $self->SUPER::_composable_package_for($role);
 253 }
 254
 255 sub _install_single_modifier {
 256   my ($me, @args) = @_;
 257   _install_modifier(@args);
 258 }
 259
 260 sub _handle_constructor {
 261   my ($me, $to, $attr_info, $superclass) = @_;
 262   return unless $attr_info && @$attr_info;
 263   if ($INFO{$to}) {
 264     push @{$INFO{$to}{attributes}||=[]}, @$attr_info;
 265   } else {
 266     # only fiddle with the constructor if the target is a Moo class
 267     if ($INC{"Moo.pm"}
 268         and my $con = Moo->_constructor_maker_for($to, $superclass)) {
 269       # shallow copy of the specs since the constructor will assign an index
 270       $con->register_attribute_specs(map ref() ? { %$_ } : $_, @$attr_info);
 271     }
 272   }
 273 }
 274
 275 1;
 276
 277 =head1 NAME
 278
 279 Moo::Role - Minimal Object Orientation support for Roles
 280
 281 =head1 SYNOPSIS
 282
 283  package My::Role;
 284
 285  use Moo::Role;
 286
 287  sub foo { ... }
 288
 289  sub bar { ... }
 290
 291  has baz => (
 292    is => 'ro',
 293  );
 294
 295  1;
 296
 297 And elsewhere:
 298
 299  package Some::Class;
 300
 301  use Moo;
 302
 303  # bar gets imported, but not foo
 304  with('My::Role');
 305
 306  sub foo { ... }
 307
 308  1;
 309
 310 =head1 DESCRIPTION
 311
 312 C<Moo::Role> builds upon L<Role::Tiny>, so look there for most of the
 313 documentation on how this works.  The main addition here is extra bits to make
 314 the roles more "Moosey;" which is to say, it adds L</has>.
 315
 316 =head1 IMPORTED SUBROUTINES
 317
 318 See L<Role::Tiny/IMPORTED SUBROUTINES> for all the other subroutines that are
 319 imported by this module.
 320
 321 =head2 has
 322
 323  has attr => (
 324    is => 'ro',
 325  );
 326
 327 Declares an attribute for the class to be composed into.  See
 328 L<Moo/has> for all options.
 329
 330 =head1 AUTHORS
 331
 332 See L<Moo> for authors.
 333
 334 =head1 COPYRIGHT AND LICENSE
 335
 336 See L<Moo> for the copyright and license.
 337
 338 =cut